WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

PyramidElement[{{i11,i12,i13,i14,i15},…,{in1,in2,in3,in4,in5}}]

インシデント{ik1,ik2,ik3,ik4,ik5}を持つ n 個の線形錐体要素 ek を表す．

PyramidElement[{{i11,…,i113},…,{in1,…,in13}}]

インシデント{ik1,…,ik13}を持つ n 個の二次錐体要素 ek を表す．

PyramidElement[{e1,…,en},{m1,…,mn}]

n 個の錐体要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
一般化と拡張  
アプリケーション  
考えられる問題  
関連項目
関連するガイド
引用書式
NDSolve`FEM`
NDSolve`FEM`

PyramidElement

PyramidElement[{{i11,i12,i13,i14,i15},…,{in1,in2,in3,in4,in5}}]

インシデント{ik1,ik2,ik3,ik4,ik5}を持つ n 個の線形錐体要素 ek を表す．

PyramidElement[{{i11,…,i113},…,{in1,…,in13}}]

インシデント{ik1,…,ik13}を持つ n 個の二次錐体要素 ek を表す．

PyramidElement[{e1,…,en},{m1,…,mn}]

n 個の錐体要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション

  • PyramidElementは，ElementMeshの錐体メッシュ要素を表すのに使われる．
  • PyramidElementは，ToElementMeshへの入力として使うことができる．
  • インシデント ik,j は，空間座標の配列に指標を付ける整数である．ek={ik1,…}が参照する座標は，k 番目の錐体のノードである．
  • 最初の5つのインシデント ik1，ik2，ik3，ik4，ik5は常に頂点である．
  • 二次錐体要素については，次の8つのインシデントは，曲がっている可能性のある辺の中間のノードである．
  • 線形要素は次数1の要素であり，二次要素は次数2の要素である．
  • PyramidElement[{e1,…,en}]では， すべての要素 ek が同じ次数でなければならない．
  • PyramidElement[{e1,…,en}]の錐体は，共通のノード，辺，面を持つが，お互いに交差することはできず，二次の錐体については，それ自身と交差することができない．
  • 以下は，線形錐体と二次錐体のノードである．
  • PyramidElementについては，面のインシデントは反時計回りでなければならない．要素{i1,i2,i3,i4,i5}は，5つの面について面のインシデント{i1,i2,i3,i4}，{i1,i5,i2,0}，{i2,i5,i3,0}，{i3,i5,i4,0}，{i4,i5,i1,0}を持つ．
  • 錐体要素は，有限要素法ではセレンディピティ要素として知られる．
  • 錐体要素は，同じメッシュ内の四面体と六面体をつなぐことができる．
  • 錐体要素は，頂点のノードがつぶれて単独のノードになった，切頂六面体要素として実装される．

例題

すべて開く すべて閉じる

例  (1)

パッケージをロードする：

Wolfram Language code: <<NDSolve`FEM`

錐体要素を1つ含むメッシュを作成する：

Wolfram Language code: ToElementMesh["Coordinates" -> {{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}, {0, 0, 1}}, "MeshElements" -> {PyramidElement[{{1, 2, 3, 4, 5}}]}]

一般化と拡張  (4)

線形要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[PyramidElement, 1]

線形要素の基本のインシデント：

Wolfram Language code: e = PyramidElement[{MeshElementBaseIncidents[PyramidElement, 1]}]

線形単位要素を持つメッシュ：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

線形単位要素の可視化：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

二次要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[PyramidElement, 2]

二次要素の基本のインシデント：

Wolfram Language code: e = PyramidElement[{MeshElementBaseIncidents[PyramidElement, 2]}]

基本の座標とインシデントに基づいてメッシュを作成する：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

メッシュを可視化する：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

二次ノードは，六面体要素のノードであることに注意する．

線形要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[PyramidElement, 1]

二次要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[PyramidElement, 2]

アプリケーション  (1)

四面体と六面体の要素を錐体要素と組み合せる：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> {{0., 1., 0.}, {0., 0., 0.}, {1., 1., 0.}, {1., 0., 0.}, {0., 0., 1.}, {1., 0., 1.}, {1., 1., 1.}, {0., 1., 1.}, {2., 0., 0.}, {2., 0., 1.}, {2., 1., 0.}, {2., 1., 1.}, {1.5, 0.5, 0.}, {1.5, 0.5, 1.}, {1.5, 0., 0.5}, {1.5, 1., 0.5}, {1.5, 0.5, 0.5}}, "MeshElements" -> {TetrahedronElement[{{17, 13, 9, 4}, {4, 17, 13, 3}, {17, 12, 7, 14}, {14, 10, 6, 17}, {15, 4, 17, 9}, {6, 7, 14, 17}, {12, 16, 11, 17}, {16, 17, 3, 11}, {10, 12, 9, 17}, {6, 17, 15, 4}, {10, 6, 17, 15}, {15, 9, 17, 10}, {17, 13, 3, 11}, {16, 17, 12, 7}, {14, 17, 12, 10}, {11, 17, 9, 12}, {13, 17, 9, 11}, {7, 17, 3, 16}}, 1], PyramidElement[{{7, 6, 4, 3, 17}}, 2], HexahedronElement[{{2, 4, 3, 1, 5, 6, 7, 8}}, 4]}]

要素のマーカーと一緒にメッシュを可視化する：

Wolfram Language code: Show[ mesh["Wireframe"["MeshElement" -> "MeshElements"]], mesh["Wireframe"[ElementMarker == 2, "MeshElement" -> "MeshElements", "MeshElementStyle" -> Directive[Opacity[0.3], FaceForm[LightGreen], EdgeForm[Black]]]] ]

考えられる問題  (6)

インシデントは，適切な長さでなければならない：

Wolfram Language code: PyramidElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]

異なる次数インシデントを混ぜて使うことはできない：

Wolfram Language code: PyramidElement[{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18}}]

インシデントは整数のリストでなければならない：

Wolfram Language code: PyramidElement[{{a, 2, 3, 4, 5}}]

マーカーの数は，インシデントの数とマッチしなければならない：

Wolfram Language code: PyramidElement[{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, {1, 1, 2}]

Markers must be a vector of integers:

Wolfram Language code: PyramidElement[{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, {1, a}]

可能であれば，非整数のマーカーは，整数に変換される：

Wolfram Language code: PyramidElement[{{1., 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, {1, 2.}]
Wolfram Research (2026), PyramidElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html.

テキスト

Wolfram Research (2026), PyramidElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html.

CMS

Wolfram Language. 2026. "PyramidElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html.

APA

Wolfram Language. (2026). PyramidElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html

BibTeX

@misc{reference.wolfram_2026_pyramidelement, author="Wolfram Research", title="{PyramidElement}", year="2026", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html}", note=[Accessed: 25-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_pyramidelement, organization={Wolfram Research}, title={PyramidElement}, year={2026}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/PyramidElement.html}, note=[Accessed: 25-August-2026]}