WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GroupBy[{elem1,elem2,…},f]

明確なキー f[elemi]に関連付けられたリストに分かれるように，elemiをグループ化する連想を与える．

GroupBy[{elem1,elem2,…},fkfv]

fk[elemi]に従って，fv[elemi]をグループ化する．

GroupBy[{elem1,elem2,…},{fs1,fs2,…}]

レベル i に fsiを使って，ネストした連想にグループ化する．

GroupBy[{elem1,elem2,…},spec,red]

生成された値の簡約リストに関数 red を適用する．

GroupBy[spec]

式に適用できるGroupByの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

GroupBy

GroupBy[{elem1,elem2,…},f]

明確なキー f[elemi]に関連付けられたリストに分かれるように，elemiをグループ化する連想を与える．

GroupBy[{elem1,elem2,…},fkfv]

fk[elemi]に従って，fv[elemi]をグループ化する．

GroupBy[{elem1,elem2,…},{fs1,fs2,…}]

レベル i に fsiを使って，ネストした連想にグループ化する．

GroupBy[{elem1,elem2,…},spec,red]

生成された値の簡約リストに関数 red を適用する．

GroupBy[spec]

式に適用できるGroupByの演算子形を表す．

詳細

  • GroupByは，写像の簡約操作の一般化を与える．
  • GroupBy[list,f]は，キーが他とは異なる f[elemi]でその値がリスト list の部分リストである連想を与える．
  • GroupBy[assoc,f]は，キーが他とは異なるf[elemi]で値が連想 assoc の部分的な連想である連想を与える．
  • GroupBy[spec][expr]はGroupBy[expr,spec]と等価である．

例題

すべて開く すべて閉じる

例  (3)

項目のペアを，ペアの第1要素に従ってグループ化する：

Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, First]

連想の値をグループ化する：

Wolfram Language code: GroupBy[<|a -> 1, b -> 2, c -> 3|>, EvenQ]

先頭項目でグループ化し，対応する最終項目の平均を計算する：

Wolfram Language code: GroupBy[{{a, x}, {b, v}, {a, y}, {a, z}, {b, w}}, First -> Last, Mean]

スコープ  (13)

複数の関数を使って要素を繰り返しグループ化する：

Wolfram Language code: GroupBy[Range[10], {PrimeQ, OddQ}]

ペアの最終部分を最初の部分に従ってグループ化する：

Wolfram Language code: GroupBy[{{a, 10}, {b, 20}, {a, 30}}, First -> Last]

複数の関数を使って連想の値をプループ化する：

Wolfram Language code: GroupBy[<|a -> 1, b -> 2, c -> 4|>, {EvenQ, PrimeQ}]

グループ化に記号セレクタを使う：

Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, f]

セレクタが同じ値を与えるペアは，同じキーの下にグループ化される：

Wolfram Language code: GroupBy[{-3, -2, -1, 0, 1, 2, 3}, Abs]

キーと値を取り出すのに別々の関数を使う：

Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, f -> g]
Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, f -> Last]
Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, First -> Last]

Extractの演算子形を使ってキーあるいは値を指定する：

Wolfram Language code: GroupBy[{{{a}, b}, {{a}, d}}, Extract[{1, 1}]]
Wolfram Language code: GroupBy[{{{a}, b}, {{a}, d}}, Extract[2] -> Extract[{1, 1}]]

結合器関数を使って値を結合する：

Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, First -> Last, Total]
Wolfram Language code: GroupBy[{{a, 10}, {b, 20}, {a, 30}}, First -> Last, Total]

連想を，その第1要素の値によってグループ化する：

Wolfram Language code: GroupBy[{<|1 -> a, 2 -> b|>, <|1 -> a, 2 -> c|>}, First]

連想を，与えられたキーの値によってグループ化する：

Wolfram Language code: GroupBy[{<|1 -> a, 2 -> b|>, <|2 -> a, 3 -> c|>}, Key[2]]

Keyを使ってキーと値を指定する：

Wolfram Language code: GroupBy[{<|1 -> a, 2 -> c|>, <|1 -> b, 2 -> c|>}, Key[2] -> Key[1]]

欠落キーはMissingで置換される：

Wolfram Language code: GroupBy[{<|1 -> a, 2 -> b|>, <|1 -> a, 3 -> c|>}, Key[2]]

整数のリストを正値性および偶奇性でグループ化し，グループを列ベクトルとして表す：

Wolfram Language code: GroupBy[Range[-4, 4], {Positive, EvenQ}, MatrixForm]

GroupByの演算子形を使う：

Wolfram Language code: GroupBy[First] @ {{a, b}, {a, c}, {b, c}}

関数を連想の値に適用した結果をグループ化する：

Wolfram Language code: GroupBy[<|a -> 1, b -> 2, c -> 4|>, EvenQ -> (# + 1&)]

アプリケーション  (1)

GroupByを使ってデータ集合の行をグループ化し，新たなレベルの連想を導入する：

Wolfram Language code: titanic = ExampleData[{"Dataset", "Titanic"}]

乗客を搭乗クラスでグループ化する：

Wolfram Language code: titanic[GroupBy["class"]]

乗客を性別と搭乗クラスでグループ化する：

Wolfram Language code: titanic[GroupBy["sex"], GroupBy["class"]]

特性と関係  (3)

GroupByは連想を返すのに対し，GatherByはリストを返す：

Wolfram Language code: GroupBy[{{a, b}, {a, c}, {b, c}}, First]
Wolfram Language code: GatherBy[{{a, b}, {a, c}, {b, c}}, First]

f でグループ化することは fIdentityでグループ化することに等しい：

Wolfram Language code: GroupBy[{a, b, a}, f]
Wolfram Language code: GroupBy[{a, b, a}, f -> Identity]

Counts[expr]はGroupBy[expr,Identity,Length]に等しい：

Wolfram Language code: Counts[{a, b, c, a}] == GroupBy[{a, b, c, a}, Identity, Length]

CountsBy[expr,f]はGroupBy[expr,f,Length]に等しい：

Wolfram Language code: CountsBy[{{a, b}, {b, c}, {a, d}}, First] == GroupBy[{{a, b}, {b, c}, {a, d}}, First, Length]
Wolfram Research (2014), GroupBy, Wolfram言語関数， https://reference.wolfram.com/language/ref/GroupBy.html.

テキスト

Wolfram Research (2014), GroupBy, Wolfram言語関数， https://reference.wolfram.com/language/ref/GroupBy.html.

CMS

Wolfram Language. 2014. "GroupBy." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GroupBy.html.

APA

Wolfram Language. (2014). GroupBy. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GroupBy.html

BibTeX

@misc{reference.wolfram_2026_groupby, author="Wolfram Research", title="{GroupBy}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/GroupBy.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_groupby, organization={Wolfram Research}, title={GroupBy}, year={2014}, url={https://reference.wolfram.com/language/ref/GroupBy.html}, note=[Accessed: 03-November-2026]}