WOLFRAM

Wolfram 语言与系统参考资料中心

ExactBlackmanWindow[x]

表示 x 的精确 Blackman 窗函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ExactBlackmanWindow

ExactBlackmanWindow[x]

表示 x 的精确 Blackman 窗函数.

更多信息

  • ExactBlackmanWindow 是一个窗函数，通常用于设计有限冲激响应 (FIR) 滤波器和进行频谱分析.
  • 窗函数被用在以较短的片段来处理数据的应用中，并且通过在每个片段的末尾将数据值逐渐减小为零来产生平滑效果.
  • ExactBlackmanWindow[x] 等于 (4620 cos(2 pi x)+715 cos(4 pi x)+3969)/(9304) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2;
  • ExactBlackmanWindow 自动逐项作用于列表的各个元素.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维精确 Blackman 窗的形状：

Wolfram Language code: Plot[ExactBlackmanWindow[x], {x, -1, 1}]

二维精确 Blackman 窗的形状：

Wolfram Language code: Plot3D[ExactBlackmanWindow[x]ExactBlackmanWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示精确 Blackman 窗的连续函数：

Wolfram Language code: FunctionExpand[ExactBlackmanWindow[x]]

范围  (4)

数值计算：

Wolfram Language code: ExactBlackmanWindow[0.1]

精确 Blackman 窗的变换和扩张：

Wolfram Language code: Plot[ExactBlackmanWindow[(x - 1) / 2], {x, -1, 3}]

具有圆形支持的二维精确 Blackman 窗：

Wolfram Language code: Plot3D[ExactBlackmanWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

长度为15的离散精确 Blackman 窗：

Wolfram Language code: ListPlot[Array[ExactBlackmanWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散 15×10 二维精确 Blackman 窗：

Wolfram Language code: ListPointPlot3D[Array[ExactBlackmanWindow[#1] ExactBlackmanWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

应用  (3)

创建长度为11的平移均值滤波器：

Wolfram Language code: a = ConstantArray[1 / 11, 11]

使用精确 Blackman 窗进行滤波器平滑：

Wolfram Language code: a2 = # / Total[#]&[a Array[ExactBlackmanWindow, 11, {-1 / 2, 1 / 2}]];

滤波器的频率谱的对数-幅值图线：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {a, a2}], {ω, 0.0314, Pi}, PlotRange -> All, GridLines -> Automatic, ImageSize -> 300]

使用窗指定，计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, ExactBlackmanWindow];

与不用窗函数计算得到的谱密度比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

下图显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

将窗指定用于时间序列估计：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> ExactBlackmanWindow}]

属性和关系  (2)

精确 Blackman 窗下的面积：

Wolfram Language code: area = Integrate[ExactBlackmanWindow[x], {x, -∞, ∞}]

规范化以创建单位面积的窗：

Wolfram Language code: Plot[{ExactBlackmanWindow[x], ExactBlackmanWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

精确 Blackman 窗的傅里叶变换：

Wolfram Language code: f = FourierTransform[ExactBlackmanWindow[x], x, w]

精确 Blackman 窗的功率谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012)，ExactBlackmanWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html.

文本

Wolfram Research (2012)，ExactBlackmanWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html.

CMS

Wolfram 语言. 2012. "ExactBlackmanWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html.

APA

Wolfram 语言. (2012). ExactBlackmanWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html 年

BibTeX

@misc{reference.wolfram_2026_exactblackmanwindow, author="Wolfram Research", title="{ExactBlackmanWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_exactblackmanwindow, organization={Wolfram Research}, title={ExactBlackmanWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/ExactBlackmanWindow.html}, note=[Accessed: 08-August-2026]}