WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DistributionParameterAssumptions[dist]

記号分布 dist の母数に関する仮定の論理式を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

DistributionParameterAssumptions

DistributionParameterAssumptions[dist]

記号分布 dist の母数に関する仮定の論理式を返す．

詳細

  • DistributionParameterAssumptionsは，dist の母数に関する仮定についての，方程式，不等式，領域指定の論理結合を返す．
  • DistributionParameterAssumptionsは，記号分布として指定された任意の一変量あるいは多変量の分布に関する母数についての仮定を生成することができる．

例題

すべて開く すべて閉じる

例  (1)

正規分布の母数仮定を得る：

Wolfram Language code: DistributionParameterAssumptions[NormalDistribution[μ, σ]]

多項式分布の母数仮定：

Wolfram Language code: DistributionParameterAssumptions[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}]]

スコープ  (4)

数値と記号の母数の組合せで分布の仮定を得る：

Wolfram Language code: dists = Table[GammaDistribution[a, b], {a, {α, 1}}, {b, {β, 2}}]//Flatten
Wolfram Language code: Table[{d, DistributionParameterAssumptions[d]}, {d, dists}]//TableForm

一変量と多変量の離散分布と連続分布について仮定を得る：

Wolfram Language code: validDistributions = {GeometricDistribution[p], ParetoDistribution[k, a], BinormalDistribution[ρ], MultivariatePoissonDistribution[μ, {Subscript[μ, 1], Subscript[μ, 2]}]};
Wolfram Language code: Table[{dist, DistributionParameterAssumptions[dist]}, {dist, validDistributions}]//TableForm

生成された分布について仮定を得る：

Wolfram Language code: tdist = TransformedDistribution[x ^ 3, xPoissonDistribution[μ]];
Wolfram Language code: DistributionParameterAssumptions[tdist]

データ分布は母数を持たないので，仮定は無意味な真である：

Wolfram Language code: ddist = EmpiricalDistribution[Range[10]];
Wolfram Language code: DistributionParameterAssumptions[ddist]

アプリケーション  (4)

極値分布について確率密度関数を得る：

Wolfram Language code: pdf = PDF[ExtremeValueDistribution[α, β], x]

母数の仮定を含まずに平均について積分を計算する：

Wolfram Language code: Integrate[x * pdf, {x, -∞, ∞}]

母数の仮定を使って結果を簡略化する：

Wolfram Language code: Assuming[DistributionParameterAssumptions[ExtremeValueDistribution[α, β]], Simplify[%]]

仮定を直接Integrateに与えることによって，結果を計算する：

Wolfram Language code: Integrate[x * pdf, {x, -∞, ∞}, Assumptions -> DistributionParameterAssumptions[ExtremeValueDistribution[α, β]]]

分布の平均と比べる：

Wolfram Language code: Mean[ExtremeValueDistribution[α, β]]

2つのカイ二乗(χ2)分布とそのパラメータに関する仮定を定義する：

Wolfram Language code: dist1 = ChiSquareDistribution[n]; dist2 = ChiSquareDistribution[m]; assumpts = DistributionParameterAssumptions[dist1] && DistributionParameterAssumptions[dist2];

カイ二乗(χ2)分布に従う変数の和の確率密度関数を，仮定付きのたたみ込みを使って計算する：

Wolfram Language code: Convolve[PDF[dist1, t], PDF[dist2, t], t, x, Assumptions -> assumpts]

カイ二乗(χ2)変数の加算性を確かめる：

Wolfram Language code: % == PDF[ChiSquareDistribution[m + n], x]//Simplify

Haight分布を確率母数 で定義する：

Wolfram Language code: dist = ProbabilityDistribution[(4 ^ (-1 + k)p((1 - p) * p) ^ (-1 + k)(-(3 / 2) + k)!) / (Sqrt[Pi]k!), {k, 1, Infinity, 1}, Assumptions -> 1 / 2 < p < 1];

確率密度関数式を合計し，正規化をチェックする：

Wolfram Language code: Sum[PDF[dist, k], {k, 1, Infinity}]

分布の仮定が満たされなければ，結果が常に1になるわけではない：

Wolfram Language code: FullSimplify[%, Not[DistributionParameterAssumptions[dist]]]

Sumに仮定を与え， の仮定された値について全確率が1になることを確かめる：

Wolfram Language code: Sum[PDF[dist, k], {k, 1, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]

母数 b1および b0が未知であるタイプ1のピアソン(Pearson)分布についての仮定を得る：

Wolfram Language code: assumpts = DistributionParameterAssumptions[PearsonDistribution[1, 3, -2, 3, Subscript[b, 1], Subscript[b, 0]]]

b1の可能な最大値を b0の関数として求める：

Wolfram Language code: max = ArgMax[{Subscript[b, 1], assumpts}, Subscript[b, 1]]
Wolfram Language code: Plot[max, {Subscript[b, 0], -10, 10}, Filling -> -20, AxesLabel -> {Subscript[b, 0], Subscript[b, 1]}]

特性と関係  (1)

DistributionParameterAssumptionsは母数の条件を返す：

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[n, p]]

DistributionParameterQは記号母数が有効であると仮定する：

Wolfram Language code: DistributionParameterQ[BinomialDistribution[n, p]]

数値母数では，出力は等しい：

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[20, 1 / 3]]
Wolfram Language code: DistributionParameterQ[BinomialDistribution[20, 1 / 3]]
Wolfram Research (2010), DistributionParameterAssumptions, Wolfram言語関数， https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

テキスト

Wolfram Research (2010), DistributionParameterAssumptions, Wolfram言語関数， https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

CMS

Wolfram Language. 2010. "DistributionParameterAssumptions." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

APA

Wolfram Language. (2010). DistributionParameterAssumptions. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html

BibTeX

@misc{reference.wolfram_2026_distributionparameterassumptions, author="Wolfram Research", title="{DistributionParameterAssumptions}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_distributionparameterassumptions, organization={Wolfram Research}, title={DistributionParameterAssumptions}, year={2010}, url={https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html}, note=[Accessed: 15-September-2026]}