ストリームメソッド—Wolfram Documentation

ストリームメソッド

はじめに	入力ストリームメソッド
ストリームメソッドを使う	出力ストリームメソッド

はじめに

入力ストリームと出力ストリームは，ストレージメカニズムからバイトを読み書きするために要求されるストリーム操作を表すストリームメソッドを使って開かれる．ストリームメソッドを使うことで，ファイル，子プロセス，Webサーバ，バイトのインメモリリスト等のストレージメカニズムやデータソースから読み書きすることが可能になる．ストリームメソッドは圧縮や暗号化といったような変換も実行できる．たとえば，ユーザはストリームメソッドを使うことで圧縮されたファイルを開き，解凍されたコンテンツを読むことができる．ストリームへの操作では，物理メモリに適合しないような非常に大きいファイルへの操作も行える．

Wolframシステムは，ファイル，Webサーバ，文字列，外部コマンドからの読み書きのような一般的なニーズに応えられるストリームメソッドを提供している．また，に新しいストリームメソッドを加えることもできる．

ストリームメソッドを使う

読み書きのためにストリームを開いたら，Methodオプションを使って自分でストリームメソッドを指定することもできれば，Wolframシステムに，ストリーム名から自動的にストリームメソッドを選ばせることもできる．

次は，ストリーム名からストリームメソッドを選んで，Webサーバからストリームを開く：

Wolfram Language code:

Needs["CURLLink`"]
st = OpenRead["http://www.wolfram.com"]

Wolfram Language code: Find[st, "Mathematica"]

Wolfram Language code: Close[st]

次はMethodオプションでストリームメソッドを選んで，Webサーバからストリームを開く：

Wolfram Language code:

Needs["CURLLink`"]
st = OpenRead["http://www.wolfram.com", Method -> "HTTP"]

Wolfram Language code: Find[st, "<body", IgnoreCase -> True]

Wolfram Language code: Close[st]

次では，ストリーム名からストリームメソッドを選んで，Webサーバから直接Wolframシステムパッケージをロードする：

Wolfram Language code: Get["http://exampledata.wolfram.com/Collatz.m"]

Wolfram Language code: Collatz[5]

以下では，明示的に開かれた入力ストリームを使って，Webサーバから直接Wolframシステムパッケージをロードする：

Wolfram Language code: st = OpenRead["http://exampledata.wolfram.com/Collatz.m"]

Wolfram Language code: ClearAll["Collatz`*"]

Wolfram Language code: Get[st]

Wolfram Language code: Collatz[4]

Wolfram Language code: Close[st]

入力ストリームメソッド

Wolframシステムには新しい入力ストリームメソッドを加えることができる．新しいストレージ媒体から読みたい場合や，ファイルの解凍等，読まれると同時にデータを変換したい場合に便利である．

ファイルからではなく，メソッドオプション"Bytes"として渡されるバイトのリストから入力を取るストリームメソッドを定義する：

Wolfram Language code:

DefineInputStreamMethod["ByteList", {
	"ConstructorFunction" -> 
	Function[{name, caller, opts}, If[MatchQ[opts, {___, "Bytes" -> {_Integer ...}, ___}], 
	{True, {0, "Bytes" /. opts}}, 
	{False, $Failed}
	]], 
	
	"ReadFunction" -> 
	Function[{state, n}, 
	Module[{pos = state[[1]], bytes = state[[2]], bytesRead}, 
	If[pos >= Length[bytes], 
	{{}, state}, 
	bytesRead = Part[bytes, pos + 1 ;; Min[Length[bytes], pos + n]];
	{bytesRead, {pos + Length[bytesRead], bytes}}
	]
	]], 
	
	"EndOfFileQFunction" -> ({#[[1]] >= Length[#[[2]]], #}&)
	}]

次で新しいメソッドをテストする：

Wolfram Language code:

bytes = ToCharacterCode["Title: The Quick Brown Fox
Abstract: A fox jumps over dogs.
The quick brown fox jumped over the lazy dogs.
"];
st = OpenRead["Quick Brown Fox", Method -> {"ByteList", "Bytes" -> bytes}];
ReadList[st, String]//InputForm
Close[st];

次は，読み込むと同時にストリームに回転暗号化を実行するストリームメソッドを定義する．暗号的に強い暗号化も同じように実行できる：

Wolfram Language code:

SetAttributes[rotateByte, Listable]
rotateByte[n_, x_] := 
	With[{char = FromCharacterCode[x]}, 
	Which[
	UpperCaseQ[char], Mod[(x - 65) + n, 26] + 65, 
	LowerCaseQ[char], Mod[(x - 97) + n, 26] + 97, 
	True, x]
	]
	
DefineInputStreamMethod["Rotate", 
	{
	"ConstructorFunction" -> 
	Function[{streamname, caller, opts}, 
	With[{state = Unique["RotateInputStream"]}, 
	state["stream"] = OpenRead[streamname, BinaryFormat -> True];
	state["positions"] = "Positions" /. Join[opts, {"Positions" -> 13}];
	state["eof"] = False;
	{True, state}
	]], 
	
	"CloseFunction" -> Function[state, Close[state["stream"]]; ClearAll[state]], 
	
	"EndOfFileQFunction" -> Function[state, {state["eof"], state}], 
	
	"ReadFunction" -> 
	Function[{state, nBytes}, 
	Module[{bytes = If[state["eof"], {}, BinaryReadList[state["stream"], "Byte", nBytes]]}, 
	If[!ListQ[bytes], bytes = {}];
	state["eof"] = Length[bytes] < nBytes;
	{rotateByte[state["positions"], bytes], state}
	]
	]
	}]

このメソッドをテストするために，まず暗号化されたテストファイルを書き，この新しいメソッドを使ってそれを読み込む：

Wolfram Language code:

Export["testrot13.txt", "guvf vf n jrnxyl-uvqqra cnffjbeq", "Text"]
FilePrint["testrot13.txt"]

Wolfram Language code: st = OpenRead["testrot13.txt", Method -> "Rotate"]

ストリームメソッドがファイルの内容を変換するため，内容はReadが返すものとは異なっている：

Wolfram Language code: Read[st, String]

Wolfram Language code:

Close[st]
DeleteFile["testrot13.txt"]

出力ストリームメソッド

Wolframシステムには新しい出力ストリームメソッドを加えることもできる．新しい記憶媒体に書き込みたい場合や，ファイルの解凍等，書き込まれると同時にデータを変換した場合に便利である．

書き込まれたバイト数を出力する最小のストリームメソッドを定義する：

Wolfram Language code:

DefineOutputStreamMethod["Passthrough", 
  {
    "ConstructorFunction" -> 
	Function[{streamname, isAppend, caller, opts}, 
	With[{state = Unique["PassthroughOutputStream"]}, 
	state["stream"] = OpenWrite[streamname, BinaryFormat -> True];
	state["pos"] = 0;
	{True, state}
	]], 
	
	"CloseFunction"  -> Function[state, Close[state["stream"]]; ClearAll[state]], 
	
	"StreamPositionFunction" -> Function[state, {state["pos"], state}], 
	
	"WriteFunction"  -> 
	Function[{state, bytes}, 
	Module[{result = BinaryWrite[state["stream"], bytes], nBytes}, 
	nBytes = If[result === state["stream"], Length[bytes], 0];
	Print["Wrote ", nBytes, " bytes"];
	state["pos"] += nBytes;
	{nBytes, state}
	]
	]
    }
 ]

以下で新しいメソッドをテストする：

Wolfram Language code: st = OpenWrite["test.bin", Method -> "Passthrough", BinaryFormat -> True]

Wolfram Language code: BinaryWrite[st, Range[0, 255]]

Wolfram Language code: StreamPosition[st]

Wolfram Language code: Close[st]

Wolfram Language code: BinaryReadList["test.bin", "Byte"] === Range[0, 255]

Wolfram Language code: DeleteFile["test.bin"]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ストリームメソッド