WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

TetrahedronElement[{{i11,i12,i13,i14},…,{in1,in2,in3,in4}}]

インシデント{ik1,ik2,ik3,ik4}を持つ n 個の線形四面体要素 ek を表す．

TetrahedronElement[{{i11,…,i110},…,{in1,…,in10}}]

インシデント{ik1,…,ik10}を持つ n 個の二次四面体要素 ek を表す．

TetrahedronElement[{e1,…,en},{m1,…,mn}]

n 個の四面体要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
一般化と拡張  
アプリケーション  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
引用書式
NDSolve`FEM`
NDSolve`FEM`

TetrahedronElement

TetrahedronElement[{{i11,i12,i13,i14},…,{in1,in2,in3,in4}}]

インシデント{ik1,ik2,ik3,ik4}を持つ n 個の線形四面体要素 ek を表す．

TetrahedronElement[{{i11,…,i110},…,{in1,…,in10}}]

インシデント{ik1,…,ik10}を持つ n 個の二次四面体要素 ek を表す．

TetrahedronElement[{e1,…,en},{m1,…,mn}]

n 個の四面体要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション

  • TetrahedronElementは，ElementMeshの四面体メッシュ要素を表すのに使われる．
  • TetrahedronElementは，ToElementMeshの入力として使うことができる．
  • インシデント ik,j は，空間座標の配列に指標を付ける整数である．ek={ik1,…}によって参照される座標は，k 番目の四面体のノードである．
  • 最初の4つのインシデント ik1，ik2，ik3，ik4 は常に頂点である．
  • 二次四面体要素については，次の6つのインシデントは，湾曲している可能性のある辺の中間のノードである．
  • 線形要素は次数1の要素であり，二次要素は次数2の要素である．
  • TetrahedronElement[{e1,…,en}]では，すべての要素 ek は同じ次数のものでなければならない．
  • TetrahedronElement[{e1,…,en}]の四面体は，共通のノード，辺，面を持つが，お互いに交差することはできず，二次の四面体については，それ自身と交差することができない．
  • 線形と二次の四面体のノードは以下の通りである．
  • TetrahedronElementについては，頂点 ij の反対の面のインシデントは，反時計回りでなければならない．要素{i1,i2,i3,i4}は，4つの面に対して面のインシデント{i4,i3,i2}，{i4,i1,i3}，{i4,i2,i1}，{i1,i2,i3}を持つ．
  • 四面体要素は，有限要素法ではセレンディピティ要素として知られる．

例題

すべて開く すべて閉じる

例  (1)

パッケージをロードする：

Wolfram Language code: <<NDSolve`FEM`

四面体要素を1つ持つメッシュを作成する：

Wolfram Language code: ToElementMesh["Coordinates" -> {{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}}, "MeshElements" -> {TetrahedronElement[{{1, 2, 3, 4}}]}]

一般化と拡張  (4)

線形要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[TetrahedronElement, 1]

線形要素の基本のインシデント：

Wolfram Language code: e = TetrahedronElement[{MeshElementBaseIncidents[TetrahedronElement, 1]}]

線形単位要素を持つメッシュ：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

線形単位要素の可視化：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

二次要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[TetrahedronElement, 2]

二次要素の基本のインシデント：

Wolfram Language code: e = TetrahedronElement[{MeshElementBaseIncidents[TetrahedronElement, 2]}]
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]
Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

線形要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[TetrahedronElement, 1]

二次要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[TetrahedronElement, 2]

アプリケーション  (1)

マーカー付きの線形四面体要素のメッシュの集合：

Wolfram Language code: coordinates = N[Join[{{0, 0, 1}, {0, 0, 0}}, Table[{Sin[i], Cos[i], 0}, {i, 0, 2π - π / 4, π / 4}]]];

座標の指標をそれぞれの位置で可視化する：

Wolfram Language code: Graphics3D[MapIndexed[Text[ToString[#2[[1]]], #1]&, coordinates]]

メッシュを作成する：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> { TetrahedronElement[{{1, 2, 3, 4}, {1, 2, 4, 5}, {1, 2, 5, 6}, {1, 2, 6, 7}, {1, 2, 7, 8}, {1, 2, 8, 9}, {1, 2, 9, 10}, {1, 2, 10, 3}}, {1, 1, 1, 1, 2, 2, 2, 2}] }]

要素マーカーと一緒にメッシュを可視化する：

Wolfram Language code: mesh["Wireframe"["MeshElement" -> "MeshElements", "MeshElementMarkerStyle" -> Red, Boxed -> False]]

考えられる問題  (6)

インシデントは，適切な長さでなければならない：

Wolfram Language code: TetrahedronElement[{{3, 4, 7}, {4, 8, 7}, {7, 9, 12}, {7, 8, 9}}]

異なる次数インシデントを混ぜて使うことはできない：

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6, 5, 1, 8, 9, 11, 12}}]

インシデントは整数のリストでなければならない：

Wolfram Language code: TetrahedronElement[{{a, 2, 6, 5}, {2, 3, 7, 8}, {5, 6, 11, 12}}]

マーカーの数は，インシデントの数とマッチしなければならない：

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2}]

マーカーは，整数のベクトルでなければならない：

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, a}]

可能であれば，非整数のマーカーは，整数に変換される：

Wolfram Language code: TetrahedronElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}, {1, 1, 2, 2.}]
Wolfram Research (2014), TetrahedronElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html.

テキスト

Wolfram Research (2014), TetrahedronElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html.

CMS

Wolfram Language. 2014. "TetrahedronElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html.

APA

Wolfram Language. (2014). TetrahedronElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html

BibTeX

@misc{reference.wolfram_2026_tetrahedronelement, author="Wolfram Research", title="{TetrahedronElement}", year="2014", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_tetrahedronelement, organization={Wolfram Research}, title={TetrahedronElement}, year={2014}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/TetrahedronElement.html}, note=[Accessed: 10-August-2026]}