WOLFRAM

Wolfram 语言与系统参考资料中心

FindThreshold[image]

求把 image 中的亮度值划分为两个区间的全局阈值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Method  
应用  
参见
技术笔记
相关指南
历史
按以下格式引用：

FindThreshold

FindThreshold[image]

求把 image 中的亮度值划分为两个区间的全局阈值.

更多信息和选项

  • 阈值是二元聚类或分割最常用的技术之一.
  • FindThreshold 可用于二维和三维图像，以及任意阶数的数据数组. 它将多通道和彩色图像转化为灰度级图像，然后找到一个全局阈值.
  • FindThreshold[image,Method->method] 指定用来决定阈值的方法.
  • Method 选项的可能设置包括：
  • {"BlackFraction",b}使得所有像素中的一定比例 b 变成黑色
    "Cluster"聚类方差最大化（Otsu 算法）
    "Entropy"直方图熵最大化（Kapur 方法）
    "Mean"将平均像素级作为阈值使用
    "Median"将中位数像素级作为阈值使用
    "MinimumError"Kittler–Illingworth 最小误差阈值方法
  • 默认设置为 Method->"Cluster".

范例

打开所有单元 关闭所有单元

基本范例  (1)

求像素亮度的阈值：

Wolfram Language code: i = [image]; FindThreshold[i]

使用阈值运算图像二值化：

Wolfram Language code: Binarize[i, %]

范围  (3)

求数据数组的聚类阈值：

Wolfram Language code: FindThreshold[{1, 2, 3, 10, 11}]

找到分割彩色图像的阈值：

Wolfram Language code: i = [image]; Binarize[i, FindThreshold[i]]

求三维立体的阈值：

Wolfram Language code: FindThreshold[[image]]

选项  (5)

Method  (5)

默认情况下使用最大化两个簇之间的方差的 "Cluster" 方法：

Wolfram Language code: r = RandomReal[MixtureDistribution[{3 / 5, 2 / 5}, {NormalDistribution[1, 1 / 2], NormalDistribution[2, 1 / 6]}], 10 ^ 6]; t = FindThreshold[r]

显示直方图并计算阈值：

Wolfram Language code: Histogram[r, 50, Epilog -> {Blue, InfiniteLine[{t, 0}, {0, 1}]}]

用 "MinimumError" 方法对从两个高斯分布抽取的数据进行分类：

Wolfram Language code: r = RandomReal[MixtureDistribution[{3 / 5, 2 / 5}, {NormalDistribution[1, 1 / 2], NormalDistribution[2, 1 / 6]}], 10 ^ 6]; t = FindThreshold[r, Method -> "MinimumError"]

显示直方图并计算阈值：

Wolfram Language code: Histogram[r, 50, Epilog -> {Blue, InfiniteLine[{t, 0}, {0, 1}]}]

使用 "BlackFraction" 方法指定多少数据应该位于阈值以下：

Wolfram Language code: r = RandomReal[NormalDistribution[1, 1 / 2], 10 ^ 6];
Wolfram Language code: Table[ t = FindThreshold[r, Method -> {"BlackFraction", f}];Histogram[r, 50, Epilog -> {Blue, InfiniteLine[{t, 0}, {0, 1}]}], {f, {.2, .5, .8}}]

比较不同方法返回的阈值：

Wolfram Language code: r = RandomReal[MixtureDistribution[{3 / 5, 2 / 5}, {NormalDistribution[1, 1 / 2], NormalDistribution[2, 1 / 6]}], 10 ^ 6];
Wolfram Language code: Table[ t = FindThreshold[r, Method -> method];Histogram[r, 50, Epilog -> {Blue, InfiniteLine[{t, 0}, {0, 1}]}, PlotLabel -> method, Axes -> {True, False}], {method, {"Cluster", {"BlackFraction", .5}, "Entropy", "Mean", "Median", "MinimumError"}}]

计算彩色图像的阈值并比较每种方法的值：

Wolfram Language code: methods = {{"BlackFraction", 0.6}, "Cluster", "Entropy", "Mean", "Median", "MinimumError"};
Wolfram Language code: i = [image];
Wolfram Language code: With[{t = FindThreshold[i, Method -> #]}, {#, t, Binarize[i, t]}]& /@ methods//TextGrid[#, Frame -> All]&

应用  (1)

求一个文本图像中字母的垂直维度的阈值：

Wolfram Language code: i = [image]; l = FindThreshold[(Differences /@ ComponentMeasurements[i, "BoundingBox"][[All, 2]])[[All, 1, 2]]]

选择垂直维度比阈值长的字母：

Wolfram Language code: SelectComponents[i, Differences[#BoundingBox][[1, 2]] > l&]

在原始图像中突出显示这些字母：

Wolfram Language code: HighlightImage[i, %]
Wolfram Research (2010)，FindThreshold，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindThreshold.html （更新于 2012 年）.

文本

Wolfram Research (2010)，FindThreshold，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindThreshold.html （更新于 2012 年）.

CMS

Wolfram 语言. 2010. "FindThreshold." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2012. https://reference.wolfram.com/language/ref/FindThreshold.html.

APA

Wolfram 语言. (2010). FindThreshold. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FindThreshold.html 年

BibTeX

@misc{reference.wolfram_2026_findthreshold, author="Wolfram Research", title="{FindThreshold}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/FindThreshold.html}", note=[Accessed: 12-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_findthreshold, organization={Wolfram Research}, title={FindThreshold}, year={2012}, url={https://reference.wolfram.com/language/ref/FindThreshold.html}, note=[Accessed: 12-October-2026]}