WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

HexahedronElement[{{i11,…,i18},…,{in1,…,in8}}]

インシデント{ik1,…ik8}を持つ n 個の線形六面体要素 ek を表す．

HexahedronElement[{{i11,…,i120},…,{in1,…,in20}}]

インシデント{ik1,…,ik20}を持つ n 個の二次六面体要素 ek を表す．

HexahedronElement[{e1,…,en},{m1,…,mn}]

n 個の六面体要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
一般化と拡張  
アプリケーション  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
引用書式
NDSolve`FEM`
NDSolve`FEM`

HexahedronElement

HexahedronElement[{{i11,…,i18},…,{in1,…,in8}}]

インシデント{ik1,…ik8}を持つ n 個の線形六面体要素 ek を表す．

HexahedronElement[{{i11,…,i120},…,{in1,…,in20}}]

インシデント{ik1,…,ik20}を持つ n 個の二次六面体要素 ek を表す．

HexahedronElement[{e1,…,en},{m1,…,mn}]

n 個の六面体要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション

  • HexahedronElementを使ってElementMesh内の六面体のメッシュ要素を表す．
  • HexahedronElementは，ToElementMeshあるいはToBoundaryMeshへの入力として使うことができる．
  • インシデント ik,j は，空間座標の配列に指標を付ける整数である．ek={ik1,…}が参照する座標は， k 番目の三角形のノードである．
  • 最初の3つのインシデント ik1 は，ik8 までは常に頂点である．
  • 二次三角要素については，次の12個のインシデントは，曲がっている可能性のある辺の中間のノードである．
  • 線形要素は，次数1の要素であり，二次要素は，次数2の要素である．
  • HexahedronElement[{e1,…,en}]では，すべての要素 ek が同じ次数でなければならない．
  • HexahedronElement[{e1,…,en}]の六面体は，共通のノード，辺，面を共有するが，お互いが交差したり，それ自身と交差したりすることがあってはならない．
  • 線形と二次の六面体についてノードが示されている．
  • HexahedronElementについては，面のインシデントは，要素の内側から見た場合に反時計回りでなければならない．要素{i1,…,i8}は，面のインシデント{i1,i2,i3,i4}，{i8,i7,i6,i5}，{i1,i5,i6,i2}，{i2,i6,i7,i3}，{i3,i7,i8,i4}，{i4,i8,i5,i1}を6つの面について持つ．
  • 六面体要素は，有限要素法では，セレンディピティ要素として知られている．

例題

すべて開く すべて閉じる

例  (1)

パッケージをロードする：

Wolfram Language code: <<NDSolve`FEM`

二次要素を1つ持つメッシュを作成する：

Wolfram Language code: ToElementMesh["Coordinates" -> {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {0, 0, 1}, {2, 0, 1}, {2, 2, 1}, {0, 2, 1}}, "MeshElements" -> {HexahedronElement[{{1, 2, 3, 4, 5, 6, 7, 8}}]}]

一般化と拡張  (4)

線形要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[HexahedronElement, 1]

線形要素の基本のインシデント：

Wolfram Language code: e = HexahedronElement[{MeshElementBaseIncidents[HexahedronElement, 1]}]

線形単位要素を持つメッシュ：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

線形単位要素の可視化：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

二次要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[HexahedronElement, 2]

二次要素の基本のインシデント：

Wolfram Language code: e = HexahedronElement[{MeshElementBaseIncidents[HexahedronElement, 2]}]
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]
Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

線形要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[HexahedronElement, 1]

二次要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[HexahedronElement, 2]

アプリケーション  (1)

マーカー付きの線形六面体要素のメッシュ：

Wolfram Language code: coordinates = {{0., 0., 1.}, {1., 0., 1.}, {2., 0., 1.}, {0., 1., 1.}, {1., 1., 1.}, {2., 1., 1.}, {0., 2., 1.}, {1., 2., 1.}, {2., 2., 1.}, {0., 0., 0.}, {1., 0., 0.}, {2., 0., 0.}, {0., 1., 0.}, {1., 1., 0.}, {2., 1., 0.}, {0., 2., 0.}, {1., 2., 0.}, {2., 2., 0.} };

座標の指標をそれぞれの位置で可視化する：

Wolfram Language code: Graphics3D[MapIndexed[Text[ToString[#2[[1]]], #1]&, coordinates]]

メッシュを作成する：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> {HexahedronElement[{{10, 11, 14, 13, 1, 2, 5, 4}, {11, 12, 15, 14, 2, 3, 6, 5}, {13, 14, 17, 16, 4, 5, 8, 7}, {14, 15, 18, 17, 5, 6, 9, 8}}, {1, 1, 2, 2}]}]

要素マーカーと一緒にメッシュを可視化する：

Wolfram Language code: mesh["Wireframe"["MeshElement" -> "MeshElements", "MeshElementMarkerStyle" -> Red, Boxed -> False]]

考えられる問題  (6)

インシデントは，適切な長さでなければならない：

Wolfram Language code: HexahedronElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]

異なる次数インシデントを混ぜて使うことはできない：

Wolfram Language code: HexahedronElement[{{1, 2, 3, 4, 5, 6, 7, 8}, {9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28}}]

インシデントは整数のリストでなければならない：

Wolfram Language code: HexahedronElement[{{a, 2, 3, 4, 5, 6, 7, 8}}]

マーカーの数は，インシデントの数とマッチしなければならない：

Wolfram Language code: HexahedronElement[{{1, 2, 5, 4, 10, 11, 14, 13}, {2, 3, 6, 5, 11, 12, 15, 14}, {4, 5, 8, 7, 13, 14, 17, 16}, {5, 6, 9, 8, 14, 15, 18, 17}}, {1, 1, 2}]

マーカーは，整数のベクトルでなければならない：

Wolfram Language code: HexahedronElement[{{1, 2, 5, 4, 10, 11, 14, 13}, {2, 3, 6, 5, 11, 12, 15, 14}, {4, 5, 8, 7, 13, 14, 17, 16}, {5, 6, 9, 8, 14, 15, 18, 17}}, {1, 1, 2, a}]

可能であれば，非整数のマーカーは，整数に変換される：

Wolfram Language code: HexahedronElement[{{1, 2, 5, 4, 10, 11, 14, 13}, {2, 3, 6, 5, 11, 12, 15, 14}, {4, 5, 8, 7, 13, 14, 17, 16}, {5, 6, 9, 8, 14, 15, 18, 17}}, {1, 1, 2, 2.}]
Wolfram Research (2014), HexahedronElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html.

テキスト

Wolfram Research (2014), HexahedronElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html.

CMS

Wolfram Language. 2014. "HexahedronElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html.

APA

Wolfram Language. (2014). HexahedronElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html

BibTeX

@misc{reference.wolfram_2026_hexahedronelement, author="Wolfram Research", title="{HexahedronElement}", year="2014", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_hexahedronelement, organization={Wolfram Research}, title={HexahedronElement}, year={2014}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/HexahedronElement.html}, note=[Accessed: 12-August-2026]}