WOLFRAM

Wolfram 语言与系统参考资料中心

DistributionParameterAssumptions[dist]

给出符号式分布 dist 中的参数的假定所用的逻辑表达式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DistributionParameterAssumptions

DistributionParameterAssumptions[dist]

给出符号式分布 dist 中的参数的假定所用的逻辑表达式.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (1)

获取正态分布的参数假定：

Wolfram Language code: DistributionParameterAssumptions[NormalDistribution[μ, σ]]

用于多项分布的参数假定：

Wolfram Language code: DistributionParameterAssumptions[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}]]

范围  (4)

获取具有数值和符号式参数的分布的假定：

Wolfram Language code: dists = Table[GammaDistribution[a, b], {a, {α, 1}}, {b, {β, 2}}]//Flatten
Wolfram Language code: Table[{d, DistributionParameterAssumptions[d]}, {d, dists}]//TableForm

获取单变量和多变量离散和连续分布的假定：

Wolfram Language code: validDistributions = {GeometricDistribution[p], ParetoDistribution[k, a], BinormalDistribution[ρ], MultivariatePoissonDistribution[μ, {Subscript[μ, 1], Subscript[μ, 2]}]};
Wolfram Language code: Table[{dist, DistributionParameterAssumptions[dist]}, {dist, validDistributions}]//TableForm

获取导出分布的假定：

Wolfram Language code: tdist = TransformedDistribution[x ^ 3, xPoissonDistribution[μ]];
Wolfram Language code: DistributionParameterAssumptions[tdist]

数据分布不含有参数，因此假定无意义地为真：

Wolfram Language code: ddist = EmpiricalDistribution[Range[10]];
Wolfram Language code: DistributionParameterAssumptions[ddist]

应用  (4)

获取极值分布的概率密度函数：

Wolfram Language code: pdf = PDF[ExtremeValueDistribution[α, β], x]

计算均值的积分，而不包含参数假定：

Wolfram Language code: Integrate[x * pdf, {x, -∞, ∞}]

利用参数假定简化结果：

Wolfram Language code: Assuming[DistributionParameterAssumptions[ExtremeValueDistribution[α, β]], Simplify[%]]

通过直接对 Integrate 给出假定，计算结果：

Wolfram Language code: Integrate[x * pdf, {x, -∞, ∞}, Assumptions -> DistributionParameterAssumptions[ExtremeValueDistribution[α, β]]]

与分布的均值比较：

Wolfram Language code: Mean[ExtremeValueDistribution[α, β]]

定义两个 χ2 分布和它们的参数设定：

Wolfram Language code: dist1 = ChiSquareDistribution[n]; dist2 = ChiSquareDistribution[m]; assumpts = DistributionParameterAssumptions[dist1] && DistributionParameterAssumptions[dist2];

通过与设定参数的卷积计算服从 χ2 分布的变量的和的 pdf：

Wolfram Language code: Convolve[PDF[dist1, t], PDF[dist2, t], t, x, Assumptions -> assumpts]

验证 χ2 变量的可加性：

Wolfram Language code: % == PDF[ChiSquareDistribution[m + n], x]//Simplify

定义一个 Haight 分布，其概率参数为 ：

Wolfram Language code: dist = ProbabilityDistribution[(4 ^ (-1 + k)p((1 - p) * p) ^ (-1 + k)(-(3 / 2) + k)!) / (Sqrt[Pi]k!), {k, 1, Infinity, 1}, Assumptions -> 1 / 2 < p < 1];

计算 PDF 表达式的和以检查归一性：

Wolfram Language code: Sum[PDF[dist, k], {k, 1, Infinity}]

如果没有满足分布的设定，结果不总是为 1：

Wolfram Language code: FullSimplify[%, Not[DistributionParameterAssumptions[dist]]]

对于设定的值 ，对 Sum 给出假设值以验证总的概率为 1：

Wolfram Language code: Sum[PDF[dist, k], {k, 1, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]

获取第一类 Pearson 分布的设定，其中含有未知参数 b1 和 b0：

Wolfram Language code: assumpts = DistributionParameterAssumptions[PearsonDistribution[1, 3, -2, 3, Subscript[b, 1], Subscript[b, 0]]]

求 b1 作为 b0 的函数最大的可能的值：

Wolfram Language code: max = ArgMax[{Subscript[b, 1], assumpts}, Subscript[b, 1]]
Wolfram Language code: Plot[max, {Subscript[b, 0], -10, 10}, Filling -> -20, AxesLabel -> {Subscript[b, 0], Subscript[b, 1]}]

属性和关系  (1)

DistributionParameterAssumptions 返回参数上的条件：

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[n, p]]

DistributionParameterQ 假定参数是有效的：

Wolfram Language code: DistributionParameterQ[BinomialDistribution[n, p]]

在数值参数下，输出是等价的：

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[20, 1 / 3]]
Wolfram Language code: DistributionParameterQ[BinomialDistribution[20, 1 / 3]]
Wolfram Research (2010)，DistributionParameterAssumptions，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

文本

Wolfram Research (2010)，DistributionParameterAssumptions，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

CMS

Wolfram 语言. 2010. "DistributionParameterAssumptions." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

APA

Wolfram 语言. (2010). DistributionParameterAssumptions. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html 年

BibTeX

@misc{reference.wolfram_2026_distributionparameterassumptions, author="Wolfram Research", title="{DistributionParameterAssumptions}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_distributionparameterassumptions, organization={Wolfram Research}, title={DistributionParameterAssumptions}, year={2010}, url={https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html}, note=[Accessed: 08-September-2026]}