WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FareySequence[n]

次数 n のファレイ(Farey)数列を生成する．

FareySequence[n,k]

次数 n のファレイ数列の k 番目の要素を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
関連リンク
履歴
引用書式

FareySequence

FareySequence[n]

次数 n のファレイ(Farey)数列を生成する．

FareySequence[n,k]

次数 n のファレイ数列の k 番目の要素を与える．

詳細

  • 次数 n のファレイ数列は，n より小さい分母を持つ，0から1までの完全既約分数を昇順にならべた数列である．

例題

すべて開く すべて閉じる

例  (1)

次数5のファレイ数列を生成する：

Wolfram Language code: FareySequence[5]

次数24のファレイ数列の17番目の要素を求める：

Wolfram Language code: FareySequence[24, 17]

スコープ  (1)

次数3のファレイ数列を与える：

Wolfram Language code: FareySequence[3]

次数3のファレイ数列の第2番項を与える：

Wolfram Language code: FareySequence[3, 2]

アプリケーション  (5)

ファレイ数列で隣接する有理数を連結した，ファレイの弧の線図：

Wolfram Language code: FareyPairArc[r1_, r2_] := Circle[{(r1 + r2) / 2, 0}, (r2 - r1) / 2, {0, Pi}]
Wolfram Language code: Table[Graphics[{ColorData[94, n], FareyPairArc@@@Partition[FareySequence[n], 2, 1]}, PlotLabel -> n], {n, 1, 6}]

一緒に示す：

Wolfram Language code: Show[%]

次数12のファレイ数列の分母のパターンを可視化する：

Wolfram Language code: Denominator /@ FareySequence[12]
Wolfram Language code: MatrixPlot[SparseArray[MapIndexed[Prepend[#2, #1] -> 1&, %]], Mesh -> All]

次数の低いいくつかのファレイ数列の長さ：

Wolfram Language code: Table[Length[FareySequence[n]], {n, 1, 12}]

Eulerのファイ関数による閉形式の式と比較する：

Wolfram Language code: Table[1 + Underoverscript[∑, k = 1, n]EulerPhi[k], {n, 1, 12}]

いくつかの小さい次数についてのファレイ数列のすべての非零要素の積：

Wolfram Language code: Table[Apply[Times, Rest[FareySequence[n]]], {n, 2, 12}]

閉じた形の式と比較する：

Wolfram Language code: Table[Underoverscript[∏, k = 1, n]((BarnesG[Quotient[n, k] + 2]/Hyperfactorial[Quotient[n, k]]))^MoebiusMu[k], {n, 2, 12}]

ファレイ数列からFordの円を作る：

Wolfram Language code: FordCircle[r_] := With[{den = (2 Denominator[r] ^ 2)}, Disk[{r, 1 / den}, 1 / den]]
Wolfram Language code: Graphics[{GrayLevel[3 / (2 + 3Denominator[#])], Tooltip[FordCircle[#], #]}& /@ FareySequence[10], PlotRange -> {{0, 1}, {0, 1}}]

特性と関係  (2)

Subdivideリストの和集合としてファレイ数列を得る：

Wolfram Language code: FareySequence[5]
Wolfram Language code: % === Union@@(Subdivide /@ Range[5])

FareySequence[n,k]はFareySequence[n]〚k〛に等しい：

Wolfram Language code: FareySequence[50, 500]
Wolfram Language code: FareySequence[50][[500]]

FareySequence[n,k]の方がはるかに速い：

Wolfram Language code: FareySequence[5000, 1000000]//AbsoluteTiming
Wolfram Language code: FareySequence[5000][[1000000]]//AbsoluteTiming
Wolfram Research (2014), FareySequence, Wolfram言語関数， https://reference.wolfram.com/language/ref/FareySequence.html （2016年に更新）.

テキスト

Wolfram Research (2014), FareySequence, Wolfram言語関数， https://reference.wolfram.com/language/ref/FareySequence.html （2016年に更新）.

CMS

Wolfram Language. 2014. "FareySequence." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/FareySequence.html.

APA

Wolfram Language. (2014). FareySequence. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FareySequence.html

BibTeX

@misc{reference.wolfram_2026_fareysequence, author="Wolfram Research", title="{FareySequence}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/FareySequence.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_fareysequence, organization={Wolfram Research}, title={FareySequence}, year={2016}, url={https://reference.wolfram.com/language/ref/FareySequence.html}, note=[Accessed: 04-September-2026]}