WOLFRAM

Wolfram 语言与系统参考资料中心

GeoBoundsRegionBoundary[{{latmin,latmax},{lonmin,lonmax}}]

是一个一维 GeoGraphics 基元，表示地球上位于纬圈 latmin、latmax 和子午线 lonmin、lonmax 之间的区域的边界.

GeoBoundsRegionBoundary[g]

表示地理区域 g 的经纬边界框的边界.

GeoBoundsRegionBoundary[g,δ]

对经度和维度的范围填充 ±δ.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

GeoBoundsRegionBoundary

GeoBoundsRegionBoundary[{{latmin,latmax},{lonmin,lonmax}}]

是一个一维 GeoGraphics 基元，表示地球上位于纬圈 latmin、latmax 和子午线 lonmin、lonmax 之间的区域的边界.

GeoBoundsRegionBoundary[g]

表示地理区域 g 的经纬边界框的边界.

GeoBoundsRegionBoundary[g,δ]

对经度和维度的范围填充 ±δ.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

欧洲部分地区的经纬矩形的边界：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[{{40, 60}, {-10, 25}}], GeoGridLines -> Automatic, GeoZoomLevel -> 5]

绘制国家的边境线及其边界框的边界:

Wolfram Language code: GeoGraphics[{GeoBoundsRegionBoundary[Entity["Country", "Brazil"]], Red, Polygon[Entity["Country", "Brazil"]]}]

范围  (3)

用度数给出经度和维度：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[{{-40, 40}, {-60, 60}}]]

用 Quantity 角度给出经度和维度：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[{{Quantity[-40, "AngularDegrees"], Quantity[40, "AngularDegrees"]}, {Quantity[-1, "Radians"], Quantity[1, "Radians"]}}]]

或使用带有角度单位的 QuantityArray 对象：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[QuantityArray[{{-40, 40}, {-60, 60}}, "AngularDegrees"]]]

绘制地理区域的边界框：

Wolfram Language code: disk = GeoDisk[Here, Quantity[3000, "Kilometers"]];
Wolfram Language code: GeoGraphics[{Blue, disk, Red, GeoBoundsRegionBoundary[disk]}, GeoGridLines -> Automatic]

使用圆柱投影（如墨卡托投影）获得矩形形状：

Wolfram Language code: GeoGraphics[{Blue, disk, Red, GeoBoundsRegionBoundary[disk]}, GeoGridLines -> Automatic, GeoProjection -> "Mercator"]

在所有方向上添加同样的填充：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[Entity["Country", "Spain"], Quantity[100, "Kilometers"]]]

添加不同的填充：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[Entity["Country", "Spain"], {{Quantity[100, "Kilometers"], 0}, {Quantity[-100, "Kilometers"], Quantity[200, "Kilometers"]}}]]

属性和关系  (6)

经度的范围 {lonmin,lonmax} 被视为从 lonmax 向东到 lonmin：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[{{-50, 50}, {-90, 90}}], Frame -> True]
Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[{{-50, 50}, {90, -90}}], Frame -> True]

GeoBoundsRegionBoundary 对应于 GeoBoundsRegion 基元的边界：

Wolfram Language code: GeoGraphics[{GeoBoundsRegion[{{-50, 50}, {-90, 90}}], Red, GeoBoundsRegionBoundary[{{-50, 50}, {-90, 90}}]}, Frame -> True]

对于地理区域 g，GeoBoundsRegionBoundary[g] 等价于 GeoBoundsRegionBoundary[GeoBounds[g]]：

Wolfram Language code: {GeoGraphics[GeoBoundsRegionBoundary[Entity["Country", "Australia"]]], GeoGraphics[GeoBoundsRegionBoundary[GeoBounds[Entity["Country", "Australia"]]]]}

地理区域的边是纬圈和子午线，而不是测地线：

Wolfram Language code: {latmin, latmax} = {-30, 60}; {lonmin, lonmax} = {-20, 70};
Wolfram Language code: GeoGraphics[{GeoBoundsRegionBoundary[{{latmin, latmax}, {lonmin, lonmax}}], Red, GeoPath[{{latmin, lonmin}, {latmin, lonmax}, {latmax, lonmax}, {latmax, lonmin}, {latmin, lonmin}}]}, GeoGridLines -> Automatic]

地理区域的边是恒向线 (rhumb line)：

Wolfram Language code: GeoGraphics[{GeoBoundsRegionBoundary[{{latmin, latmax}, {lonmin, lonmax}}], Red, GeoPath[{{latmin, lonmin}, {latmin, lonmax}, {latmax, lonmax}, {latmax, lonmin}, {latmin, lonmin}}, "RhumbLine"]}, GeoGridLines -> Automatic]

地理区域的形状取决于所用的投影：

Wolfram Language code: grect = GeoBoundsRegionBoundary[{{0, 85}, {-70, 70}}];
Wolfram Language code: GeoGraphics[grect, GeoProjection -> "Equirectangular", GeoGridLines -> Automatic]
Wolfram Language code: GeoGraphics[grect, GeoProjection -> "LambertAzimuthal", GeoGridLines -> Automatic]
Wolfram Language code: GeoGraphics[grect, GeoProjection -> "Albers", GeoGridLines -> Automatic]

到达纬度 90 或 的地理区域实际上是一个以极点为中心的地理圆的扇区：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[{{70, 90}, {-150, 150}}], GeoGridLines -> Automatic]

可能存在的问题  (1)

取两个位置：

Wolfram Language code: rio = Entity["City", {"RioDeJaneiro", "RioDeJaneiro", "Brazil"}]; moscow = Entity["City", {"Moscow", "Moscow", "Russia"}];

这两个地图是重合的，即使位置是相反的：

Wolfram Language code: {GeoGraphics[GeoBoundsRegionBoundary[{rio, moscow}]], GeoGraphics[GeoBoundsRegionBoundary[{moscow, rio}]]}

这是因为 GeoBounds 对方位不敏感：

Wolfram Language code: bounds = GeoBounds[{rio, moscow}]
Wolfram Language code: GeoBounds[{moscow, rio}] == bounds

如果想要获取经度上的互补矩形，可使用以下命令：

Wolfram Language code: GeoGraphics[GeoBoundsRegionBoundary[MapAt[Reverse, bounds, {2}]]]
Wolfram Research (2020)，GeoBoundsRegionBoundary，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoBoundsRegionBoundary.html.

文本

Wolfram Research (2020)，GeoBoundsRegionBoundary，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoBoundsRegionBoundary.html.

CMS

Wolfram 语言. 2020. "GeoBoundsRegionBoundary." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/GeoBoundsRegionBoundary.html.

APA

Wolfram 语言. (2020). GeoBoundsRegionBoundary. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/GeoBoundsRegionBoundary.html 年

BibTeX

@misc{reference.wolfram_2026_geoboundsregionboundary, author="Wolfram Research", title="{GeoBoundsRegionBoundary}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/GeoBoundsRegionBoundary.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geoboundsregionboundary, organization={Wolfram Research}, title={GeoBoundsRegionBoundary}, year={2020}, url={https://reference.wolfram.com/language/ref/GeoBoundsRegionBoundary.html}, note=[Accessed: 05-November-2026]}