WOLFRAM

Wolfram 语言与系统参考资料中心

FindGeometricConjectures[scene]

找到看上去对 GeometricScene 对象 scene 成立的猜想，并将这些猜想添加到场景对象中.

FindGeometricConjectures[{scene1,scene2,…}]

找到看上去对所有几何场景 scenei 都成立的猜想，并返回已添加了猜想的组合场景.

FindGeometricConjectures[scenes,patt]

只添加与模式 patt 匹配的猜想.

FindGeometricConjectures[scenes,patt,n]

最多添加 n 个猜想.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
参见
技术笔记
相关指南
历史
按以下格式引用：

FindGeometricConjectures

FindGeometricConjectures[scene]

找到看上去对 GeometricScene 对象 scene 成立的猜想，并将这些猜想添加到场景对象中.

FindGeometricConjectures[{scene1,scene2,…}]

找到看上去对所有几何场景 scenei 都成立的猜想，并返回已添加了猜想的组合场景.

FindGeometricConjectures[scenes,patt]

只添加与模式 patt 匹配的猜想.

FindGeometricConjectures[scenes,patt,n]

最多添加 n 个猜想.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

表示具有外接三角形的场景，其直径为一条边：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, o}, {Triangle[{a, b, c}], CircleThrough[{a, b, c}, o], o == Midpoint[{a, c}]}]]

求似乎适合该场景的猜想：

Wolfram Language code: FindGeometricConjectures[%]

发现泰勒斯定理：

Wolfram Language code: FindGeometricConjectures[%, PlanarAngle[{__}] == 90°]["Conclusions"]

范围  (2)

找到具有两组共线点的场景的两个实例：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d, e, f, x, y, z}, {Line[{{a, b, c}}], Line[{d, e, f}], Line[{a, x, e}], Line[{b, x, d}], Line[{a, y, f}], Line[{c, y, d}], Line[{b, z, f}], Line[{c, z, e}], Style[InfiniteLine[{x, z}], Red]}], 2, RandomSeeding -> 1]

通过搜索同时满足两个实例的猜想来发现帕普斯六边形定理：

Wolfram Language code: FindGeometricConjectures[%]["Conclusions"]

用五角星表示一个场景，其中一些角度已知：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d, e, f, g, h, i, j}, {Line[{a, b, c, d}], Line[{d, e, f, g}], Line[{g, h, b, i}], Line[{i, c, e, j}], Line[{j, f, h, a}], PlanarAngle[{b, c, e}, "Counterclockwise"] == 100°, PlanarAngle[{f, h, b}, "Counterclockwise"] == 110°, PlanarAngle[{h, a, b}, "Counterclockwise"] == 35°}], RandomSeeding -> 1234]

求解未知的角：

Wolfram Language code: FindGeometricConjectures[%, PlanarAngle[{__}] == _ ? NumericQ][ "Conclusions"]

仅返回一个未知的角：

Wolfram Language code: FindGeometricConjectures[%%, PlanarAngle[{__}] == _ ? NumericQ, 1][ "Conclusions"]

应用  (2)

迭代式取外心：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, o, oa, ob, oc, k}, {o == TriangleCenter[{a, b, c}, "Circumcenter"], oa == TriangleCenter[{o, b, c}, "Circumcenter"], ob == TriangleCenter[{a, o, c}, "Circumcenter"], oc == TriangleCenter[{a, b, o}, "Circumcenter"], Line[{a, k, oa}], Line[{b, k, ob}], Line[{c, oc}]}], RandomSeeding -> 17]

发现 Kosnita 定理：

Wolfram Language code: FindGeometricConjectures[%]["Conclusions"]

描述两个正方形的场景，通过取中点形成四边形：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d, bb, cc, dd, q, r, s, t}, {GeometricAssertion[{Polygon[{a, b, c, d}], Polygon[{a, bb, cc, dd}]}, "Regular", "Counterclockwise"], q == Midpoint[{bb, d}], r == Midpoint[{a, c}], s == Midpoint[{b, dd}], t == Midpoint[{a, cc}], Style[Polygon[{q, r, s, t}], Opacity[0.4], Red]}], RandomSeeding -> 1]

发现 Finsler–Hadwiger 定理：

Wolfram Language code: FindGeometricConjectures[%, GeometricAssertion[_, "Regular"]]["Conclusions"]
Wolfram Research (2019)，FindGeometricConjectures，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindGeometricConjectures.html.

文本

Wolfram Research (2019)，FindGeometricConjectures，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindGeometricConjectures.html.

CMS

Wolfram 语言. 2019. "FindGeometricConjectures." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FindGeometricConjectures.html.

APA

Wolfram 语言. (2019). FindGeometricConjectures. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FindGeometricConjectures.html 年

BibTeX

@misc{reference.wolfram_2026_findgeometricconjectures, author="Wolfram Research", title="{FindGeometricConjectures}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/FindGeometricConjectures.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_findgeometricconjectures, organization={Wolfram Research}, title={FindGeometricConjectures}, year={2019}, url={https://reference.wolfram.com/language/ref/FindGeometricConjectures.html}, note=[Accessed: 07-September-2026]}