WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

RarerProbability[dist,example]

PDFが example 以下のサンプルを生成する分布 dist を計算する．

RarerProbability[dist,{ex1,ex2,…}]

各 exiについて，よりまれな確率を計算する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
外れ値検出  
品質管理のモニタリング  
特性と関係  
関連項目
関連するガイド
関連リンク
履歴
引用書式

RarerProbability

RarerProbability[dist,example]

PDFが example 以下のサンプルを生成する分布 dist を計算する．

RarerProbability[dist,{ex1,ex2,…}]

各 exiについて，よりまれな確率を計算する．

詳細

  • RarerProbabilityは，確率分布内において，与えられた観測値がいかに異常または特異であるかを定量化するために用いられる統計関数である．
  • 典型的な応用としては，データ解析および機械学習のワークフローにおいて，外れ値，異常値，ならびに期待されるパターンからの統計的に有意な逸脱を特定することが挙げられる．
  • RarerProbability[dist,x]はProbability[PDF[dist,y]≤PDF[dist,x],ydist]を計算する．
  • RarerProbabilityは統計で使われる p 値の多変量版と見ることができる．dist が，一変量，連続，対称の場合は，よりまれな確率は「両側」p 値に等しい．
  • RarerProbabilityは，AnomalyDetection，FindAnomalies，あるいはDeleteAnomaliesで異常の定義に使われる．

例題

すべて開く すべて閉じる

例  (2)

確率を計算して，正規分布から3よりもまれな値を得る：

Wolfram Language code: RarerProbability[NormalDistribution[], 3]
Wolfram Language code: N[%]

色のデータについての分布を学ぶ：

Wolfram Language code: ld = LearnDistribution[{RGBColor[0.5172966964096541, 0.4435322033449375, 1.], RGBColor[0.3984626930847484, 0.5592892024442906, 1.], RGBColor[0.6149389612362844, 0.5648721294502163, 1.], RGBColor[0.4129156497559272, 0.9146065592632544, 1.], RGBColor[0.7907065846445507, 0.41054133291260947, 1.], RGBColor[0.4878854162550912, 0.9281119680196579, 1.], RGBColor[0.9884362181280959, 0.49025178842859785, 1.], RGBColor[0.633242503827218, 0.9880985331612835, 1.], RGBColor[0.9215182482568276, 0.8103084921468551, 1.], RGBColor[0.667469513641223, 0.46420827644204676, 1.]}]
Wolfram Language code: RarerProbability[ld, {RGBColor[0.6500379955252116, 0.8945809371196838, 1.000516202399788], RGBColor[0, 0, 1], RGBColor[0, 1, 0], RGBColor[1, 0, 0]}]

スコープ  (5)

まれな確率を数値的に計算する：

Wolfram Language code: RarerProbability[NormalDistribution[0, 1], 2.5]

結果を厳密数で取得する：

Wolfram Language code: RarerProbability[NormalDistribution[0, 1], 5 / 2]
Wolfram Language code: N@%

連続分布について任意精度の結果を取得する：

Wolfram Language code: RarerProbability[WeibullDistribution[2, 5], N[4, 25]]

非厳密なパラメータを持つ離散分布について，任意精度の結果を取得する：

Wolfram Language code: RarerProbability[NegativeBinomialDistribution[20, N[1 / 3, 30]], 5]

RarerProbabilityは要素単位でリストに縫い込まれる：

Wolfram Language code: RarerProbability[NormalDistribution[0, 1], {-2., -1., 0., 1., 2.}]

アプリケーション  (2)

外れ値検出  (1)

一変量データの外れ値を特定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 1], 50];

外れ値を加える：

Wolfram Language code: data = Join[data, {5, -4.5, 6}];

データ分布を推定する：

Wolfram Language code: dist = EstimatedDistribution[data, NormalDistribution[μ, σ]]

各データ点についてまれな確率を計算する：

Wolfram Language code: rareness = RarerProbability[dist, data]

低い確率の点を選択する：

Wolfram Language code: outliers = Pick[data, rareness, _ ? (# < 0.01&)]

点を検出された外れ値とともにプロットする：

Wolfram Language code: ListPlot[{Transpose[{data, rareness}], Pick[Transpose[{data, rareness}], rareness, _ ? (# < 0.01&)]}, ...]

品質管理のモニタリング  (1)

製造プロセスをモニターする：

Wolfram Language code: measurements = {10.2, 9.8, 10.1, 11.5, 9.9, 10.3, 8.5, 10.0};

目標指定を定義する：

Wolfram Language code: specs = NormalDistribution[10, 0.5];

まれな確率を計算する：

Wolfram Language code: rareness = RarerProbability[specs, measurements]

低品質のサンプルを求める：

Wolfram Language code: bad = Select[rareness, LessThan[0.01] -> "Index"]

制御グラフを作成する：

Wolfram Language code: ListLinePlot[measurements, Epilog -> {Red, InfiniteLine[{#, 0}, {0, 1}]& /@ bad}, ...]

特性と関係  (1)

一変量連続分布および対称分布について，まれな確率は「二尾」の p 値に等しい：

Wolfram Language code: Integrate[PDF[NormalDistribution[], x], {x, 2, Infinity}] + Integrate[PDF[NormalDistribution[], x], {x, -Infinity, -2}]
Wolfram Language code: RarerProbability[NormalDistribution[], 2]
Wolfram Research (2019), RarerProbability, Wolfram言語関数， https://reference.wolfram.com/language/ref/RarerProbability.html.

テキスト

Wolfram Research (2019), RarerProbability, Wolfram言語関数， https://reference.wolfram.com/language/ref/RarerProbability.html.

CMS

Wolfram Language. 2019. "RarerProbability." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RarerProbability.html.

APA

Wolfram Language. (2019). RarerProbability. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RarerProbability.html

BibTeX

@misc{reference.wolfram_2026_rarerprobability, author="Wolfram Research", title="{RarerProbability}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/RarerProbability.html}", note=[Accessed: 18-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_rarerprobability, organization={Wolfram Research}, title={RarerProbability}, year={2019}, url={https://reference.wolfram.com/language/ref/RarerProbability.html}, note=[Accessed: 18-June-2026]}