---
title: "Abs"
language: "en"
type: "Symbol"
summary: "Abs[z] gives the absolute value of the real or complex number z."
keywords: 
- absolute value
- complex number
- magnitude of complex number
- modulus
- abs
- ABS
- abs
- cabs
- cabsf
- cabsl
- fabs
- fabsf
- fabsl
- labs
- llabs
- abs
- abs
- magnitude
- abs
- abs
canonical_url: "https://reference.wolfram.com/language/ref/Abs.html"
source: "Wolfram Language Documentation"
related_guides: 
  - 
    title: "Numerical Functions"
    link: "https://reference.wolfram.com/language/guide/NumericalFunctions.en.md"
  - 
    title: "Complex Numbers"
    link: "https://reference.wolfram.com/language/guide/ComplexNumbers.en.md"
  - 
    title: "Functions of Complex Variables"
    link: "https://reference.wolfram.com/language/guide/FunctionsOfComplexVariables.en.md"
  - 
    title: "Image Processing & Analysis"
    link: "https://reference.wolfram.com/language/guide/ImageProcessing.en.md"
  - 
    title: "GPU Computing"
    link: "https://reference.wolfram.com/language/guide/GPUComputing.en.md"
  - 
    title: "Mathematical Functions"
    link: "https://reference.wolfram.com/language/guide/MathematicalFunctions.en.md"
  - 
    title: "Representation of Numbers"
    link: "https://reference.wolfram.com/language/guide/RepresentationOfNumbers.en.md"
  - 
    title: "GPU Computing with NVIDIA"
    link: "https://reference.wolfram.com/language/guide/GPUComputing-NVIDIA.en.md"
  - 
    title: "Angles and Polar Coordinates"
    link: "https://reference.wolfram.com/language/guide/AnglesAndPolarCoordinates.en.md"
  - 
    title: "GPU Computing with Apple"
    link: "https://reference.wolfram.com/language/guide/GPUComputing-Apple.en.md"
  - 
    title: "Audio Editing"
    link: "https://reference.wolfram.com/language/guide/AudioEditing.en.md"
related_functions: 
  - 
    title: "RealAbs"
    link: "https://reference.wolfram.com/language/ref/RealAbs.en.md"
  - 
    title: "Norm"
    link: "https://reference.wolfram.com/language/ref/Norm.en.md"
  - 
    title: "Re"
    link: "https://reference.wolfram.com/language/ref/Re.en.md"
  - 
    title: "Im"
    link: "https://reference.wolfram.com/language/ref/Im.en.md"
  - 
    title: "Arg"
    link: "https://reference.wolfram.com/language/ref/Arg.en.md"
  - 
    title: "AbsArg"
    link: "https://reference.wolfram.com/language/ref/AbsArg.en.md"
  - 
    title: "Sign"
    link: "https://reference.wolfram.com/language/ref/Sign.en.md"
  - 
    title: "Conjugate"
    link: "https://reference.wolfram.com/language/ref/Conjugate.en.md"
  - 
    title: "Mod"
    link: "https://reference.wolfram.com/language/ref/Mod.en.md"
  - 
    title: "ComplexExpand"
    link: "https://reference.wolfram.com/language/ref/ComplexExpand.en.md"
related_tutorials: 
  - 
    title: "Some Mathematical Functions"
    link: "https://reference.wolfram.com/language/tutorial/SomeMathematicalFunctions.en.md"
  - 
    title: "Complex Numbers"
    link: "https://reference.wolfram.com/language/tutorial/Numbers.en.md#9161"
  - 
    title: "Numerical Functions"
    link: "https://reference.wolfram.com/language/tutorial/MathematicalFunctions.en.md#21826"
  - 
    title: "Piecewise Functions"
    link: "https://reference.wolfram.com/language/tutorial/MathematicalFunctions.en.md#690"
---
# Abs

Abs[z] gives the absolute value of the real or complex number z.

## Details

* ``Abs`` is also known as modulus.

* Mathematical function, suitable for both symbolic and numerical manipulation.

* For complex numbers ``z``, ``Abs[z]`` gives the modulus $| z|$.

* ``Abs[z]`` is left unevaluated if ``z`` is not a numeric quantity.

* ``Abs`` automatically threads over lists.  »

* ``Abs`` can be used with ``Interval`` and ``CenteredInterval`` objects.  »

---

## Examples (61)

### Basic Examples (4)

Real numbers:

```wl
In[1]:= Abs[-2.5]

Out[1]= 2.5

In[2]:= Abs[3.14]

Out[2]= 3.14
```

---

Complex numbers:

```wl
In[1]:= Abs[1.4 + 2.3I]

Out[1]= 2.69258
```

---

Plot over a subset of the reals:

```wl
In[1]:= Plot[Abs[x], {x, -3, 3}]

Out[1]= [image]
```

---

Plot over a subset of the complexes:

```wl
In[1]:= ComplexPlot3D[Abs[z], {z, -3 - 3I, 3 + 3I}, PlotLegends -> Automatic]

Out[1]= [image]
```

### Scope (34)

#### Numerical Evaluation (6)

Evaluate numerically:

```wl
In[1]:= Abs[1.2]

Out[1]= 1.2
```

---

Complex number input:

```wl
In[1]:= Abs[3 + 4I]

Out[1]= 5
```

---

Evaluate to high precision:

```wl
In[1]:= N[Abs[Pi + I Catalan], 25]

Out[1]= 3.272399329361528960349014
```

The precision of the output tracks the precision of the input:

```wl
In[2]:= Abs[-0.312788888855555500005]

Out[2]= 0.31278888885555550000
```

---

Evaluate efficiently at high precision:

```wl
In[1]:= Abs[-Pi / E + 1.15573`100]//Timing

Out[1]= {0.000047, 2.6502090782820899068166873037008791489768355841795002934646727113681590830605598115657643264411955133463129793`94.3604237506444*^-6}

In[2]:= Abs[-Pi / E + 1.15573`10000];//Timing

Out[2]= {0.000047, Null}
```

---

Compute the elementwise values of an array using automatic threading:

```wl
In[1]:= Abs[{{1 / 2, -1}, {-5 / 3, 1 / 2}}]

Out[1]= {{(1/2), 1}, {(5/3), (1/2)}}
```

Or compute the matrix ``Abs`` function using ``MatrixFunction``:

```wl
In[2]:= MatrixFunction[Abs, {{1 / 2, -1}, {-5 / 3, 1 / 2}}]//FullSimplify

Out[2]= {{Sqrt[(5/3)], -(Sqrt[(3/5)]/2)}, {-(Sqrt[(5/3)]/2), Sqrt[(5/3)]}}
```

---

``Abs`` can be used with ``Interval`` and ``CenteredInterval`` objects:

```wl
In[1]:= Abs[Interval[{-3, 5}]]

Out[1]= Interval[{0, 5}]

In[2]:= Abs[CenteredInterval[-5, 3]]

Out[2]= CenteredInterval[{{5, 0, 805306368, -28}, 63}]

In[3]:= Abs[CenteredInterval[2 + 3I, 1 + I]]

Out[3]= CenteredInterval[{{805306365, -28, 536870920, -28}, 63}]
```

Or compute average-case statistical intervals using ``Around``:

```wl
In[4]:= Abs[ Around[3 / 2, 0.01]]

Out[4]= Around[1.5, 0.01]
```

#### Specific Values (6)

Values of ``Abs`` at fixed points:

```wl
In[1]:= Table[Abs[n], {n, {1, I 7 / 3, -7 / 5}}]

Out[1]= {1, (7/3), (7/5)}
```

---

Value at zero:

```wl
In[1]:= Abs[0]

Out[1]= 0
```

---

Values at infinity:

```wl
In[1]:= Abs[Infinity]

Out[1]= ∞

In[2]:= Abs[I Infinity]

Out[2]= ∞

In[3]:= Abs[ComplexInfinity]

Out[3]= ∞
```

---

Evaluate symbolically:

```wl
In[1]:= PiecewiseExpand[Abs[I x], -2 < x < 2]

Out[1]= Piecewise[{{-x, x < 0}}, x]
```

---

Exact inputs:

```wl
In[1]:= Abs[-5^(1/(3)) + 3]

Out[1]= Sqrt[(3 5^2 / 3/4) + (3 + (5^1 / 3/2))^2]
```

---

Find real values of $x$ for which $| x| =2$ :

```wl
In[1]:= xval = Solve[Abs[x] == 2, x, Reals]

Out[1]= {{x -> -2}, {x -> 2}}
```

Substitute in the value of $x$ to create $(x,y)$ pairs:

```wl
In[2]:= points = {x, Abs[x]} /. xval

Out[2]= {{-2, 2}, {2, 2}}
```

Visualize the result:

```wl
In[3]:= Plot[Abs[x], {x, -3, 3}, Epilog -> Style[Point[points], Red, PointSize[Large]]]

Out[3]= [image]
```

#### Visualization (5)

Plot $| 1+ x|$ on the real axis:

```wl
In[1]:= Plot[Abs[1 + x], {x, -3, 3}]

Out[1]= [image]
```

---

Plot $| 1+i x|$ on the real axis:

```wl
In[1]:= Plot[Abs[1 + I x], {x, -3, 3}]

Out[1]= [image]
```

---

Plot ``Abs`` in the complex plane:

```wl
In[1]:= ComplexContourPlot[Abs[z], {z, 2}, PlotLegends -> Automatic]

Out[1]= [image]
```

---

Visualize ``Abs`` in three dimensions:

```wl
In[1]:= ComplexPlot3D[Abs[z], {z, -2 - 2I, 2 + 2I}, Mesh -> Automatic, BoxRatios -> Automatic, RegionFunction -> Function[{z}, Abs[z] ≤ 2]]

Out[1]= [image]
```

---

Use ``Abs`` to specify regions of the complex plane:

```wl
In[1]:= ComplexRegionPlot[Abs[z ^ 2] < Abs[z - 1], {z, 2}]

Out[1]= [image]
```

#### Function Properties (11)

``Abs`` is defined for all real and complex inputs:

```wl
In[1]:= FunctionDomain[Abs[x], x]

Out[1]= True

In[2]:= FunctionDomain[Abs[x], x, Complexes]

Out[2]= True
```

---

The range of ``Abs`` is the non-negative reals:

```wl
In[1]:= FunctionRange[Abs[x], x, y]

Out[1]= y ≥ 0
```

This is true even in the complex plane:

```wl
In[2]:= FunctionRange[Abs[x], x, y, Complexes]

Out[2]= Re[y] ≥ 0 && Im[y] == 0
```

---

``Abs`` is an even function:

```wl
In[1]:= Abs[-x] == Abs[x]

Out[1]= True
```

---

``Abs`` is not a differentiable function:

```wl
In[1]:= Abs'[x]

Out[1]= Derivative[1][Abs][x]
```

The difference quotient does not have a limit in the complex plane:

```wl
In[2]:= Underscript[\[Limit], hUnderscript[ -> , ℂ]0](Abs[x + h] - Abs[x]/h)

Out[2]= Indeterminate
```

There is only a limit in certain directions, for example, the real direction:

```wl
In[3]:= Underscript[\[Limit], hUnderscript[ -> , ℝ]0](Abs[x + h] - Abs[x]/h)

Out[3]= (Re[x]/Sqrt[Im[x]^2 + Re[x]^2])
```

This result, restricted to real inputs, is the derivative of ``RealAbs`` :

```wl
In[4]:= Simplify[% == RealAbs'[x], x∈Reals]

Out[4]= True
```

---

``Abs`` is not an analytic function:

```wl
In[1]:= FunctionAnalytic[Abs[x], x]

Out[1]= False
```

It has singularities but no discontinuities:

```wl
In[2]:= FunctionSingularities[Abs[x], x]

Out[2]= x == 0

In[3]:= FunctionDiscontinuities[Abs[x], x]

Out[3]= False
```

Over the complex plane, it is singular everywhere but still continuous:

```wl
In[4]:= FunctionSingularities[Abs[x], x, Complexes]

Out[4]= True

In[5]:= FunctionDiscontinuities[Abs[x], x, Complexes]

Out[5]= False
```

---

``Abs`` is neither nondecreasing nor nonincreasing:

```wl
In[1]:= FunctionMonotonicity[Abs[x], x]

Out[1]= Indeterminate
```

---

``Abs`` is not injective:

```wl
In[1]:= FunctionInjective[Abs[x], x]

Out[1]= False

In[2]:= Plot[{Abs[x], 1}, {x, -4, 4}]

Out[2]= [image]
```

---

``Abs`` is not surjective:

```wl
In[1]:= FunctionSurjective[Abs[x], x]

Out[1]= False

In[2]:= Plot[{Abs[x], -2.5}, {x, -4, 4}]

Out[2]= [image]
```

---

``Abs`` is non-negative:

```wl
In[1]:= FunctionSign[Abs[x], x]

Out[1]= 1
```

---

``Abs`` is convex:

```wl
In[1]:= FunctionConvexity[Abs[x], x]

Out[1]= 1
```

---

``TraditionalForm`` formatting:

```wl
In[1]:= Abs[x]//TraditionalForm

Out[1]//TraditionalForm= $$| x|$$
```

#### Function Identities and Simplifications (6)

Expand assuming real variables ``x`` and ``y`` :

```wl
In[1]:= ComplexExpand[Abs[x]]

Out[1]= Sqrt[x^2]

In[2]:= ComplexExpand[Abs[x + I y]]

Out[2]= Sqrt[x^2 + y^2]
```

---

Simplify ``Abs`` using appropriate assumptions:

```wl
In[1]:= Simplify[Abs[x], x > 0]

Out[1]= x
```

---

Express a complex number as a product of ``Abs`` and ``Sign`` :

```wl
In[1]:= FullSimplify[Abs[z]Sign[z]]

Out[1]= z
```

---

Express in terms of real and imaginary parts:

```wl
In[1]:= Abs[x ^ 2]//FunctionExpand

Out[1]= Im[x]^2 + Re[x]^2
```

---

``Abs`` commutes with real exponentiation:

```wl
In[1]:= FullSimplify[Abs[x ^ n] == Abs[x] ^ n, n∈Reals]

Out[1]= True
```

This result is applied automatically for concrete powers:

```wl
In[2]:= Abs[x ^ 2]

Out[2]= Abs[x]^2
```

---

Find the absolute value of a ``Root`` expression:

```wl
In[1]:= Abs[Root[# ^ 5 + 11# ^ 2 + 1&, 2]]//RootReduce

Out[1]= Root[1 - 11*#1^2 - 2*#1^10 + 11*#1^12 - 121*#1^14 + #1^20 & , 3, 0]
```

### Applications (2)

Plot ``Abs`` over the complex plane:

```wl
In[1]:= Plot3D[Abs[x + I y], {x, -3, 3}, {y, -3, 3}]

Out[1]= [image]
```

---

Color plots according to ``Abs`` :

```wl
In[1]:= Plot[Sin[x], {x, 0, 4Pi}, ColorFunction -> (Hue[Abs[#2]]&)]

Out[1]= [image]

In[2]:= Plot3D[Re[Sin[x + I y]], {x, -2Pi, 2Pi}, {y, -1, 1}, ColorFunction -> (Hue[Abs[Sin[#1 + I#2]]]&)]

Out[2]= [image]
```

### Properties & Relations (16)

``Abs`` is idempotent:

```wl
In[1]:= Abs[Abs[z]]

Out[1]= Abs[z]
```

---

``Abs`` is defined for all complex numbers:

```wl
In[1]:= Abs[{3, -5, 2 + 5I}]

Out[1]= {3, 5, Sqrt[29]}
```

``RealAbs`` is defined only for real numbers:

```wl
In[2]:= RealAbs[{3, -5, 2 + 5I}]

Out[2]= {3, 5, RealAbs[2 + 5 I]}
```

---

Simplify expressions containing ``Abs`` :

```wl
In[1]:= {x Abs[x], Abs[2x + 2]}

Out[1]= {x Abs[x], Abs[2 + 2 x]}

In[2]:= Simplify[%, x > 3]

Out[2]= {x^2, 2 (1 + x)}
```

---

Simplification of some identities involving ``Abs`` may require explicit assumptions that variables are real:

```wl
In[1]:= Simplify[Abs[x] ^ 2 == x ^ 2]

Out[1]= x^2 == Abs[x]^2

In[2]:= Simplify[Abs[x] ^ 2 == x ^ 2, x∈Reals]

Out[2]= True
```

The assumptions may not be needed if ``RealAbs`` is used instead:

```wl
In[3]:= Simplify[RealAbs[x] ^ 2 == x ^ 2]

Out[3]= True
```

---

``Abs`` is not a differentiable function:

```wl
In[1]:= Abs'[x]

Out[1]= Derivative[1][Abs][x]
```

``RealAbs`` is differentiable:

```wl
In[2]:= RealAbs'[x]

Out[2]= (x/RealAbs[x])
```

---

Use ``Abs`` as a target function in ``ComplexExpand`` :

```wl
In[1]:= ComplexExpand[Re[ArcSin[x + I y]], TargetFunctions -> {Abs}]

Out[1]= -I Log[Sqrt[1 - (x + I y)^2] + I (x + I y)] + I Log[Abs[Sqrt[1 - (x + I y)^2] + I (x + I y)]]
```

---

Solve an equation involving ``Abs`` :

```wl
In[1]:= Reduce[Abs[x + 3] + Abs[x - 2] == 17, x, Reals]

Out[1]= x == -9 || x == 8
```

---

Prove an inequality containing ``Abs`` :

```wl
In[1]:= Reduce[Abs[z1 + z2 + z3] ≤ Abs[z1] + Abs[z2] + Abs[z3], {z1, z2, z3}, Reals]

Out[1]= True
```

---

Definite integration:

```wl
In[1]:= Integrate[Abs[x], {x, -2, Pi}]

Out[1]= (1/2) (4 + π^2)

In[2]:= Integrate[Abs[x Sin[x]], {x, -2, Pi}]

Out[2]= π - 2 Cos[2] + Sin[2]
```

---

Integrate along a line in the complex plane, symbolically and numerically:

```wl
In[1]:= Integrate[Abs[x], {x, -2 + I, Pi + I}]

Out[1]= (1/2) (2 Sqrt[5] + π Sqrt[1 + π^2] + ArcSinh[2] + ArcSinh[π])

In[2]:= N[%]

Out[2]= 9.06781

In[3]:= NIntegrate[Abs[x], {x, -2 + I, Pi + I}]

Out[3]= 9.06781 + 0. I
```

---

Interpret as the indefinite integral for real arguments:

```wl
In[1]:= Integrate[Abs[x], x]

Out[1]= ∫Abs[x]\[DifferentialD]x

In[2]:= Assuming[x∈Reals, Integrate[Abs[x], x]]

Out[2]=
\[Piecewise]|          |       |
| :------- | :---- |
| -(x^2/2) | x ≤ 0 |
| (x^2/2)  | True  |
```

---

Integral transforms:

```wl
In[1]:= FourierTransform[Abs[y], y, x]

Out[1]= -(Sqrt[(2/π)]/x^2)

In[2]:= LaplaceTransform[Abs[y], y, x]

Out[2]= (1/x^2)
```

---

Obtain ``Abs`` from ``Limit`` :

```wl
In[1]:= Assuming[x∈Reals, (1/π)Limit[ArcTan[(x/ε)], ε -> +0, Direction -> "FromAbove"] + (1/2)]

Out[1]= (1/2) + (Abs[x]/2 x)
```

---

Convert into ``Piecewise`` :

```wl
In[1]:= PiecewiseExpand[Abs[x]Abs[1 - x], x∈Reals]

Out[1]=
\[Piecewise]|             |           |
| :---------- | :-------- |
| -(-1 + x) x | 0 ≤ x ≤ 1 |
| (-1 + x) x  | True      |
```

---

Denest:

```wl
In[1]:= PiecewiseExpand[Abs[x + Abs[1 - x] ^ 3], x∈Reals]

Out[1]=
\[Piecewise]|                        |       |
| :--------------------- | :---- |
| 1 - 2 x + 3 x^2 - x^3  | x ≤ 1 |
| -1 + 4 x - 3 x^2 + x^3 | True  |
```

---

``ComplexPlot3D`` plots the magnitude of a function as height and colors using the phase:

```wl
In[1]:= ComplexPlot3D[Sin[z] ^ 3 / (z + 1) ^ 4, {z, -5 - 5I, 5 + 5I}]

Out[1]= [image]

In[2]:= Plot3D[Abs[Sin[x + I * y] ^ 3 / (x + I * y + 1) ^ 4], {x, -5, 5}, {y, -5, 5}]

Out[2]= [image]
```

### Possible Issues (3)

``Abs`` is a function of a complex variable and is therefore not differentiable:

```wl
In[1]:= D[Abs[z], z]

Out[1]= Derivative[1][Abs][z]
```

As a complex function, it is not possible to write ``Abs[z]`` without involving ``Conjugate[z]`` :

```wl
In[2]:= FullSimplify[Abs[z] == Sqrt[Conjugate[z]z]]

Out[2]= True
```

In particular, the limit that defines the derivative is direction dependent and therefore does not exist:

```wl
In[3]:= Limit[DifferenceQuotient[Abs[z], {z, h}], h -> 0, Direction -> 1]

Out[3]= (Re[z]/Sqrt[Im[z]^2 + Re[z]^2])

In[4]:= Limit[DifferenceQuotient[Abs[z], {z, h}], h -> 0, Direction -> I]

Out[4]= -(I Im[z]/Sqrt[Im[z]^2 + Re[z]^2])
```

Adding assumptions that the argument is real makes ``Abs`` differentiable:

```wl
In[5]:= FullSimplify[Abs'[x], x∈Reals]

Out[5]= Sign[x]
```

Alternatively, use ``RealAbs``, which assumes its argument is real:

```wl
In[6]:= D[RealAbs[x], x]

Out[6]= (x/RealAbs[x])
```

---

``Abs`` can stay unevaluated for some complicated numeric arguments:

```wl
In[1]:= Abs[-1 - 2E - E^2 + (1 + E)^2]
```

N::meprec: Internal precision limit \$MaxExtraPrecision = 50.\` reached while evaluating -1-2 E-E^2+(1+E)^2.

```wl
Out[1]= Abs[-1 - 2 E - E^2 + (1 + E)^2]

In[2]:= Simplify[%]

Out[2]= 0
```

---

No series can be formed from ``Abs`` for complex arguments:

```wl
In[1]:= Series[Abs[x], {x, 0, 2}]

Out[1]= Abs[x]
```

For real arguments, a series can be found:

```wl
In[2]:= Series[Abs[x], {x, 0, 2}, Assumptions -> Element[x, Reals]]

Out[2]=
\[Piecewise]|                                 |       |
| :------------------------------ | :---- |
| SeriesData[x, 0, {-1}, 1, 3, 1] | x ≤ 0 |
| SeriesData[x, 0, {1}, 1, 3, 1]  | True  |
```

### Neat Examples (2)

Form nested functions involving ``Abs`` :

```wl
In[1]:=
SeedRandom[3];
NestList[
	Module[{r := RandomChoice[{-2 / 3, -1 / 2, -1 / 3, 0, 1 / 3, 1 / 2, 2 / 3}]}, (# /. Abs[x_] :> Sum[r Abs[r + r x + r Abs[r + r x]], {2}])]&, Abs[x], 3]//TraditionalForm

Out[1]//TraditionalForm=
$$\left\{| x| ,-\frac{2}{3} \left| \frac{x}{3}+\frac{1}{2} \left| -\frac{x}{3}-\frac{1}{3}\right| -\frac{2}{3}\right| ,-\frac{2}{3} \left(\frac{4}{9}
\left| \frac{1}{2} \left(\frac{x}{3}+\frac{1}{2} \left| -\frac{x}{3}-\frac{1}{3}\right| -\frac{2}{ ... ht| -\frac{2}{3}\right)-\frac{2}{3} \left|
\frac{1}{2} \left(-\frac{x}{3}-\frac{1}{2} \left| -\frac{x}{3}-\frac{1}{3}\right| +\frac{2}{3}\right)-\frac{1}{3}\right| -\frac{1}{2}\right)-\frac{1}{2}\right|
-\frac{1}{2}\right| \right)\right)\right\}$$

In[2]:= Plot[Evaluate[%], {x, -3, 3}]

Out[2]= [image]
```

---

Plot ``Abs`` at Gaussian integers:

```wl
In[1]:= ArrayPlot[Table[Mod[Round[Abs[x + I y]], 2], {x, -36, 36}, {y, -36, 36}]]

Out[1]= [image]
```

## See Also

* [`RealAbs`](https://reference.wolfram.com/language/ref/RealAbs.en.md)
* [`Norm`](https://reference.wolfram.com/language/ref/Norm.en.md)
* [`Re`](https://reference.wolfram.com/language/ref/Re.en.md)
* [`Im`](https://reference.wolfram.com/language/ref/Im.en.md)
* [`Arg`](https://reference.wolfram.com/language/ref/Arg.en.md)
* [`AbsArg`](https://reference.wolfram.com/language/ref/AbsArg.en.md)
* [`Sign`](https://reference.wolfram.com/language/ref/Sign.en.md)
* [`Conjugate`](https://reference.wolfram.com/language/ref/Conjugate.en.md)
* [`Mod`](https://reference.wolfram.com/language/ref/Mod.en.md)
* [`ComplexExpand`](https://reference.wolfram.com/language/ref/ComplexExpand.en.md)

## Tech Notes

* [Some Mathematical Functions](https://reference.wolfram.com/language/tutorial/SomeMathematicalFunctions.en.md)
* [Complex Numbers](https://reference.wolfram.com/language/tutorial/Numbers.en.md#9161)
* [Numerical Functions](https://reference.wolfram.com/language/tutorial/MathematicalFunctions.en.md#21826)
* [Piecewise Functions](https://reference.wolfram.com/language/tutorial/MathematicalFunctions.en.md#690)

## Related Guides

* [Numerical Functions](https://reference.wolfram.com/language/guide/NumericalFunctions.en.md)
* [Complex Numbers](https://reference.wolfram.com/language/guide/ComplexNumbers.en.md)
* [Functions of Complex Variables](https://reference.wolfram.com/language/guide/FunctionsOfComplexVariables.en.md)
* [Image Processing & Analysis](https://reference.wolfram.com/language/guide/ImageProcessing.en.md)
* [GPU Computing](https://reference.wolfram.com/language/guide/GPUComputing.en.md)
* [Mathematical Functions](https://reference.wolfram.com/language/guide/MathematicalFunctions.en.md)
* [Representation of Numbers](https://reference.wolfram.com/language/guide/RepresentationOfNumbers.en.md)
* [GPU Computing with NVIDIA](https://reference.wolfram.com/language/guide/GPUComputing-NVIDIA.en.md)
* [Angles and Polar Coordinates](https://reference.wolfram.com/language/guide/AnglesAndPolarCoordinates.en.md)
* [GPU Computing with Apple](https://reference.wolfram.com/language/guide/GPUComputing-Apple.en.md)
* [Audio Editing](https://reference.wolfram.com/language/guide/AudioEditing.en.md)

## Related Links

* [MathWorld](http://mathworld.wolfram.com/AbsoluteValue.html)
* [An Elementary Introduction to the Wolfram Language: More about Numbers](https://www.wolfram.com/language/elementary-introduction/23-more-about-numbers.html)

## History

* Introduced in 1988 (1.0) \| [Updated in 2021 (13.0)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn130.en.md)