WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoGridLines

GeoGraphicsのオプションで，表示する緯線および経線を指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
GeoGridLinesの位置  
GeoGridLinesのスタイリング  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GeoGridLines

GeoGridLines

GeoGraphicsのオプションで，表示する緯線および経線を指定する．

詳細

  • 次は，GeoGridLinesに使える設定値である．
  • None測地線格子は描かない
    Automatic自動的に測地線格子を描く
    n緯線と経線のおよその本数
    Quantity[…]角度量の倍数位置に置かれた測地線格子
    {latgrid,longrid}緯度と経度に別々に指定された測地線格子
  • Automatic設定の場合，測地線格子は，通常は小数表示で桁数が最小になる座標の点に置かれる．
  • 次の格子線オプションを，経度／緯度座標のそれぞれに与えることができる．
  • None測地線格子は描かない
    Automatic測地線格子の位置を自動的に選択する
    n緯線と経線のおよその本数
    Quantity[…]角度量の倍数位置に置かれた測地線格子
    {x1,x2,…}指定位置に測地線格子を描く
    {{x1,style1},…}指定されたスタイルの測地線格子
    funcxmin, xmaxに適用して測地線の格子オプションを得るための関数
  • 経度あるいは緯度に正の整数 n が指定された場合は，「適切な」測地線格子が生成されるように，さまざまなヒューリスティックが適用される．結果として，実際に表示される格子の本数は厳密に n ではなくなることがある．
  • GeoGridLines->n あるいはGeoGridLines->Automaticのとき，表示される格子の本数は，緯線と経線で異なることがある．
  • Quantity指定については，角度量のみがサポートされている．
  • 測地線格子関数 func[xmin,xmax]は，その他の任意の測地線格子オプションを返すことがある．
  • AbsoluteOptionsを使ってAutomatic設定の際のGeoGridLines指定に使われる経緯度の明示的なリストを抽出することができる．
  • GeoGridLinesStyleを使って測地線格子のスタイルを設定することができる．

例題

すべて開く すべて閉じる

例  (4)

デフォルトのスタイリングで測地線格子のある地図を重ねる：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> Automatic, GeoBackground -> "Plain"]

特定の経緯度線のところに測地線格子を描く：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> {Range[0, 50, 5], Range[-150, -40, 10]}, GeoGridLinesStyle -> Yellow]

測地格子のスタイルを指定する：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> Automatic, GeoGridLinesStyle -> Directive[Thick, Dashed, Orange]]

火星上に緯線および経線を15度間隔で区切って表示する：

Wolfram Language code: GeoGraphics[GeoModel -> "Mars", GeoGridLines -> Quantity[15, "AngularDegrees"], GeoProjection -> "WinkelTripel"]

スコープ  (9)

GeoGridLinesの位置  (5)

自動的に測地線格子を置く：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> Automatic]
Wolfram Language code: GeoGraphics[{Polygon[EntityClass["Country", "Europe"]]}, GeoGridLines -> Automatic]
Wolfram Language code: GeoGraphics[{GeoStyling[LightRed], Polygon[Entity["Country", "China"]]}, GeoBackground -> GeoStyling["ReliefMap"], GeoGridLines -> Automatic]

特定の緯度線に測地線格子を描く：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> {Range[20, 50, 5], None}, GeoGridLinesStyle -> Gray]

特定の経度線に測地線格子を描く：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> {None, Range[-150, -40, 10]}, GeoGridLinesStyle -> Magenta]

特定の経緯度線に測地線格子を描く：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> {Range[20, 50, 5], Range[-150, -40, 10]}, GeoGridLinesStyle -> Yellow]

測地線格子の目標数を指定する：

Wolfram Language code: GeoGraphics[Entity["Country", "UnitedStates"], GeoGridLines -> 20, GeoGridLinesStyle -> Orange]

経線と緯線に異なる数の測地線格子を指定する：

Wolfram Language code: GeoGraphics[Entity["Country", "UnitedStates"], GeoGridLines -> {4, 20}, GeoGridLinesStyle -> Directive[Thin, Orange]]

指定された角度の倍数位置に測地線格子を引く：

Wolfram Language code: GeoGraphics[Entity["Country", "UnitedStates"], GeoGridLines -> Quantity[5, "AngularDegrees"], GeoGridLinesStyle -> Orange]

GeoGridLinesのスタイリング  (4)

各測地線格子のスタイルを指定する：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> {{{20, Red}, {30, Orange}, {40, Yellow}, {50, Green}, {60, Blue}}, None}, GeoGridLinesStyle -> Black]
Wolfram Language code: With[{p = CountryData["UnitedStates", "CenterCoordinates"]}, GeoGraphics[Entity["Country", "UnitedStates"], GeoGridLines -> {{{p[[1]], Red}}, {{p[[2]], Blue}}}, GeoBackground -> "StreetMapNoLabels", GeoGridLinesStyle -> Black] ]

GeoGridLinesStyleを使って全体的な測地線格子のスタイルを指定する：

Wolfram Language code: GeoGraphics[Polygon[EntityClass["Country", "SouthAmerica"]], GeoGridLines -> Automatic, GeoGridLinesStyle -> {Blue, Orange}]

個別にスタイル付けされた測地線格子をGeoGridLinesStyleとともに使うことができる（優先順位は前者が高い）：

Wolfram Language code: GeoGraphics[Polygon[EntityClass["Country", "SouthAmerica"]], GeoGridLines -> {{-60, {-50, Directive[Thick, Yellow]}, -40, -30, -20, -10, 0, 10, 20, 30}, {-90, -80, -70, {-60, Directive[Thick, Green]}, -50, -40, -30, -20}}, GeoGridLinesStyle -> {Blue, Orange}]

各方向の xmin値および xmax値に適用される格子関数を指定する：

Wolfram Language code: grids[min_, max_] := Table[If[EvenQ[i], {i, Red}, {i, Blue}], {i, Ceiling[min], Floor[max], 1}]
Wolfram Language code: GeoGraphics[Entity["Country", "Australia"], GeoGridLines -> grids]

アプリケーション  (2)

30°の倍数のところに実線を引き，10°の倍数のところに破線を引く：

Wolfram Language code: styles[m_] := Table[{c, If[Mod[c, 30] == 0, Directive[Thick, Black], Dashed]}, {c, -m, m, 10}];
Wolfram Language code: GeoGraphics[GeoGridLines -> {styles[90], styles[180]}, GeoRange -> "World"]

ボンヌ図法上に測地線格子を示す：

Wolfram Language code: GeoGraphics[GeoGridLines -> Automatic, GeoProjection -> "Bonne", GeoRange -> "World"]
Wolfram Language code: AbsoluteOptions[%, GeoGridLines]

特性と関係  (2)

測地線格子は常にグラフィックスの上に描かれる：

Wolfram Language code: GeoGraphics[EntityClass["Country", "Europe"], GeoGridLines -> Automatic, GeoBackground -> GeoStyling["ReliefMap"], GeoGridLinesStyle -> Blue]
Wolfram Language code: GeoGraphics[EntityClass["Country", "Europe"], GeoGridLines -> Automatic, GeoGridLinesStyle -> Orange]

AbsoluteOptionsを使ってAutomatic設定で使われる格子を得る：

Wolfram Language code: GeoGraphics[GeoRange -> "World", GeoGridLines -> Automatic]
Wolfram Language code: AbsoluteOptions[%, GeoGridLines]

考えられる問題  (4)

GeoGridLinesスタイルに加えてGeoGridLinesStyleを指定すると，結果が変わることがある：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]]}, GeoGridLines -> {{{20, Red}, {30, Orange}, {40, Yellow}, {50, Green}, {60, Blue}}, None}, GeoGridLinesStyle -> #]& /@ {Opacity[1], Automatic}

測地線格子は角度量として指定してもよい：

Wolfram Language code: GeoGraphics[Entity["Country", "UnitedStates"], GeoGridLines -> Quantity[5, "AngularDegrees"]]

測地線格子は距離量として指定することはできない：

Wolfram Language code: GeoGraphics[Entity["Country", "UnitedStates"], GeoGridLines -> Quantity[500, "Kilometer"]]

いくつかの測地関数についての整数の引数とオプション設定は，メートル単位の距離（あるいは半径）として解釈される：

Wolfram Language code: With[{city = Entity["City", {"Rugby", "NorthDakota", "UnitedStates"}]}, GeoGraphics[{GeoDisk[city, 4.4*^6], Red, PointSize[Large], Point[city]}, GeoRange -> 4.5*^6, GeoGridLines -> Automatic]]

しかし，整数の測地線格子指定は，表示すべき「適切な」グリッドラインのおよその本数を示す：

Wolfram Language code: GeoGraphics[Entity["City", {"Rugby", "NorthDakota", "UnitedStates"}], GeoGridLines -> 5, GeoGridLinesStyle -> Pink]

GeoPathを使って測地線の測地座標をインタラクティブに表示する：

Wolfram Language code: GeoGraphics[{Table[Tooltip[GeoPath[{"Meridian", lon}], Row[{"lon = ", lon, Degree}]], {lon, -180, 180, 30}], Table[Tooltip[GeoPath[{"Parallel", lat}], Row[{"lat = ", lat, Degree}]], {lat, -90, 90, 15}]}, GeoProjection -> "Bonne"]

おもしろい例題  (3)

測地線格子のランダムな集合：

Wolfram Language code: GeoGraphics[GeoRange -> "World", GeoGridLines -> {Table[{RandomReal[{-90, 90}], Hue[RandomReal[]]}, {30}], Table[{RandomReal[{-180, 180}], Hue[RandomReal[]]}, {30}]}]

1°経緯線網の測地線格子をオーストラリア上に描く：

Wolfram Language code: With[{region = Entity["Country", "Australia"]}, With[{ranges = Append[#, 1]& /@ Round[GeoBounds[region]]}, GeoGraphics[{Polygon[region]}, GeoGridLines -> Range@@@ranges, GeoGridLinesStyle -> Directive[Opacity[.5], Yellow], GeoBackground -> GeoStyling["ReliefMap"]] ] ]

アメリカ合衆国の大都市の位置に測地線格子を置く：

Wolfram Language code: Length[large = CityData[{Large, "UnitedStates"}]]
Wolfram Language code: largest = TakeLargest[EntityValue[large, "Population", "EntityAssociation"], 15]

都市の座標を計算する：

Wolfram Language code: pos = CityData[#, "Coordinates"]& /@ Keys[largest]; points = Tooltip[Point[#1], #2]&@@@Transpose[{GeoPosition /@ pos, Keys@largest}];

アメリカ合衆国の地図を，経緯度線が大都市を通るようにして表示する：

Wolfram Language code: GeoGraphics[{Polygon[Entity["Country", "UnitedStates"]], PointSize[Medium], points}, GeoGridLines -> Transpose[pos], GeoBackground -> "ReliefMap", GeoGridLinesStyle -> GrayLevel[0.2, 0.5]]
Wolfram Research (2014), GeoGridLines, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridLines.html.

テキスト

Wolfram Research (2014), GeoGridLines, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridLines.html.

CMS

Wolfram Language. 2014. "GeoGridLines." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoGridLines.html.

APA

Wolfram Language. (2014). GeoGridLines. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoGridLines.html

BibTeX

@misc{reference.wolfram_2026_geogridlines, author="Wolfram Research", title="{GeoGridLines}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/GeoGridLines.html}", note=[Accessed: 08-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geogridlines, organization={Wolfram Research}, title={GeoGridLines}, year={2014}, url={https://reference.wolfram.com/language/ref/GeoGridLines.html}, note=[Accessed: 08-November-2026]}