WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExactBlackmanWindow[x]

x の厳密なBlackman窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ExactBlackmanWindow

ExactBlackmanWindow[x]

x の厳密なBlackman窓関数を表す．

詳細

  • ExactBlackmanWindowは，一般に，有限インパルス応答(FIR)フィルタ設計とスペクトル解析で使われる窓関数である．
  • 窓関数は，データが短いセグメントで処理されるアプリケーションに使われ，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • ExactBlackmanWindow[x]は (4620 cos(2 pi x)+715 cos(4 pi x)+3969)/(9304) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • ExactBlackmanWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1D厳密Blackman窓の形：

Wolfram Language code: Plot[ExactBlackmanWindow[x], {x, -1, 1}]

2D厳密Blackman窓の形：

Wolfram Language code: Plot3D[ExactBlackmanWindow[x]ExactBlackmanWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

厳密Blackman窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[ExactBlackmanWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: ExactBlackmanWindow[0.1]

平行移動され広げられた厳密なBlackman窓：

Wolfram Language code: Plot[ExactBlackmanWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ厳密な2DBlackman窓：

Wolfram Language code: Plot3D[ExactBlackmanWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の厳密な離散Blackman窓：

Wolfram Language code: ListPlot[Array[ExactBlackmanWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の厳密な2D離散Blackman窓：

Wolfram Language code: ListPointPlot3D[Array[ExactBlackmanWindow[#1] ExactBlackmanWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

アプリケーション  (3)

長さ11の移動平均フィルタを作る：

Wolfram Language code: a = ConstantArray[1 / 11, 11]

厳密Blackman窓を使ってフィルタを平滑化する：

Wolfram Language code: a2 = # / Total[#]&[a Array[ExactBlackmanWindow, 11, {-1 / 2, 1 / 2}]];

フィルタの周波数スペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {a, a2}], {ω, 0.0314, Pi}, PlotRange -> All, GridLines -> Automatic, ImageSize -> 300]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, ExactBlackmanWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> ExactBlackmanWindow}]

特性と関係  (2)

厳密Blackman窓の下の面積：

Wolfram Language code: area = Integrate[ExactBlackmanWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{ExactBlackmanWindow[x], ExactBlackmanWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

厳密Blackman窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[ExactBlackmanWindow[x], x, w]

厳密Blackman窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012), ExactBlackmanWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html.

テキスト

Wolfram Research (2012), ExactBlackmanWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html.

CMS

Wolfram Language. 2012. "ExactBlackmanWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html.

APA

Wolfram Language. (2012). ExactBlackmanWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html

BibTeX

@misc{reference.wolfram_2026_exactblackmanwindow, author="Wolfram Research", title="{ExactBlackmanWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exactblackmanwindow, organization={Wolfram Research}, title={ExactBlackmanWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html}, note=[Accessed: 14-September-2026]}