WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EstimatedBackground[data]

data の背景を推定する．

EstimatedBackground[data,σ]

峰をスケール σ まで保存しようとする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Padding  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

EstimatedBackground

EstimatedBackground[data]

data の背景を推定する．

EstimatedBackground[data,σ]

峰をスケール σ まで保存しようとする．

詳細とオプション

  • EstimatedBackgroundは，入力リストの特徴を保存しようとしつつ，背景またはベースラインを推定する．
  • 入力 data には次の形式が使える．
  • {y1,y2,…}値のリスト
    TimeSeries[…]時系列オブジェクト
    EventSeries[…]事象系列オブジェクト
  • 使用可能なオプション
  • MethodAutomatic使用するメソッド
    Padding "Reversed"使用する充填方法
  • EstimatedBackgroundはMethodオプションを取る．以下は可能な設定値である．
  • "MovingAverage"移動平均背景推定
    {"SNIP",r}統計に敏感な非線形反復峰切取り

例題

すべて開く すべて閉じる

例  (2)

リストのベースラインを推定する：

Wolfram Language code: data = {2, 1, 3, 5, 6, 6, 4, 3, 2, 4, 7, 3, 2, 4, 2, 2, 1};
Wolfram Language code: base = EstimatedBackground[data]
Wolfram Language code: ListLinePlot[{data, base}]

もとのデータからベースラインを除き，リストを視覚的に比較する：

Wolfram Language code: ListLinePlot[{data, data - base}]

正弦波信号の背景を推定する：

Wolfram Language code: data = Table[Sin[i] + .1Sin[10 i], {i, 0, 2Pi, 0.01}]; ListLinePlot[{data, EstimatedBackground[data]}]

スコープ  (4)

背景はスケールに依存する．デフォルトで，自動計算されたスケールが使われる：

Wolfram Language code: data = FinancialData["GE", {"Jun 2010", "Jan 2011"}, "Value"];
Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data]}]

スケール で，背景が入力データの忠実な推定となる：

Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data, 0]}]

別のスケールを指定する：

Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data, 10]}]

異なるスケールの比較：

Wolfram Language code: list = Range[5, 20, 5]; ListLinePlot[Prepend[EstimatedBackground[data, #]& /@ list, data], PlotLegends -> Prepend["σ = " <> ToString[#]& /@ list, "Original"], Filling -> Table[i -> {i + 1}, {i, 1, Length[list]}]]

Quantityオブジェクトのベースラインを推定する：

Wolfram Language code: data = WeatherData["New York", "Temperature", {"2010", "2012", "Month"}, "Value"]
Wolfram Language code: EstimatedBackground[data]

等間隔TimeSeriesオブジェクトのベースラインを推定する：

Wolfram Language code: ts = TimeSeries[FinancialData["MSFT", "Jan. 1, 2008"], TemporalRegularity -> True]
Wolfram Language code: base = EstimatedBackground[ts]
Wolfram Language code: DateListPlot[{ts, EstimatedBackground[ts]}]

不規則にサンプルされたTimeSeriesオブジェクトのベースラインを推定する：

Wolfram Language code: v = {2, 1, 6, 5, 7, 4}; t = {1, 2, 5, 10, 12, 15}; ts = TimeSeries[v, {t}]
Wolfram Language code: RegularlySampledQ[ts]
Wolfram Language code: EstimatedBackground[ts]
Wolfram Language code: DateListPlot[{ts, %}]

オプション  (1)

Padding  (1)

デフォルトの充填は"Reversed"である：

Wolfram Language code: data = Sin[Range[0, 1, 1 / 50]] + RandomReal[.5, 51]; ListLinePlot[{data, EstimatedBackground[data]}]

別の充填を指定する：

Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data, Padding -> "Periodic"]}]

アプリケーション  (2)

最近の黒点活動から背景を推定し，減算する：

Wolfram Language code: data = WolframAlpha["sunspot", {{"SunspotsPartialTimeSeries:SpaceWeatherData", 1}, "TimeSeriesData"}][[All, 2]];
Wolfram Language code: bg = EstimatedBackground[data];
Wolfram Language code: ListLinePlot[{data, bg}, AspectRatio -> 1 / 3]

背景を減算してからデータをプロットする：

Wolfram Language code: ListLinePlot[data - bg, AspectRatio -> 1 / 3]

12月におけるシカゴの1時間ごとの気温：

Wolfram Language code: temp = WeatherData["Chicago", "Temperature", {{2014, 12, 1, 0, 0}, {2014, 12, 31, 23, 59}, All}]
Wolfram Language code: DateListPlot[temp]

このプロットは，データに欠測値があることを示している．MissingDataMethodを指定し，背景を推定する：

Wolfram Language code: res = EstimatedBackground[data = TimeSeries[temp, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}]]
Wolfram Language code: DateListPlot[{data, res}]

もとのデータから背景を引いた時系列を作る：

Wolfram Language code: diff = TimeSeriesThread[Subtract[#[[1]], #[[2]]]&, {data, res}]
Wolfram Language code: DateListPlot[diff]

弱定常時系列モデルをフィットする：

Wolfram Language code: model = TimeSeriesModelFit[TimeSeriesResample[diff]]
Wolfram Language code: model["Process"]

特性と関係  (1)

"MovingAverage"は充填された入力のMovingAverageを計算する：

Wolfram Language code: data = Table[Sin[i] + .1Sin[10 i], {i, 0, 2Pi, 0.01}]; r = 10;
Wolfram Language code: bg1 = EstimatedBackground[data, r, Method -> "MovingAverage"]; bg2 = MovingAverage[ArrayPad[data, r, "Reversed"], 2r + 1];
Wolfram Language code: bg1 == bg2
Wolfram Research (2014), EstimatedBackground, Wolfram言語関数， https://reference.wolfram.com/language/ref/EstimatedBackground.html.

テキスト

Wolfram Research (2014), EstimatedBackground, Wolfram言語関数， https://reference.wolfram.com/language/ref/EstimatedBackground.html.

CMS

Wolfram Language. 2014. "EstimatedBackground." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedBackground.html.

APA

Wolfram Language. (2014). EstimatedBackground. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EstimatedBackground.html

BibTeX

@misc{reference.wolfram_2026_estimatedbackground, author="Wolfram Research", title="{EstimatedBackground}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedBackground.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedbackground, organization={Wolfram Research}, title={EstimatedBackground}, year={2014}, url={https://reference.wolfram.com/language/ref/EstimatedBackground.html}, note=[Accessed: 06-September-2026]}