WOLFRAM

Wolfram 语言与系统参考资料中心

EstimatedBackground[data]

估计 data 的背景.

EstimatedBackground[data,σ]

尝试保留尺度为 σ 以内的峰值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Padding  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EstimatedBackground

EstimatedBackground[data]

估计 data 的背景.

EstimatedBackground[data,σ]

尝试保留尺度为 σ 以内的峰值.

更多信息和选项

  • EstimatedBackground 估计背景或基线，同时试图保持输入列表的特征.
  • 输入 data 可以是下列形式之一：
  • {y1,y2,…}一个值列表
    TimeSeries[…]时间序列对象
    EventSeries[…]事件序列对象
  • 可以给出以下选项：
  • MethodAutomatic所用方法
    Padding "Reversed"所用的填充方案
  • EstimatedBackground 接受 Method 选项. 可能的设置为：
  • "MovingAverage"移动平均背景估计
    {"SNIP",r}统计敏感的非线性迭代削峰

范例

打开所有单元 关闭所有单元

基本范例  (2)

估计列表的基线：

Wolfram Language code: data = {2, 1, 3, 5, 6, 6, 4, 3, 2, 4, 7, 3, 2, 4, 2, 2, 1};
Wolfram Language code: base = EstimatedBackground[data]
Wolfram Language code: ListLinePlot[{data, base}]

删除原始数据的基线，并通过视图比较列表：

Wolfram Language code: ListLinePlot[{data, data - base}]

估计正弦信号的背景：

Wolfram Language code: data = Table[Sin[i] + .1Sin[10 i], {i, 0, 2Pi, 0.01}]; ListLinePlot[{data, EstimatedBackground[data]}]

范围  (4)

背景是依赖尺度的；在缺省情况下，使用自动计算的尺度：

Wolfram Language code: data = FinancialData["GE", {"Jun 2010", "Jan 2011"}, "Value"];
Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data]}]

在尺度 时，背景是输入数据的接近估计：

Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data, 0]}]

指定不同尺度：

Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data, 10]}]

不同尺度的比较：

Wolfram Language code: list = Range[5, 20, 5]; ListLinePlot[Prepend[EstimatedBackground[data, #]& /@ list, data], PlotLegends -> Prepend["σ = " <> ToString[#]& /@ list, "Original"], Filling -> Table[i -> {i + 1}, {i, 1, Length[list]}]]

比较 Quantity 对象的基线：

Wolfram Language code: data = WeatherData["New York", "Temperature", {"2010", "2012", "Month"}, "Value"]
Wolfram Language code: EstimatedBackground[data]

估计规则采样的 TimeSeries 对象的基线：

Wolfram Language code: ts = TimeSeries[FinancialData["MSFT", "Jan. 1, 2008"], TemporalRegularity -> True]
Wolfram Language code: base = EstimatedBackground[ts]
Wolfram Language code: DateListPlot[{ts, EstimatedBackground[ts]}]

估计不规则采样的 TimeSeries 对象的基线：

Wolfram Language code: v = {2, 1, 6, 5, 7, 4}; t = {1, 2, 5, 10, 12, 15}; ts = TimeSeries[v, {t}]
Wolfram Language code: RegularlySampledQ[ts]
Wolfram Language code: EstimatedBackground[ts]
Wolfram Language code: DateListPlot[{ts, %}]

选项  (1)

Padding  (1)

默认填充为 "Reversed"：

Wolfram Language code: data = Sin[Range[0, 1, 1 / 50]] + RandomReal[.5, 51]; ListLinePlot[{data, EstimatedBackground[data]}]

指定不同的填充：

Wolfram Language code: ListLinePlot[{data, EstimatedBackground[data, Padding -> "Periodic"]}]

应用  (2)

估计并提取近期太阳黑子活动中的背景：

Wolfram Language code: data = WolframAlpha["sunspot", {{"SunspotsPartialTimeSeries:SpaceWeatherData", 1}, "TimeSeriesData"}][[All, 2]];
Wolfram Language code: bg = EstimatedBackground[data];
Wolfram Language code: ListLinePlot[{data, bg}, AspectRatio -> 1 / 3]

绘制背景删除后的数据：

Wolfram Language code: ListLinePlot[data - bg, AspectRatio -> 1 / 3]

12月份芝加哥的每小时气温：

Wolfram Language code: temp = WeatherData["Chicago", "Temperature", {{2014, 12, 1, 0, 0}, {2014, 12, 31, 23, 59}, All}]
Wolfram Language code: DateListPlot[temp]

图线表明数据包含缺失数据. 指定 MissingDataMethod 并且估计背景：

Wolfram Language code: res = EstimatedBackground[data = TimeSeries[temp, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}]]
Wolfram Language code: DateListPlot[{data, res}]

创建原始数据减去背景的时间序列：

Wolfram Language code: diff = TimeSeriesThread[Subtract[#[[1]], #[[2]]]&, {data, res}]
Wolfram Language code: DateListPlot[diff]

拟合每周稳态时间序列模型：

Wolfram Language code: model = TimeSeriesModelFit[TimeSeriesResample[diff]]
Wolfram Language code: model["Process"]

属性和关系  (1)

"MovingAverage" 计算填充输入的 MovingAverage：

Wolfram Language code: data = Table[Sin[i] + .1Sin[10 i], {i, 0, 2Pi, 0.01}]; r = 10;
Wolfram Language code: bg1 = EstimatedBackground[data, r, Method -> "MovingAverage"]; bg2 = MovingAverage[ArrayPad[data, r, "Reversed"], 2r + 1];
Wolfram Language code: bg1 == bg2
Wolfram Research (2014)，EstimatedBackground，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedBackground.html.

文本

Wolfram Research (2014)，EstimatedBackground，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EstimatedBackground.html.

CMS

Wolfram 语言. 2014. "EstimatedBackground." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedBackground.html.

APA

Wolfram 语言. (2014). EstimatedBackground. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EstimatedBackground.html 年

BibTeX

@misc{reference.wolfram_2026_estimatedbackground, author="Wolfram Research", title="{EstimatedBackground}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedBackground.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedbackground, organization={Wolfram Research}, title={EstimatedBackground}, year={2014}, url={https://reference.wolfram.com/language/ref/EstimatedBackground.html}, note=[Accessed: 14-September-2026]}