WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EllipticFilterModel[n]

次数 n のローパス楕円フィルタを設計する．

EllipticFilterModel[{n,ωc}]

カットオフ周波数 ωcを使う．

EllipticFilterModel[{"type",spec}]

spec を使って指定されたタイプ"type"の楕円フィルタを設計する．

EllipticFilterModel[{"type",spec},var]

変数 var によってモデルを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

EllipticFilterModel

EllipticFilterModel[n]

次数 n のローパス楕円フィルタを設計する．

EllipticFilterModel[{n,ωc}]

カットオフ周波数 ωcを使う．

EllipticFilterModel[{"type",spec}]

spec を使って指定されたタイプ"type"の楕円フィルタを設計する．

EllipticFilterModel[{"type",spec},var]

変数 var によってモデルを表す．

詳細

  • EllipticFilterModelは設計されたフィルタをTransferFunctionModelとして与える．
  • EllipticFilterModel[{n,ω}]は，周波数 ω での減衰（約3dB）のローパスフィルタを返す．
  • EllipticFilterModel[n]はカットオフ周波数1を使う．
  • フィルタ指定{"type",spec}に下のすべての形が使える．
  • {"Lowpass",{ωp,ωs},{ap,as}}パスバンドとストップバンドの周波数と減衰を使ったローパスフィルタ
    {"Highpass",{ωs,ωp},{as,ap}}ハイパスフィルタ指定
    {"Bandpass",{ωs1,ωp1,ωp2,ωs2},{as,ap}}バンドパスフィルタ指定
    {"Bandstop",{ωp1,ωs1,ωs2,ωp2},{ap,as}}バンドストップフィルタ指定
  • 周波数値は昇順で与えられなければならない．
  • 値 apと asはそれぞれパスバンドとストップバンドの減衰の絶対値である．
  • ゲインがの割合 のとき，減衰は である．

例題

すべて開く すべて閉じる

例  (2)

カットオフ周波数 における三次楕円フィルタモデル：

Wolfram Language code: tf = EllipticFilterModel[3]//Chop

フィルタモデルを変数 で表現する：

Wolfram Language code: tf = EllipticFilterModel[3, s]//Chop

フィルタのボード線図：

Wolfram Language code: BodePlot[tf, GridLines -> Automatic, PlotLayout -> "Magnitude"]

完全指定を使ったローパス楕円フィルタ：

Wolfram Language code: tf = EllipticFilterModel[{"Lowpass", {1., 2.}, {1., 20.}}, s]

理想的なフィルタの特徴を示すフィルタの振幅特性：

Wolfram Language code: Plot[Abs[tf[I * ω]], {ω, 0, 3}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, 0.89}, {1, 0.89}, {1, 0.1}}], Line[{{2., 0.89}, {2., 0.1}, {3., 0.1}}]}]

スコープ  (5)

2次ローパスフィルタの記号表現：

Wolfram Language code: EllipticFilterModel[{2, ω}, s]//N//Chop

モデルの厳密計算：

Wolfram Language code: EllipticFilterModel[{2, 1}, s]

24桁精度でのモデルの計算：

Wolfram Language code: EllipticFilterModel[{2, N[1, 24]}, s]

カットオフ周波数10でローパスフィルタモデルを作る：

Wolfram Language code: BodePlot[EllipticFilterModel[{2, 10.}], GridLines -> Automatic, PlotLayout -> "Magnitude"]

ハイパス楕円フィルタを作る：

Wolfram Language code: BodePlot[EllipticFilterModel[{"Highpass", {1., 10.}, {20., 1.}}], {.1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

バンドパス楕円フィルタを作る：

Wolfram Language code: tf = EllipticFilterModel[{"Bandpass", {0.1, 1., 10., 100.}, {20, 1}}]; BodePlot[tf, {0.1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

バンドストップ楕円フィルタを作る：

Wolfram Language code: tf = EllipticFilterModel[{"Bandstop", {0.1, 1., 10., 100.}, {1, 20}}]; BodePlot[tf, {0.1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

アプリケーション  (5)

ローパス楕円フィルタを作る：

Wolfram Language code: tf = EllipticFilterModel[{"Lowpass", {1., 2.}, {1, 40}}];

正弦曲線信号から高周波数ノイズをフィルタアウトする：

Wolfram Language code: ω = 1 / 5;input = (Sin[ω t] + 1 / 2 Sin[25ω t]) UnitStep[t]; response1 = OutputResponse[tf, input, {t, 0, 100}];

楕円フィルタ位相はArg[tf[ω ]]による応答をシフトする．ただし，ω は入力正弦曲線の周波数である：

Wolfram Language code: Plot[{input, response1}, {t, 20, 100}]

位相シフトについて修正する：

Wolfram Language code: delay = Arg[tf[I ω]] / ω//First//First; Plot[Evaluate[Flatten[{input, response1 /. t -> (t - delay)}]], {t, 20, 100}]

ローパスのプロトタイプからハイパス楕円フィルタを作る：

Wolfram Language code: tf2 = TransferFunctionTransform[1 / #&, tf];

低周波数正弦曲線を入力からフィルタアウトする：

Wolfram Language code: Plot[Evaluate[Flatten[{input, OutputResponse[tf2, input, {t, 0, 100}]}]], {t, 20, 100}]

次のパスバンド周波数，ストップバンド周波数，減衰を満足する楕円近似を使ってデジタルローパスフィルタを設計する：

Wolfram Language code: Subscript[ω, p] = 0.4 π;Subscript[ω, s] = 0.6π; Subscript[a, p] = 1;Subscript[a, s] = 20;

サンプリング周期が1であると仮定して，同等のアナログ周波数を得る：

Wolfram Language code: {Subscript[Ω, p] = 2 Tan[(0.4π/2)], Subscript[Ω, s] = 2 Tan[(0.6π/2)]}

アナログ楕円フィルタ伝達関数を計算する：

Wolfram Language code: tf = EllipticFilterModel[{"Lowpass", {Subscript[Ω, p], Subscript[Ω, s]}, {Subscript[a, p], Subscript[a, s]}}, s]

離散時間モデルに変換する：

Wolfram Language code: dtf = ToDiscreteTimeModel[tf, 1, z]//Chop

大きさをプロットする:

Wolfram Language code: BodePlot[dtf, {0.1 π, π}, PlotLayout -> "Magnitude", GridLines -> {{Subscript[ω, p], Subscript[ω, s]}, {10^-Subscript[a, p] / 20, 10^-Subscript[a, s] / 20}}, ScalingFunctions -> {"Linear", "Absolute"}, PlotRange -> All]

離散時間楕円IIRフィルタの長さ31のFIR近似を作成する：

Wolfram Language code: OutputResponse[dtf, KroneckerDelta[n], {n, 0, 30}]//Chop

FIRフィルタをプロットする：

Wolfram Language code: ListPlot[%, PlotRange -> All, Filling -> 0]

楕円フィルタのFIRデータを使って金融データを平滑化する：

Wolfram Language code: data = Transpose[FinancialData["GE", {"Jan. 1, 2012", "Jan. 1, 2013"}]["Path"]]; fir = OutputResponse[ToDiscreteTimeModel[EllipticFilterModel[{3, 0.66}], 1], KroneckerDelta[n], {n, 0, 100}]//Chop//Flatten; DateListPlot[{Transpose[data], Transpose[{data[[1]], -ListConvolve[fir, data[[2]], 4]}]}, PlotRange -> All, PlotLegends -> {"original", "smoothed"}]

ローパス楕円フィルタを使って画像にフィルタをかける：

Wolfram Language code: h = ToDiscreteTimeModel[EllipticFilterModel[{"Lowpass", {1., 2.}, {1., 20.}}], 1]; RecurrenceFilter[h, [image]]

ハイパス楕円フィルタを使って画像にフィルタをかける：

Wolfram Language code: h = ToDiscreteTimeModel[EllipticFilterModel[{"Highpass", {.5, 1.}, {20., 1.}}], 1]; RecurrenceFilter[h, [image]]

特性と関係  (3)

楕円フィルタの次数を抽出する：

Wolfram Language code: SystemsModelOrder[StateSpaceModel[EllipticFilterModel[{"Highpass", {1, 1.2}, {20, 3}}]]]

楕円フィルタの極と零点を抽出する：

Wolfram Language code: tf = EllipticFilterModel[7];
Wolfram Language code: TransferFunctionPoles[tf]//Chop
Wolfram Language code: TransferFunctionZeros[tf]//Chop

ローパスフィルタをハイパスフィルタに変換する：

Wolfram Language code: lo = EllipticFilterModel[{3, .5}]; hi = TransferFunctionTransform[(1 / #&), lo]//Chop
Wolfram Language code: Plot[{Abs[lo[I w]], Abs[hi[I w]]}, {w, 0, 3}, PlotRange -> All]
Wolfram Research (2012), EllipticFilterModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticFilterModel.html.

テキスト

Wolfram Research (2012), EllipticFilterModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticFilterModel.html.

CMS

Wolfram Language. 2012. "EllipticFilterModel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EllipticFilterModel.html.

APA

Wolfram Language. (2012). EllipticFilterModel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticFilterModel.html

BibTeX

@misc{reference.wolfram_2026_ellipticfiltermodel, author="Wolfram Research", title="{EllipticFilterModel}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticFilterModel.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticfiltermodel, organization={Wolfram Research}, title={EllipticFilterModel}, year={2012}, url={https://reference.wolfram.com/language/ref/EllipticFilterModel.html}, note=[Accessed: 08-September-2026]}