WOLFRAM

Wolfram 语言与系统参考资料中心

SymmetrizedDependentComponents[comp,sym]

给出对称性 sym 下等价于分量 comp 的分量列表.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

SymmetrizedDependentComponents

SymmetrizedDependentComponents[comp,sym]

给出对称性 sym 下等价于分量 comp 的分量列表.

更多信息

  • 分量 comp 必须以正整数列表的形式给出.

范例

打开所有单元 关闭所有单元

基本范例  (1)

深度为3的数组的分量由于对称性与分量 {1,3,5} 相关:

Wolfram Language code: SymmetrizedDependentComponents[{1, 3, 5}, Antisymmetric[{1, 2, 3}]]

随着对称性化为零的分量也与其他分量相关：

Wolfram Language code: SymmetrizedDependentComponents[{1, 3, 3}, Antisymmetric[{1, 2, 3}]]

范围  (2)

这是一个具有对称性的数组：

Wolfram Language code: A = {{{a, b}, {b, c}}, {{b, c}, {c, d}}}; TensorSymmetry[A]

这些是与分量 {1,1,2} 相关联的独立分量：

Wolfram Language code: comps = SymmetrizedDependentComponents[{1, 1, 2}, %]

相应的值关于对称性一致：

Wolfram Language code: Extract[A, comps]

在没有对称性的数组中，所有分量都是独立的：

Wolfram Language code: SymmetrizedDependentComponents[{1, 3}, {}]

属性和关系  (4)

使用 Symmetric，SymmetrizedDependentComponents 与 Permutations 等价：

Wolfram Language code: SymmetrizedDependentComponents[{1, 5, 2, 3}, Symmetric[{1, 2, 3, 4}]] == Sort@Permutations[{1, 5, 2, 3}]

SymmetrizedDependentComponents 允许只置换某些元素：

Wolfram Language code: SymmetrizedDependentComponents[{1, 5, 2, 3}, Symmetric[{1, 2, 4}]]

在对于对称性置换相关联的群上进行 Permute 操作时，SymmetrizedDependentComponents 是一个轨道计算：

Wolfram Language code: g1 = Cycles[{{1, 2}}]; g2 = Cycles[{{1, 3}, {2, 4}}]; sym = {{g1, 1}, {g2, 1}}; G = PermutationGroup[{g1, g2}];
Wolfram Language code: SymmetrizedDependentComponents[{1, 2, 3, 4}, sym]
Wolfram Language code: GroupOrbits[G, {{1, 2, 3, 4}}, Permute]

采用深度为4的数组的对称性：

Wolfram Language code: sym = {{{2, 1, 3, 4}, -1}, {{3, 4, 1, 2}, 1}};

在维度5中，存在 55 个非独立分量：

Wolfram Language code: Length[indeps = SymmetrizedIndependentComponents[{5, 5, 5, 5}, sym]]

计算各自的非独立分量，并且展平结果：

Wolfram Language code: Length[deps = Flatten[SymmetrizedDependentComponents[#, sym]& /@ indeps, 1]]

根据对称性，剩下的分量都是零：

Wolfram Language code: Length[zeros = Complement[Tuples[Range[5], 4], deps]]

非独立分量的值彼此之间的关系取决于对称性生成器的相位. 对于反对称性，数组的符号交替：

Wolfram Language code: sym = Antisymmetric[{1, 2, 3}]
Wolfram Language code: array = SymmetrizedArray[pos_ :> Subscript[a, pos], {3, 3, 3}, sym]
Wolfram Language code: comps = SymmetrizedDependentComponents[{1, 2, 3}, sym]
Wolfram Language code: Extract[array, comps]

复相位也是可能的：

Wolfram Language code: sym = {{{2, 3, 1}, Exp[2Pi I / 3]}}
Wolfram Language code: array = SymmetrizedArray[pos_ :> Subscript[a, pos], {3, 3, 3}, sym]
Wolfram Language code: comps = SymmetrizedDependentComponents[{1, 2, 3}, sym]
Wolfram Language code: Extract[array, comps]

巧妙范例  (1)

绘制具有对称方块的数组的分量的随机轨道图线：

Wolfram Language code: BlockSymmetric[n_, m_] := Join[{Symmetric[Range[m]]}, {Cycles[#], 1}& /@ Transpose /@ Partition[Partition[Range[n m], m], 2, 1]]
Wolfram Language code: orbit[n_ ? EvenQ, m_] := With[{pos = RandomInteger[{1, m n}, m n]}, Flatten[ SparseArray[ Thread[SymmetrizedDependentComponents[pos, BlockSymmetric[m, n]] -> 1] ], Transpose@Partition[Range[m n], 2] ] ]

采用具有三层2个对称方块的深度为6的数组：

Wolfram Language code: BlockSymmetric[2, 3]

在把数组展平成矩阵之后，它的随机轨道：

Wolfram Language code: RandomSeed[0]; Table[MatrixPlot[orbit[2, 3], FrameTicks -> None, ImageSize -> 100], {12}]
Wolfram Research (2012)，SymmetrizedDependentComponents，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SymmetrizedDependentComponents.html.

文本

Wolfram Research (2012)，SymmetrizedDependentComponents，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SymmetrizedDependentComponents.html.

CMS

Wolfram 语言. 2012. "SymmetrizedDependentComponents." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SymmetrizedDependentComponents.html.

APA

Wolfram 语言. (2012). SymmetrizedDependentComponents. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SymmetrizedDependentComponents.html 年

BibTeX

@misc{reference.wolfram_2026_symmetrizeddependentcomponents, author="Wolfram Research", title="{SymmetrizedDependentComponents}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/SymmetrizedDependentComponents.html}", note=[Accessed: 07-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_symmetrizeddependentcomponents, organization={Wolfram Research}, title={SymmetrizedDependentComponents}, year={2012}, url={https://reference.wolfram.com/language/ref/SymmetrizedDependentComponents.html}, note=[Accessed: 07-November-2026]}