WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GroupStabilizer[group,{p1,…,pn}]

点 p1, …, pnのどれも動かさない group の元の部分群を返す

GroupStabilizer[group,{p1,…,pn},f]

関数 f によって与えられた作用の下での固定部分群を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GroupStabilizer

GroupStabilizer[group,{p1,…,pn}]

点 p1, …, pnのどれも動かさない group の元の部分群を返す

GroupStabilizer[group,{p1,…,pn},f]

関数 f によって与えられた作用の下での固定部分群を返す．

詳細

  • 出力は生成元によって定義される group の部分群であるが，異なる生成元が使われた可能性もある．
  • 固定群は小群あるいは等方群としても知られる．
  • 点のリストの固定群は同じ点のリストの不変部分群である．
  • 指定された group の作用関数 f，点 p，置換 g についての評価 f[p,g]は，別の点 p'を返すと考えられる．
  • 置換群の場合，デフォルトの群作用はPermutationReplaceであると考えられる．

例題

すべて開く すべて閉じる

例  (1)

交代群の固定部分群：

Wolfram Language code: GroupStabilizer[AlternatingGroup[6], {1, 5}]

どの置換によっても点{1,5}のどれも動かない：

Wolfram Language code: GroupElements[%]

スコープ  (4)

生成元によって定義された置換群の固定群を計算する：

Wolfram Language code: GroupStabilizer[PermutationGroup[{Cycles[{{2, 5, 9}, {3, 7, 6}}], Cycles[{{2, 9}}], Cycles[{{3, 10}}]}], {2}]

名前付き置換群の固定群を計算する：

Wolfram Language code: GroupStabilizer[AlternatingGroup[10], {10}]
Wolfram Language code: % == AlternatingGroup[9]

群の固定群は自明であり得る：

Wolfram Language code: GroupStabilizer[PermutationGroup[{Cycles[{{1, 2, 3}, {4, 5, 6}}]}], {1}]

Permute作用の下でオブジェクトのリストを不変のまま残す置換の部分群：

Wolfram Language code: subgroup = GroupStabilizer[SymmetricGroup[5], {{a, a, b, a, b}}, Permute]

Permute作用の下での対応する軌道がそのリストだけを含むことを確認する：

Wolfram Language code: GroupOrbits[subgroup, {{a, a, b, a, b}}, Permute]

アプリケーション  (1)

対称群 は 推移であり交代群 は 推移である．他の任意の群は最高で5推移であることが知られている．マシュー群 は5推移である：

Wolfram Language code: group = MathieuGroupM24[];
Wolfram Language code: {GroupOrder[group], domain = PermutationSupport[group]}

軌道は1つのみである．ゆえにこれは推移的である：

Wolfram Language code: GroupOrbits[group, domain]

1の固定群は残りの23点に推移的に作用するので は2推移である：

Wolfram Language code: GroupOrbits[GroupStabilizer[group, {1}], domain]

これはまた3推移，4推移，5推移である：

Wolfram Language code: GroupOrbits[GroupStabilizer[group, {1, 2}], domain]
Wolfram Language code: GroupOrbits[GroupStabilizer[group, {1, 2, 3}], domain]
Wolfram Language code: GroupOrbits[GroupStabilizer[group, {1, 2, 3, 4}], domain]

しかし2つの自明ではない軌道があるのでこれは6推移ではない：

Wolfram Language code: GroupOrbits[GroupStabilizer[group, {1, 2, 3, 4, 5}], domain]

特性と関係  (3)

軌道・固定群定理には group の点 p の軌道サイズは group の p の固定群の剰余類の数に等しいとある：

3×3×3のルービック群を取り，点20の固定群を計算する：

Wolfram Language code: rot1 = Cycles[{{1, 3, 8, 6}, {2, 5, 7, 4}, {9, 48, 15, 12}, {10, 47, 16, 13}, {11, 46, 17, 14}}]; rot2 = Cycles[{{6, 15, 35, 26}, {7, 22, 34, 19}, {8, 30, 33, 11}, {12, 14, 29, 27}, {13, 21, 28, 20}}]; rot3 = Cycles[{{1, 12, 33, 41}, {4, 20, 36, 44}, {6, 27, 38, 46}, {9, 11, 26, 24}, {10, 19, 25, 18}}]; rot4 = Cycles[{{1, 24, 40, 17}, {2, 18, 39, 23}, {3, 9, 38, 32}, {41, 43, 48, 46}, {42, 45, 47, 44}}]; rot5 = Cycles[{{3, 43, 35, 14}, {5, 45, 37, 21}, {8, 48, 40, 29}, {15, 17, 32, 30}, {16, 23, 31, 22}}]; rot6 = Cycles[{{24, 27, 30, 43}, {25, 28, 31, 42}, {26, 29, 32, 41}, {33, 35, 40, 38}, {34, 37, 39, 36}}]; GroupOrder[Rubikgroup = PermutationGroup[{rot1, rot2, rot3, rot4, rot5, rot6}]]
Wolfram Language code: GroupOrder[stab = GroupStabilizer[Rubikgroup, {20}]]

ラグランジュの定理を使った全群中の固定群の剰余類の数：

Wolfram Language code: %% / %

点20の軌道の長さは24である：

Wolfram Language code: GroupOrbits[Rubikgroup, {20}]
Wolfram Language code: Length[First[%]]

GroupStabilizerで計算された固定部分群は，もとの群より多くの生成元を使って説明されることがある：

Wolfram Language code: AlternatingGroup[10]//GroupGenerators//Length
Wolfram Language code: GroupStabilizer[AlternatingGroup[10], {8}]//GroupGenerators//Length

共役作用の下での置換の固定群は，その置換の中心化群と一致する：

Wolfram Language code: group = AlternatingGroup[6]; g = Cycles[{{1, 3, 4}, {2, 5, 6}}];
Wolfram Language code: GroupStabilizer[group, {g}, PermutationReplace]
Wolfram Language code: % == GroupCentralizer[group, g]
Wolfram Research (2010), GroupStabilizer, Wolfram言語関数， https://reference.wolfram.com/language/ref/GroupStabilizer.html （2012年に更新）.

テキスト

Wolfram Research (2010), GroupStabilizer, Wolfram言語関数， https://reference.wolfram.com/language/ref/GroupStabilizer.html （2012年に更新）.

CMS

Wolfram Language. 2010. "GroupStabilizer." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/GroupStabilizer.html.

APA

Wolfram Language. (2010). GroupStabilizer. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GroupStabilizer.html

BibTeX

@misc{reference.wolfram_2026_groupstabilizer, author="Wolfram Research", title="{GroupStabilizer}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/GroupStabilizer.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_groupstabilizer, organization={Wolfram Research}, title={GroupStabilizer}, year={2012}, url={https://reference.wolfram.com/language/ref/GroupStabilizer.html}, note=[Accessed: 03-November-2026]}