WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FoldWhile[f,x,{a1,a2,…},test]

test を適用してもTrueとならない最初の式 f[… f[f[x,a1],a2]…,ak]を返す．

FoldWhile[f,list,test]

FoldWhile[f,First[list],Rest[list],test]と等価である．

FoldWhile[f,x,{a1,a2,…},test,m]

直近の m 個の結果を各ステップにおける test についての引数として返す．

FoldWhile[f,x,{a1,a2,…},test,All]

そこまでのすべての結果を各ステップの test についての引数として与える．

FoldWhile[f,x,{a1,a2,…},test,m,n]

test が失敗した後で f を余分に n 回適用した後の結果を返す．

FoldWhile[f,x,{a1,a2,…},test,m,-n]

f を n 回少なく適用して求まった結果を返す．

FoldWhile[f,test]

式に適用可能なFoldWhileの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

FoldWhile

FoldWhile[f,x,{a1,a2,…},test]

test を適用してもTrueとならない最初の式 f[… f[f[x,a1],a2]…,ak]を返す．

FoldWhile[f,list,test]

FoldWhile[f,First[list],Rest[list],test]と等価である．

FoldWhile[f,x,{a1,a2,…},test,m]

直近の m 個の結果を各ステップにおける test についての引数として返す．

FoldWhile[f,x,{a1,a2,…},test,All]

そこまでのすべての結果を各ステップの test についての引数として与える．

FoldWhile[f,x,{a1,a2,…},test,m,n]

test が失敗した後で f を余分に n 回適用した後の結果を返す．

FoldWhile[f,x,{a1,a2,…},test,m,-n]

f を n 回少なく適用して求まった結果を返す．

FoldWhile[f,test]

式に適用可能なFoldWhileの演算子形を表す．

詳細

例題

すべて開く すべて閉じる

例  (3)

結果が非整数になるまで5!を連続する正の整数で割り続ける：

Wolfram Language code: FoldWhile[Divide, 5!, Range[10], IntegerQ]

機械演算の連続する2つの結果に対してUnequalがFalseを返すまで1/n6項を足し続ける：

Wolfram Language code: FoldWhile[Plus, 0., 1 / Range[1000] ^ 6, Unequal, 2]

5!を連続する正の整数で割り続け，結果が整数である最後のものを返す：

Wolfram Language code: FoldWhile[Divide, 5!, Range[10], IntegerQ, 1, -1]

スコープ  (9)

12から整数を引いていく．整数は1から始めて順に1ずつ大きくし，答が正の間これを続ける：

Wolfram Language code: FoldWhile[Subtract, 12, {1, 2, 3, 4, 5, 6}, Positive]

Echoを使って中間結果を表示する：

Wolfram Language code: FoldWhile[Echo @* Subtract, 12, {1, 2, 3, 4, 5, 6}, Positive]

対応する判定の結果を表示する：

Wolfram Language code: FoldWhile[Subtract, 12, {1, 2, 3, 4, 5, 6}, Echo @* Positive]

原点から始まるランダムウォークを計算し，ノルムが10を超える最初の点を返す：

Wolfram Language code: FoldWhile[Plus, {0, 0}, AngleVector /@ RandomReal[2Pi, 200], Norm /* LessThan[10]]
Wolfram Language code: Norm[%]

ランダムな単位ベクトルリストについて，ノルムが0.1より大きいCross（外積）を求める：

Wolfram Language code: FoldWhile[Cross, Normalize /@ RandomReal[1, {100, 3}], Norm /* GreaterThan[0.1]]
Wolfram Language code: Norm[%]

機械演算の連続する2つの結果に対してUnequalがFalseを返すまで1/n8項を足し続ける：

Wolfram Language code: FoldWhile[Plus, 0., 1 / Range[200] ^ 8, Unequal, 2]

すべての結果が異なる限り0にランダムな整数を加え，繰り返された最初の値を返す：

Wolfram Language code: SeedRandom[123];
Wolfram Language code: FoldWhile[Plus, 0, DeleteCases[RandomInteger[{-10, 10}, 100], 0], UnsameQ, All]

連続する正の整数で5!を割り続け，整数ではなくなった最初の結果を返す：

Wolfram Language code: FoldWhile[Divide, 5!, Range[10], IntegerQ, 1, 0]

最後の整数の結果を返す：

Wolfram Language code: FoldWhile[Divide, 5!, Range[10], IntegerQ, 1, -1]

最後から2番目の整数の結果を返す：

Wolfram Language code: FoldWhile[Divide, 5!, Range[10], IntegerQ, 1, -2]

終了前に計算を放棄する：

Wolfram Language code: Catch[FoldWhile[If[# > 25, Divide[#1, #2], Throw[#1]]&, 5!, Range[10], IntegerQ]]

FoldWhileの演算子形を使う：

Wolfram Language code: FoldWhile[Subtract, Positive][12, {1, 2, 3, 4, 5, 6}]
Wolfram Language code: FoldWhile[Plus, LessThan[20]][Range[10]]

FoldWhileには，第3および第4引数が明示的な整数の場合は3引数または4引数の演算子形がある：

Wolfram Language code: FoldWhile[Subtract, Positive, 1, -1][12, {1, 2, 3, 4, 5, 6}]

特性と関係  (4)

test[x]がTrueを返さなければ，FoldWhile[f,x,alist,test]は x を返す：

Wolfram Language code: FoldWhile[Divide, 0, {2, 3, 4, 5}, Positive]

FoldWhile[f,x,alist,test,…]はLast[FoldWhileList[f,x,alist,test,…]]と等価である：

Wolfram Language code: FoldWhileList[Divide, 5!, Range[10], IntegerQ]
Wolfram Language code: Last[%]
Wolfram Language code: FoldWhile[Divide, 5!, Range[10], IntegerQ]

FoldWhile[f,x,list,True&]はFold[f,x,list]と等価である：

Wolfram Language code: FoldWhile[Plus, 0, Range[10], True&]
Wolfram Language code: Fold[Plus, 0, Range[10]]

FoldWhile[f,x,list,test,m,n]は，関数 f が1つの引数しか取らないときは，NestWhile[f,x,test,m,Length[list],n]と等価である：

Wolfram Language code: FoldWhile[Sqrt[#]&, 10 ^ 6, Range[4], GreaterThan[2], 1, 0]
Wolfram Language code: NestWhile[Sqrt[#]&, 10 ^ 6, GreaterThan[2], 1, 4, 0]
Wolfram Research (2020), FoldWhile, Wolfram言語関数， https://reference.wolfram.com/language/ref/FoldWhile.html.

テキスト

Wolfram Research (2020), FoldWhile, Wolfram言語関数， https://reference.wolfram.com/language/ref/FoldWhile.html.

CMS

Wolfram Language. 2020. "FoldWhile." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FoldWhile.html.

APA

Wolfram Language. (2020). FoldWhile. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FoldWhile.html

BibTeX

@misc{reference.wolfram_2026_foldwhile, author="Wolfram Research", title="{FoldWhile}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FoldWhile.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_foldwhile, organization={Wolfram Research}, title={FoldWhile}, year={2020}, url={https://reference.wolfram.com/language/ref/FoldWhile.html}, note=[Accessed: 07-October-2026]}