WOLFRAM

Wolfram 语言与系统参考资料中心

Real

是实数(浮点数)的标头.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Real

Real

是实数(浮点数)的标头.

更多信息

  • _Real 可以用来表示模式中的一个实数.
  • 您可以输入任意长度的浮点数.
  • 您可以使用类似 mantissa*^exponent 的形式以科学记数法输入一个数.
  • 可用 b^^digits 输入基数为 b 的浮点数. 基数最大可为 36. 用字母 a–z 或 A–Z 序列来表示数字 10 到 35.
  • 在 Read 中，Real 也用来表示一个近似实数.

范例

打开所有单元 关闭所有单元

基本范例  (1)

输入一个实数：

Wolfram Language code: 1.23

Real 是实数的 Head：

Wolfram Language code: Head[%]

范围  (11)

仅输入少量数字的实数通常表示为机器实数：

Wolfram Language code: 1.23456789
Wolfram Language code: MachineNumberQ[%]

输入有多个有效位的实数：

Wolfram Language code: x = 987654321123456789.987654321123456789

当对于一个机器数给出过多数字位时，使用任意精度的实数：

Wolfram Language code: MachineNumberQ[x]

它的 Accuracy 是基于小数点右边的位数：

Wolfram Language code: Accuracy[%%]

输入有指定 Precision 的实数：

Wolfram Language code: x = 1`23
Wolfram Language code: Precision[x]

输入有指定 Accuracy 的实数：

Wolfram Language code: x = 0``12
Wolfram Language code: Accuracy[x]

输入有指数的实数：

Wolfram Language code: 1.23*^45

输入有指数和指定精度的一个实数：

Wolfram Language code: 1.23`45.*^67

输入二进制位的实数：

Wolfram Language code: 2^^101001000100001.0101101110111101111

输入二进制位的实数，其中按二进制指定精度：

Wolfram Language code: 2^^101001000100001.0101101110111101111`100
Wolfram Language code: Precision[%]
Wolfram Language code: % * Log[2, 10]

输入十六进制的实数：

Wolfram Language code: 16^^fab.bead

输入基数为 35 的实数：

Wolfram Language code: 35^^thecowjumpedoverthemoon.
Wolfram Language code: MachineNumberQ[%]

用基数 2 格式化一个有理数：

Wolfram Language code: BaseForm[1.2345, 2]

_Real 可以用来表示模式中的一个实数：

Wolfram Language code: MatchQ[1.23, _Real]

用附近的有理数替代实数的规则：

Wolfram Language code: 1.4142135623730951×E^3.141592653589793 t /. x_Real :> Rationalize[x, 0]

应用  (4)

确定一个矩阵是否完全由近似实数组成：

Wolfram Language code: m = {{1`20, 2.}, {3, 4.5}};
Wolfram Language code: MatrixQ[m, MatchQ[#, _Real]&]
Wolfram Language code: MatrixQ[N[m], MatchQ[#, _Real]&]

将所有实数转换为小数点后有两位数字的规则：

Wolfram Language code: rule = x_Real :> N[Round[100 x] / 100];

将一张餐馆的钞票兑换成最接近的便士：

Wolfram Language code: 123.50 / 7 /. rule

定义一个仅作用于实数的函数：

Wolfram Language code: f[x_Real] := Total[First[RealDigits[x]]]
Wolfram Language code: {f[1.2], f[4]}
Wolfram Language code: Plot[f[x], {x, 0, 1}]

定义一个有实数特例的函数：

Wolfram Language code: sqrt[x_Real] := s /. FindRoot[s ^ 2 - x, {s, 1.}, WorkingPrecision -> Precision[x]];
Wolfram Language code: sqrt[2`47]

对于整数和有理数，使用相应的近似实数：

Wolfram Language code: sqrt[x_Integer] := sqrt[N[x]] sqrt[x_Rational] := sqrt[N[x]]
Wolfram Language code: sqrt[2]

属性和关系  (5)

实数属于数：

Wolfram Language code: NumberQ[12.34]

Real 用于近似实数：

Wolfram Language code: ExactNumberQ[12.34]

实数是无子表达式的原子对象：

Wolfram Language code: AtomQ[12.34]

用不同的格式显示一个实数：

Wolfram Language code: r = -Pi ^ 10.
Wolfram Language code: Table[f[r], {f, {ScientificForm, EngineeringForm, AccountingForm}}]

在假设中用 Reals 指定域条件：

Wolfram Language code: Reduce[x Log[x] < 1, x, Reals]

可能存在的问题  (1)

Real 仅是有理实数的头部：

Wolfram Language code: MatchQ[3 / 4, Real]

您可以使用下列函数来测试实轴上的数：

Wolfram Language code: realAxisQ[x_] := NumberQ[x] && !MatchQ[x, _Complex]
Wolfram Language code: realAxisQ[3 / 4]
Wolfram Research (1988)，Real，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Real.html （更新于 1996 年）.

文本

Wolfram Research (1988)，Real，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Real.html （更新于 1996 年）.

CMS

Wolfram 语言. 1988. "Real." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 1996. https://reference.wolfram.com/language/ref/Real.html.

APA

Wolfram 语言. (1988). Real. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Real.html 年

BibTeX

@misc{reference.wolfram_2026_real, author="Wolfram Research", title="{Real}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Real.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_real, organization={Wolfram Research}, title={Real}, year={1996}, url={https://reference.wolfram.com/language/ref/Real.html}, note=[Accessed: 04-November-2026]}