WOLFRAM

Wolfram 语言与系统参考资料中心

TransferFunctionPoles[tfm]

给出 TransferFunctionModel tfm 中分母的根矩阵.

TransferFunctionPoles[tfm,reg]

在复平面上只给出区域 reg 内的根.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

TransferFunctionPoles

TransferFunctionPoles[tfm]

给出 TransferFunctionModel tfm 中分母的根矩阵.

TransferFunctionPoles[tfm,reg]

在复平面上只给出区域 reg 内的根.

更多信息

  • 矩形区域 reg 可以按 {{remin,remax},{immin,immax}} 给出.
  • 默认区域是整个复平面.

范例

打开所有单元 关闭所有单元

基本范例  (3)

陷波滤波器的极点：

Wolfram Language code: TransferFunctionPoles[TransferFunctionModel[{{{s^2 + ω^2}}, s^2 + 2*s*ζ*ω + ω^2}, s]]

指定阻尼率和自然频率的极点：

Wolfram Language code: % /. {ζ -> 0.3, ω -> 6Pi}

MIMO 系统的极点是传递函数元素的极点：

Wolfram Language code: TransferFunctionPoles[TransferFunctionModel[{{{10, 1}, {s, 1}}, {{s*(1 + s), -1 + s}, {2 + s, 3 + s}}}, s]]

时滞系统可能有无限多的极点：

Wolfram Language code: TransferFunctionPoles[TransferFunctionModel[{{{100*E^(2*s)}}, 1 + 100*E^(2*s)*s}, s]]

但是在有限区域内它们总是有无穷多极点：

Wolfram Language code: N@TransferFunctionPoles[TransferFunctionModel[{{{100*E^(2*s)}}, 1 + 100*E^(2*s)*s}, s], {{-5, 5}, {-4, 4}}]

范围  (5)

四阶巴特沃斯（Butterworth）滤波器的极点：

Wolfram Language code: TransferFunctionPoles[tfm = TransferFunctionModel[{{{1}}, (1 + 0.7654*s + s^2)* (1 + 1.848*s + s^2)}, s]]

它们位于单位圆上：

Wolfram Language code: PoleZeroPlot[tfm, PlotRange -> {{-1.1, 1.1}, {-1.1, 1.1}}, Epilog -> Style[Circle[], {Dashed, Gray}]]

十阶贝塞尔（Bessel）滤波器的极点：

Wolfram Language code: b[n_, k_] := ((2n - k)!/2^(n - k)(n - k)!k!) TransferFunctionPoles[TransferFunctionModel[(b[10, 0]/Subsuperscript[∑, i = 0, 10]b[10, i]s^i), s]]//N

离散二阶系统的极点：

Wolfram Language code: tfm = TransferFunctionModel[{{{0.004679 + 0.004837*z}}, 0.9095 - 1.9*z + z^2}, z, SamplingPeriod -> 1/100];
Wolfram Language code: p = TransferFunctionPoles[tfm]

系统是稳定的，因为极点位于单位圆内：

Wolfram Language code: y = Thread[{Range[0, 2, 10^-2], #}]& /@ OutputResponse[tfm, UnitStep[t], {t, 2}];
Wolfram Language code: ListPlot[y, Joined -> True, PlotRange -> All]
Wolfram Language code: Flatten[Abs /@ p]

原点附近正方形区域内时滞系统的极点：

Wolfram Language code: poles = TransferFunctionPoles[tfm = TransferFunctionModel[{{{1.}}, E^(-4*s) + 3.*s + s^2}, s], {{-20, 20}, {-20, 20}}]

极点在复平面上描绘的路径：

Wolfram Language code: PoleZeroPlot[tfm, Rectangle[{-5, -20}, {0, 20}]]

MIMO 系统元素的极点：

Wolfram Language code: tfm = TransferFunctionModel[{{{s, 2*s, 1 + s}, {s, 1, 1}, {1, s, 1}}, {{3 + s, 6 + s, 3 + s}, {6 + s, 3 + s, 2 + s}, {3 + s, 2 + s, 6 + s}}}, s];
Wolfram Language code: TransferFunctionPoles[tfm]//MatrixForm

应用  (2)

使用 TransferFunctionPoles 确定系统是否具有渐进稳定性：

Wolfram Language code: AsymptoticallyStableQ[tfm_ ? ContinuousTimeModelQ] := If[ Count[TransferFunctionPoles[tfm], Complex[x_ ? NonNegative, _] | x_ ? NonNegative, {3}] > 0, False, True]
Wolfram Language code: AsymptoticallyStableQ[tfm_ ? DiscreteTimeModelQ] := If[ Count[TransferFunctionPoles[tfm], _ ? (Abs[#] ≥ 1&), {3}] > 0, False, True]

各种系统的渐近稳定性：

Wolfram Language code: Grid[Join[{{"System", "Asymptotically Stable"}}, Table[{tfm, AsymptoticallyStableQ[tfm]}, {tfm, {TransferFunctionModel[{{{1}}, s}, s], TransferFunctionModel[{{{1}}, -1 + z}, z, SamplingPeriod -> τ], TransferFunctionModel[{{{1, 1}}, {{-0.4 + z, 0.08 + 0.4*z + z^2}}}, z, SamplingPeriod -> τ], TransferFunctionModel[{{{1, 1}}, {{1 + s, (1 + s)^2}}}, s], TransferFunctionModel[{{{-1 + s, 1}, {-1 + s, 2}}, -1 + s}, s]}}]], Frame -> All]

求时滞系统靠近原点处的极点：

Wolfram Language code: tfm = TransferFunctionModel[{{{-3. + 4.*s}}, 1. + s/E^s + s^2}, s]; poles = TransferFunctionPoles[tfm, {{-5, 5}, {-5, 5}}]

使用极点创建无时滞近似：

Wolfram Language code: zeros = TransferFunctionZeros[tfm]; approx = TransferFunctionModel[{zeros, poles, {{4}}}, s]

比较时滞系统互动无时滞近似的阶跃响应：

Wolfram Language code: actualresp = OutputResponse[tfm, UnitStep[t], {t, 0, 10}]; approxresp = OutputResponse[approx, UnitStep[t], {t, 0, 10}]; Plot[{actualresp, approxresp}, {t, 0, 10}]

属性和关系  (4)

对于 SISO 系统，传递函数的极点是状态矩阵的特征值：

Wolfram Language code: tfm = TransferFunctionModel[{{{10*(5 + s)}}, s*(1 + s)* (4 + s)}, s];
Wolfram Language code: Flatten[TransferFunctionPoles[tfm]] == Eigenvalues[First[Normal[StateSpaceModel[tfm]]]]

极点决定系统的自然响应：

Wolfram Language code: tfm = TransferFunctionModel[{{{1 + s}}, 272 + 114*s + 18*s^2 + s^3}, s];
Wolfram Language code: OutputResponse[{StateSpaceModel[tfm], {0.1, 1, 1}}, 0, t]//Expand

响应中的指数是极点的实数部分：

Wolfram Language code: TransferFunctionPoles[tfm]

当任何参数变化时，根轨迹图给出了闭环极点：

Wolfram Language code: tfm = TransferFunctionModel[{{{k*(2 + s)}}, 1 + s + s^2}, s];
Wolfram Language code: poles = TransferFunctionPoles[SystemsModelFeedbackConnect[tfm]];
Wolfram Language code: poleCoords = Replace[Table[Evaluate[poles], {k, 0., 8}]//Flatten, p_ :> {Re[p], Im[p]}, {1}];

当 k 变化时的根轨迹图：

Wolfram Language code: RootLocusPlot[tfm, {k, 0, 8}, PlotRange -> All, PoleZeroMarkers -> None, Epilog -> {PointSize[Medium], Red, Point /@ poleCoords}]

具有一个符号式极点的稳定三阶系统：

Wolfram Language code: tfm[p_] := TransferFunctionModel[{{{13}}, (1 + p*s)* (13 + 4*s + s^2)}, s]
Wolfram Language code: TransferFunctionPoles[tfm[p]]

如果第三个极点在左边的较远处，它能够使用二阶系统更好地近似：

Wolfram Language code: Plot[Evaluate@Table[Tooltip[OutputResponse[tfm[p], UnitStep[t], {t, 10}], p], {p, {4, 1.75, 0.95, 0.6, 0.25, 0.1, 0}}], {t, 0, 10}, PlotRange -> All]

可能存在的问题  (1)

TransferFunctionPoles 可能无法找到时间延迟系统的解：

Wolfram Language code: TransferFunctionPoles[tfm = TransferFunctionModel[{{{1}}, (E^(3*s) + s + E^(3*s)*s^2)/E^(3*s)}, s]]

指定区域：

Wolfram Language code: poles = N@TransferFunctionPoles[tfm, {{-10, 10}, {-10, 10}}]

绘制极点图线：

Wolfram Language code: PoleZeroPlot[tfm, Rectangle[{-5, -20}, {0, 20}], AspectRatio -> 1]
Wolfram Research (2010)，TransferFunctionPoles，Wolfram 语言函数，https://reference.wolfram.com/language/ref/TransferFunctionPoles.html （更新于 2012 年）.

文本

Wolfram Research (2010)，TransferFunctionPoles，Wolfram 语言函数，https://reference.wolfram.com/language/ref/TransferFunctionPoles.html （更新于 2012 年）.

CMS

Wolfram 语言. 2010. "TransferFunctionPoles." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2012. https://reference.wolfram.com/language/ref/TransferFunctionPoles.html.

APA

Wolfram 语言. (2010). TransferFunctionPoles. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/TransferFunctionPoles.html 年

BibTeX

@misc{reference.wolfram_2026_transferfunctionpoles, author="Wolfram Research", title="{TransferFunctionPoles}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/TransferFunctionPoles.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_transferfunctionpoles, organization={Wolfram Research}, title={TransferFunctionPoles}, year={2012}, url={https://reference.wolfram.com/language/ref/TransferFunctionPoles.html}, note=[Accessed: 05-November-2026]}