WOLFRAM

Wolfram 语言与系统参考资料中心

ObservableModelQ[sys]

如果系统 sys 是可观测的，给出 True，否则为 False.

ObservableModelQ[{sys,sub}]

如果子系统 sub 是可观测的，给出 True.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Method  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ObservableModelQ

ObservableModelQ[sys]

如果系统 sys 是可观测的，给出 True，否则为 False.

ObservableModelQ[{sys,sub}]

如果子系统 sub 是可观测的，给出 True.

更多信息和选项

  • 状态空间模型在 处可观测，如果从 的模型轨道与有限时间中邻域的另一个状态可以区分的.
  • 系统 sys 可以是一个标准或者描述器 StateSpaceModel 或者 AffineStateSpaceModel.
  • 可以指定下列子系统 sub：
  • All整个系统
    "Fast"快速子系统
    "Slow"慢变子系统
    "Unstable"非稳定子系统
    {λ1,…}具有特征模式 lambda_(i) 的子系统
  • "Fast" 和 "Slow" 子系统主要应用于 KroneckerModelDecomposition 中描述的描述器状态空间模型.
  • 特征模式 λi 在 JordanModelDecomposition 中描述.
  • ObservableModelQ 接受 Method 选项，具有下列设置：
  • Automatic自动选择适当的检验
    "Distribution"使用可观测分布的秩
    "Gramian"使用可观测 Gramian 的秩或正定性
    "Matrix"使用可观测矩阵的秩
    "PBH"使用 Popov–Belevitch–Hautus阶数检验

范例

打开所有单元 关闭所有单元

基本范例  (2)

一个可观测系统：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{1}, {1}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

一个不可观测系统，因为第二状态不可观测：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{1}, {1}}, {{Subscript[c, 1], 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

范围  (6)

测试具有近似系数的系统的可观测性：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{-2.5368, 0.0606}, {4.0987, -2.4631}}, {{0.1509}, {-0.0951}}, {{5.1481, -2.3431}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

精确系数：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{17, -45}, {8, -21}}, {{2}, {1}}, {{-2, 5}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

符号系统：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{0, 1}, {(-Subscript[α, 1])*Subscript[α, 2], -Subscript[α, 1] - Subscript[α, 2]}}, {{0}, {1}}, {{k, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

多输出系统：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{-1, 0}, {0, -3}}, {{1}, {0}}, {{1, 0}, {0, 1}}, {{0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

离散时间系统：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{0, 1}, {-2, -1}}, {{0}, {1}}, {{0.5, 2}}, {{0}}}, SamplingPeriod -> 1, SystemsModelLabels -> None]]

描述器系统：

Wolfram Language code: ssm = StateSpaceModel[{{{1, 0, 0}, {0, 1, 0}, {0, 0, 0}}, {{0}, {1}, {1}}, {{-1, -6, 10}}, {{0}}, {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ObservableModelQ[ssm]

可观测性等价于快变和慢变模式的可观测性（C 可观测性）：

Wolfram Language code: {ObservableModelQ[{ssm, "Slow"}], ObservableModelQ[{ssm, "Fast"}]}

测试单个本征模的可观测性：

Wolfram Language code: ssm = StateSpaceModel[{{{-2, 1, 0}, {1, -3, 1}, {0, -1, -2}}, {{-1}, {0}, {0}}, {{1, 1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

系统是不可观测的，因为本征模 :

Wolfram Language code: modes = Eigenvalues[First[Normal[ssm]]]
Wolfram Language code: Table[{λ, ObservableModelQ[{ssm, λ}]}, {λ, modes}]

这可以以约旦型表示，其中没有观测第二个状态的方式存在：

Wolfram Language code: JordanModelDecomposition[ssm]//Last

测试 AffineStateSpaceModel 的可观测性：

Wolfram Language code: ObservableModelQ[AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 1]^2}, {{Subscript[x, 2]}, {0}}, {Subscript[x, 2]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None]]

如果给出操作点 ，测试 处的可观测性：

Wolfram Language code: ObservableModelQ[AffineStateSpaceModel[{{Subscript[x, 1]*Subscript[x, 2], 0}, {{0}, {1}}, {Subscript[x, 1]}, {{0}}}, {{Subscript[x, 1], 0}, {Subscript[x, 2], 0}}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None]]

系统在普通点是可观测的：

Wolfram Language code: ObservableModelQ[AffineStateSpaceModel[{{Subscript[x, 1]*Subscript[x, 2], 0}, {{0}, {1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None]]

选项  (6)

Method  (6)

默认情况下，可观测性矩阵用于精确和符号系统：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 10}, {1, 0}}, {{0}, {1}}, {{0, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ObservableModelQ[ssm, Method -> "Matrix"]

系统是可观测的，如果 ObservabilityMatrix 是满秩的：

Wolfram Language code: om = ObservabilityMatrix[ssm];
Wolfram Language code: MatrixRank[om]

可观测性格兰姆用于稳定数值系统：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1., 0.}, {0, 0., 1.}, {-1., -2., -2.}}, {{0}, {0}, {1.}}, {{1., 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ObservableModelQ[ssm, Method -> "Gramian"]

系统是可观测的，如果 ObservabilityGramian 是满秩的：

Wolfram Language code: og = ObservabilityGramian[ssm];
Wolfram Language code: MatrixRank[og]

对于可观测性格兰姆，这等价于正定矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[og]

PBH 秩测验用于所有其他数值系统：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1.}, {1., 0}}, {{0}, {1.}}, {{0.05, 1.}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ObservableModelQ[ssm, Method -> "PBH"]

系统是可观测的，因为 对所有 是满秩的：

Wolfram Language code: {a, c} = Normal[ssm][[{1, 3}]];
Wolfram Language code: MatrixRank /@ Table[ArrayFlatten[{{λ IdentityMatrix[2] - a}, {c}}], {λ, Eigenvalues[a]}]

可观测性共分布用于输入线性系统：

Wolfram Language code: ObservableModelQ[AffineStateSpaceModel[{{0, Subscript[x, 1]}, {{1 + Subscript[x, 1]}, {0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None], Method -> "Distribution"]

对于线性系统，基于可观测性矩阵和共分布是等价的：

Wolfram Language code: Table[ObservableModelQ[AffineStateSpaceModel[{{-Subscript[x, 1] + Subscript[x, 2], 2*Subscript[x, 1] + Subscript[x, 2]}, {{1}, {-1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None], Method -> m], {m, {"Matrix", "Distribution"}}]

线性系统的可观测性隐含输入线性系统的可观测性：

Wolfram Language code: asys = AffineStateSpaceModel[{{-Subscript[x, 2] + Subscript[x, 1]* Subscript[x, 2], -Subscript[x, 1] - Subscript[x, 1]*Subscript[x, 2]}, {{1}, {0}}, {2*Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: lsys = StateSpaceModel[asys];
Wolfram Language code: {ObservableModelQ[lsys], ObservableModelQ[asys]}

输入线性系统的矩阵测试对线性系统使用 "Matrix" 方法：

Wolfram Language code: ObservableModelQ[asys, Method -> "Matrix"]

应用  (2)

可以从 的测量值估计所有3个物质的位置和速度：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{0, 1, 0, 0, 0, 0}, {-(Subscript[k, 1] + Subscript[k, 2])/Subscript[m, 1], 0, Subscript[k, 2]/Subscript[m, 1], 0, 0, 0}, {0, 0, 0, 1, 0, 0}, {Subscript[k, 2]/Subscript[m, 2], 0, -(Subscript[k, 2] + Subscript[k, 3])/Subscript[m, 2], 0, Subscript[k, 3]/Subscript[m, 2], 0}, {0, 0, 0, 0, 0, 1}, {0, 0, Subscript[k, 3]/Subscript[m, 3], 0, -Subscript[k, 3]/Subscript[m, 3], 0}}, {{0}, {0}, {0}, {0}, {0}, {Subscript[m, 3]^(-1)}}, {{1, 0, 0, 0, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

以状态和电流 为测量值的电容电压和电感电流状态的电子电路：

Wolfram Language code: ssm = StateSpaceModel[{{{-𝒞^(-1)/Subscript[R, 1], 0}, {0, (-L^(-1))*Subscript[R, 2]}}, {{1/(𝒞*Subscript[R, 1])}, {L^(-1)}}, {{-Subscript[R, 1]^(-1), 1}}, {{Subscript[R, 1]^(-1)}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

一般来说，系统是可观测的：

Wolfram Language code: ObservableModelQ[ssm]

但是，如果 ，它是不可观测的：

Wolfram Language code: ObservableModelQ[ssm /. L -> Subscript[R, 1] Subscript[R, 2]𝒞]

属性和关系  (6)

假定 和 ，对角系统是可观测的：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 0}, {0, Subscript[λ, 2]}}, {{}, {}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

设置 ，不存在观测第一个状态的方式：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 0}, {0, Subscript[λ, 2]}}, {{}, {}}, {{0, Subscript[c, 2]}}, {{}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

设置 ，第二个状态不能直接观测，但是可以从第一个状态间接观测：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 1}, {0, Subscript[λ, 2]}}, {{}, {}}, {{Subscript[c, 1], 0}}, {{}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

设置 ，第一个状态不能直接或者间接从第二个状态观测：

Wolfram Language code: ObservableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 1}, {0, Subscript[λ, 2]}}, {{}, {}}, {{0, Subscript[c, 2]}}, {{}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

使用 JordanModelDecomposition 计算上述标准状态空间表示法：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1}, {-6, -5}}, {{0}, {1}}, {{5, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: JordanModelDecomposition[ssm]//Last

使用 "PBH" 测试即时每个模式的可观测性：

Wolfram Language code: Table[{λ, ObservableModelQ[{ssm, λ}]}, {λ, {-3, -2}}]

对于描述器系统，KroneckerModelDecomposition 是对角型的推广：

Wolfram Language code: kssm = Last[KroneckerModelDecomposition[ssm = StateSpaceModel[{{{-5, -1, -3}, {-3, 1, -3}, {-6, -2, -2}}, {{2}, {1}, {2}}, {{1, 1, 1}}, {{0}}, {{3, 1, 2}, {4, 0, 2}, {1, 1, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]]

从结构判断慢变子系统的可观测性：

Wolfram Language code: SystemsModelExtract[kssm, All, All, {1, 2}]

使用原始系统计算：

Wolfram Language code: ObservableModelQ[{ssm, "Slow"}]

从结构判断快变子系统的可观测性：

Wolfram Language code: SystemsModelExtract[kssm, All, All, {3}]

使用原始系统计算：

Wolfram Language code: ObservableModelQ[{ssm, "Fast"}]

如果 StateSpaceModel 的描述器矩阵是满秩的，不存在快变子系统：

Wolfram Language code: ssm = StateSpaceModel[{{{-2, -2}, {8, 12}}, {{1}, {2}}, {{1, 1}}, {{0}}, {{1, 1}, {2, 3}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

因此，系统的完整可控性可以从慢变子系统计算：

Wolfram Language code: {ControllableModelQ[ssm], ControllableModelQ[{ssm, All}], ControllableModelQ[{ssm, "Slow"}]}

对于 AffineStateSpaceModel，输入向量中的非线性有助于可观测性：

Wolfram Language code: ObservableModelQ[AffineStateSpaceModel[{{Subscript[x, 2], Subscript[x, 3], 0}, {{0}, {Subscript[x, 1]}, {0}}, {Subscript[x, 2]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None]]

具有先行输入向量的系统是不可观测的：

Wolfram Language code: ObservableModelQ[AffineStateSpaceModel[{{Subscript[x, 2], Subscript[x, 3], 0}, {{0}, {α}, {0}}, {Subscript[x, 2]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None]]

不可观测的系统具有难区分的初始状态：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 1]*Subscript[x, 2], 0}, {{0}, {1}}, {Subscript[x, 1]}, {{0}}}, {{Subscript[x, 1], 0}, {Subscript[x, 2], 0}}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: ObservableModelQ[assm]

两个初始状态 和 产生难区分的输出：

Wolfram Language code: Table[OutputResponse[{assm, ic}, 1, {t, 0, 5}], {ic, {{0, 0}, {0, 0.5}}}]; Plot[%, {t, 0, 5}]

可能存在的问题  (1)

对于不是渐近稳定的系统，格拉姆方法不可靠：

Wolfram Language code: ssm = StateSpaceModel[{{{12, 15, 13}, {-10, -13, -10}, {0, 0, -1}}, {{10/3}, {-2}, {2/3}}, {{3/2, 5/2, 3}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; Table[ObservableModelQ[ssm, Method -> m], {m, {"Gramian", "Matrix", "PBH"}}]
Wolfram Language code: Eigenvalues@First@Normal@ssm
Wolfram Research (2010)，ObservableModelQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ObservableModelQ.html （更新于 2014 年）.

文本

Wolfram Research (2010)，ObservableModelQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ObservableModelQ.html （更新于 2014 年）.

CMS

Wolfram 语言. 2010. "ObservableModelQ." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/ObservableModelQ.html.

APA

Wolfram 语言. (2010). ObservableModelQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ObservableModelQ.html 年

BibTeX

@misc{reference.wolfram_2026_observablemodelq, author="Wolfram Research", title="{ObservableModelQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ObservableModelQ.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_observablemodelq, organization={Wolfram Research}, title={ObservableModelQ}, year={2014}, url={https://reference.wolfram.com/language/ref/ObservableModelQ.html}, note=[Accessed: 01-November-2026]}