WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

MarcumQ[m,a,b]

MarcumのQ関数 TemplateBox[{m, a, b}, MarcumQ]を与える．

MarcumQ[m,a,b0,b1]

MarcumのQ関数 TemplateBox[{m, a, {b, _, 0}}, MarcumQ]-TemplateBox[{m, a, {b, _, 1}}, MarcumQ]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
級数展開  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

MarcumQ

MarcumQ[m,a,b]

MarcumのQ関数 TemplateBox[{m, a, b}, MarcumQ]を与える．

MarcumQ[m,a,b0,b1]

MarcumのQ関数 TemplateBox[{m, a, {b, _, 0}}, MarcumQ]-TemplateBox[{m, a, {b, _, 1}}, MarcumQ]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 正の実数 ，， について TemplateBox[{m, a, b}, MarcumQ]=int_b^inftyx (x/a)^(m-1) TemplateBox[{{m, -, 1}, {a, , x}}, BesselI] exp(-1/2 (a^2+x^2))dx．
  • MarcumQ[m,a,b]は不連続な分枝切断線を持たない a と b の両方に関する整関数である．
  • 特別な引数の場合，MarcumQは自動的に厳密値を計算する．
  • MarcumQは任意の数値精度で計算できる．
  • MarcumQは自動的にリストに縫い込まれる． »

例題

すべて開く すべて閉じる

例  (4)

数値的に評価する：

Wolfram Language code: MarcumQ[2., 3, 1]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[MarcumQ[1, 4, b], {b, 0, 10}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[MarcumQ[1, 1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[MarcumQ[1 / 2, x, 2], {x, 0, 2}]

スコープ  (29)

数値評価  (6)

数値的に評価する：

Wolfram Language code: N[MarcumQ[5, 8, 7]]
Wolfram Language code: MarcumQ[2.5, 1.2, 3, 9]

高精度で評価する：

Wolfram Language code: N[MarcumQ[2 / 5, 1 / 2, 3, 9], 50]

出力精度は入力精度に従う：

Wolfram Language code: MarcumQ[2, 5, 9.21111111111111111111111111111111111]

複素数入力：

Wolfram Language code: N[MarcumQ[2 + I, 1 / 2, 3]]

高精度で効率的に評価する：

Wolfram Language code: MarcumQ[2 / 5, 1 / 2, 3`100]//Timing
Wolfram Language code: MarcumQ[1, 1 / 5, 3`1000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: MarcumQ[2, 1 / 2, {{1 / 2, -1}, {0, 1 / 2}}]

MatrixFunctionを使って行列のMarcumQ関数を計算することもできる：

Wolfram Language code: MatrixFunction[MarcumQ[2, 1 / 2, #]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: MarcumQ[ 2, 0, Around[1 / 2, 0.01]]

特定の値  (3)

記号的な a についてのMarcumQ：

Wolfram Language code: MarcumQ[2, a, a ]//FunctionExpand

MarcumQ[1,2,x]の最大値を求める：

Wolfram Language code: xmax = x /. FindRoot[D[MarcumQ[1, 2, x], x] == 0, {x, 0.1}]
Wolfram Language code: Plot[MarcumQ[1, 2, x], {x, -5, 5}, Epilog -> Style[Point[{xmax, MarcumQ[1, 2, xmax]}], PointSize[Large], Red]]

4引数の形は差を与える：

Wolfram Language code: MarcumQ[m, a, b0, b1]//FunctionExpand

可視化  (2)

MarcumQ関数をさまざまなパラメータについてプロットする：

Wolfram Language code: Plot[{MarcumQ[1, 5, x], MarcumQ[1, 4, x], MarcumQ[1, 3, x]}, {x, 0, 10}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[MarcumQ[1, 3, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[MarcumQ[1, 3, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

関数の特性  (9)

MarcumQの実領域：

Wolfram Language code: FunctionDomain[MarcumQ[m, a, b], {m, a, b}]
Wolfram Language code: FunctionDomain[MarcumQ[m, a, b1, b2], {m, a, b1, b2}]

MarcumQの複素領域：

Wolfram Language code: FunctionDomain[MarcumQ[m, a, b], {m, a, b}, Complexes]
Wolfram Language code: FunctionDomain[MarcumQ[m, a, b1, b2], {m, a, b1, b2}, Complexes]

の値域を近似する：

Wolfram Language code: FunctionRange[MarcumQ[2, 1, x], x, y]//Quiet

TemplateBox[{m, a, x}, MarcumQ]は の偶関数である：

Wolfram Language code: MarcumQ[m, a, -x]

TemplateBox[{m, a, b}, MarcumQ]は正の整数 についての と の解析関数である：

Wolfram Language code: FunctionAnalytic[MarcumQ[m, a, b], {a, b}, Assumptions -> m > 0 && m∈ℤ]

特異点も不連続点も持たない：

Wolfram Language code: Simplify[FunctionSingularities[MarcumQ[m, a, b], {a, b}], Assumptions -> m > 0 && m∈ℤ]
Wolfram Language code: Simplify[FunctionDiscontinuities[MarcumQ[m, a, b], {a, b}], Assumptions -> m > 0 && m∈ℤ]

は非増加でも非減少でもない：

Wolfram Language code: FunctionMonotonicity[MarcumQ[1 / 2, x, 2], x]

は単射ではない：

Wolfram Language code: FunctionInjective[MarcumQ[1 / 2, x, 2], x]
Wolfram Language code: Plot[{MarcumQ[1 / 2, x, 2], .5}, {x, -10, 10}]

は非負である：

Wolfram Language code: FunctionSign[MarcumQ[1 / 2, x, 2], x]

は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[MarcumQ[1 / 2, x, 2], x]

TraditionalFormによる表示：

Wolfram Language code: MarcumQ[m, a, b]//TraditionalForm
Wolfram Language code: MarcumQ[m, a, Subscript[b, 0], Subscript[b, 1]]//TraditionalForm

微分  (2)

a についての一次導関数：

Wolfram Language code: D[MarcumQ[m, a, b], a]

b についての一次導関数：

Wolfram Language code: D[MarcumQ[m, a, b], b]

a についての高次導関数：

Wolfram Language code: Table[D[MarcumQ[m, a, b], {a, k}], {k, 1, 4}]//FullSimplify

b=3で m=1のとき，a についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. { b -> 3, m -> 1}], {a, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

級数展開  (2)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[MarcumQ[m, a, b], {a, 0, 3}]//Normal//FullSimplify

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[MarcumQ[1, a, 3], {a, 0, k}], {k, 1, 5, 2}]; Plot[{MarcumQ[1, a, 3], terms}, {a, -3, 3}]

生成点におけるテイラー展開：

Wolfram Language code: Series[MarcumQ[m, a, b], {a, a0, 2}]// Normal//FullSimplify

関数の恒等式と簡約  (5)

TemplateBox[{m, a, b}, MarcumQ]は， が半整数のときは常により簡単な関数で表せる：

Wolfram Language code: MarcumQ[5 / 2, a, b]//FunctionExpand

TemplateBox[{m, a, b}, MarcumQ]は，整数 と について修正ベッセル関数で表せる：

Wolfram Language code: MarcumQ[-4, a, a]//FunctionExpand

任意の と について，TemplateBox[{m, a, b}, MarcumQ]は超幾何関数で表せる：

Wolfram Language code: MarcumQ[m, a, a]//FunctionExpand

TemplateBox[{m, a, b}, MarcumQ]が満足する についての常微分方程式：

Wolfram Language code: a^2y'''[a] + a(2a^2 + 2m - 1)y''[a] + (a^4 - a^2(b^2 - 2m) - 2m + 1)y'[a] == 0 /. y -> Function[a, MarcumQ[m, a, b]]//FullSimplify

についての常微分方程式は TemplateBox[{m, a, b}, MarcumQ]を満足する：

Wolfram Language code: b^2y'''[b] + b(2b^2 - 2m + 1)y''[b] + (b^4 - b^2(a^2 + 2m - 2) + 2m - 1)y'[b] == 0 /. y -> Function[b, MarcumQ[m, a, b]]//FullSimplify

TemplateBox[{m, a, b}, MarcumQ]が満足する についての漸化式：

Wolfram Language code: (a^2/2)y[m + 2] == ((a^2/2) - m)y[m + 1] + ((b^2/2) + m)y[m] - (b^2/2)y[m - 1] /. y -> Function[m, MarcumQ[m, a, b]]//FullSimplify

アプリケーション  (2)

信号の振幅はRiceDistributionでモデル化できる．振幅が平均値を超える確率を求める：

Wolfram Language code: 𝒟 = RiceDistribution[3, 2, 5];
Wolfram Language code: Probability[x > Mean[𝒟], x𝒟]

数値評価する：

Wolfram Language code: N[%]

大きい引数のMarcumQ関数の値とその漸近公式を比較する：

Wolfram Language code: Refine[SurvivalFunction[RiceDistribution[m, a / Sqrt[m], 1], x / Sqrt[m]], m > 0 && x > 0]

中心極限定理を使って近似を行う：

Wolfram Language code: SurvivalFunction[NormalDistribution[Mean[RiceDistribution[m, a / Sqrt[m], 1]], StandardDeviation[RiceDistribution[m, a / Sqrt[m], 1]]], x / Sqrt[m]]

数値評価する：

Wolfram Language code: {%%, %} /. {m -> 3, a -> 8.2, x -> 9.}

特性と関係  (3)

MarcumQを使ってSkellamDistributionのSurvivalFunctionを計算することができる：

Wolfram Language code: k = 3;m1 = 10;m2 = 9; SurvivalFunction[SkellamDistribution[m1, m2], k]//N
Wolfram Language code: MarcumQ[-k, Sqrt[2 m1], Sqrt[2 m2]]//N

MarcumQでNoncentralChiSquareDistributionのSurvivalFunctionを計算する：

Wolfram Language code: SurvivalFunction[NoncentralChiSquareDistribution[ν, δ], x]

MarcumQでRiceDistributionのSurvivalFunctionを計算する：

Wolfram Language code: SurvivalFunction[RiceDistribution[α, β], x]
Wolfram Language code: SurvivalFunction[RiceDistribution[m, α, β], x]
Wolfram Research (2010), MarcumQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/MarcumQ.html.

テキスト

Wolfram Research (2010), MarcumQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/MarcumQ.html.

CMS

Wolfram Language. 2010. "MarcumQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MarcumQ.html.

APA

Wolfram Language. (2010). MarcumQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MarcumQ.html

BibTeX

@misc{reference.wolfram_2026_marcumq, author="Wolfram Research", title="{MarcumQ}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/MarcumQ.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_marcumq, organization={Wolfram Research}, title={MarcumQ}, year={2010}, url={https://reference.wolfram.com/language/ref/MarcumQ.html}, note=[Accessed: 03-November-2026]}