WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

TriangleElement[{{i11,i12,i13},…,{in1,in2,in3}}]

インシデント{ik1,ik2,ik3}を持つ n 個の線形三角要素 ek を表す．

TriangleElement[{{i11,…,i16},…,{in1,…,in6}}]

インシデント{ik1,…,ik6}を持つ n 個の二次三角要素 ek を表す．

TriangleElement[{e1,…,en},{m1,…,mn}]

n 個の三角要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
引用書式
NDSolve`FEM`
NDSolve`FEM`

TriangleElement

TriangleElement[{{i11,i12,i13},…,{in1,in2,in3}}]

インシデント{ik1,ik2,ik3}を持つ n 個の線形三角要素 ek を表す．

TriangleElement[{{i11,…,i16},…,{in1,…,in6}}]

インシデント{ik1,…,ik6}を持つ n 個の二次三角要素 ek を表す．

TriangleElement[{e1,…,en},{m1,…,mn}]

n 個の三角要素 ek と n 個の整数マーカー mk を表す．

詳細とオプション

  • TriangleElementは，ElementMeshの三角メッシュ要素を表すのに使われる．
  • TriangleElementは，ToElementMeshあるいはToBoundaryMeshへの入力として使うことができる．
  • インシデント ik,j は，空間座標の配列に指標を付ける整数である．ek={ik1,…}が参照する座標は，k 番目の三角形のノードである．
  • 最初の3つのインシデント ik1，ik2，ik3 は常に頂点である．
  • 二次三角要素については，次の3つのインシデントは，曲がっている可能性のある辺の中間のノードである．
  • 線形要素は次数1の要素であり，二次要素は次数2の要素である．
  • TriangleElement[{e1,…,en}]では， すべての要素 ek が同じ次数でなければならない．
  • TriangleElement[{e1,…,en}]の三角形は，共通のノードと辺を持つが，お互いに交差することはできず，二次の三角形については，それ自身と交差することができない．
  • 線形と二次の三角形のノードは以下の通りである．
  • インシデント{i1,i2,i3}は，i1で参照される座標から i2で参照されるもの，そして i3で参照されるものと続くように，反時計回りに並べられなければならない．
  • 通常，TriangleElementは二次元領域に使われるが，例えば境界メッシュの一部として三次元に埋め込むこともできる．
  • 三角要素は，有限要素法ではセレンディピティ要素として知られる．

例題

すべて開く すべて閉じる

例  (1)

パッケージをロードする：

Wolfram Language code: <<NDSolve`FEM`

三角要素を1つ持つメッシュを作成する：

Wolfram Language code: ToElementMesh["Coordinates" -> {{0, 0}, {1, 0}, {0, 1}}, "MeshElements" -> {TriangleElement[{{1, 2, 3}}]}]

スコープ  (1)

三角要素を持つ境界メッシュ：

Wolfram Language code: bmesh = ToBoundaryMesh["Coordinates" -> {{0., 0., 0.}, {2., 0., 0.}, {2., 1., 0.}, {0., 1., 0.}, {0., 0., 1.}, {2., 0., 1.}, {2., 1., 1.}, {0., 1., 1.}}, "BoundaryElements" -> {TriangleElement[{{1, 2, 3}, {6, 5, 7}, {3, 4, 1}, {7, 2, 6}, {7, 5, 8}, {7, 8, 3}, {3, 2, 7}, {1, 4, 8}, {8, 4, 3}, {1, 5, 6}, {8, 5, 1}, {6, 2, 1}}]}]

ワイヤフレームを可視化する：

Wolfram Language code: bmesh["Wireframe"[Boxed -> False]]

一般化と拡張  (4)

線形要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[TriangleElement, 1]

線形要素の基本のインシデント：

Wolfram Language code: e = TriangleElement[{MeshElementBaseIncidents[TriangleElement, 1]}]

線形単位要素を持つメッシュ：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]

線形単位要素の可視化：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

二次要素の基本の座標：

Wolfram Language code: c = MeshElementBaseCoordinates[TriangleElement, 2]

二次要素の基本のインシデント：

Wolfram Language code: e = TriangleElement[{MeshElementBaseIncidents[TriangleElement, 2]}]
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> c, "MeshElements" -> {e}]
Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

線形要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[TriangleElement, 1]

二次要素の基本の面のインシデント：

Wolfram Language code: e = MeshElementBaseFaceIncidents[TriangleElement, 2]

アプリケーション  (3)

メッシュ内の線形三角要素：

Wolfram Language code: mesh = ToElementMesh["Coordinates" -> {{1.293, 0.228}, {1., 0.}, {0.94, 0.342}, {1.293, 0.}, {1.215, 0.442}, {2., 0.}, {1.879, 0.684}}, "MeshElements" -> {TriangleElement[{{1, 3, 2}, {1, 2, 4}, {1, 4, 6}, {1, 6, 7}, {1, 7, 5}, {1, 5, 3}}]}]

要素マーカーと一緒にメッシュを可視化する：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

メッシュ内の二次三角要素

Wolfram Language code: coordinates = {{1.293, 0.228}, {1., 0.}, {0.94, 0.342}, {1.293, 0.}, {1.215, 0.442}, {2., 0.}, {1.879, 0.684}, {0.97, 0.171}, {1.0775000000000001, 0.392}, {1.1164999999999998, 0.28500000000000003}, {1.1465, 0.}, {1.1465, 0.114}, {1.254, 0.335}, {1.293, 0.114}, {1.5470000000000002, 0.5630000000000001}, {1.5859999999999999, 0.456}, {1.6465, 0.}, {1.6465, 0.114}, {1.9395, 0.342}};
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> {TriangleElement[{{1, 3, 2, 10, 8, 12}, {1, 2, 4, 12, 11, 14}, {1, 4, 6, 14, 17, 18}, {1, 6, 7, 18, 19, 16}, {1, 7, 5, 16, 15, 13}, {1, 5, 3, 13, 9, 10}}]}]

要素マーカーと一緒にメッシュを可視化する：

Wolfram Language code: Show[mesh["Wireframe"], mesh["Wireframe"["MeshElement" -> "PointElements", "MeshElementStyle" -> Directive[Red, PointSize[0.02]], "MeshElementIDStyle" -> Blue]]]

マーカー付きの三角要素のメッシュ：

Wolfram Language code: coordinates = {{0., 0.}, {1., 0.}, {2., 0.}, {2.5, 0.5}, {0., 1.}, {1., 1.}, {2., 1.}, {3., 1.}, {2.5, 1.5}, {0., 2.}, {1., 2.}, {2., 2.}};
Wolfram Language code: mesh = ToElementMesh["Coordinates" -> coordinates, "MeshElements" -> {TriangleElement[{{1, 2, 6}, {6, 5, 1}, {2, 3, 7}, {7, 6, 2}, {3, 4, 7}, {4, 8, 7}, {5, 6, 11}, {11, 10, 5}, {6, 7, 12}, {12, 11, 6}, {7, 9, 12}, {7, 8, 9}}, {1, 1, 1, 1, 1, 1, 2, 2, 2, 2, 2, 2}]}]

要素マーカーと一緒にメッシュを可視化する：

Wolfram Language code: mesh["Wireframe"["MeshElementMarkerStyle" -> Red]]

考えられる問題  (6)

インシデントは，適切な長さでなければならない：

Wolfram Language code: TriangleElement[{{1, 2, 6, 5}, {2, 3, 7, 6}, {5, 6, 11, 10}, {6, 7, 12, 11}}]

異なる次数インシデントを混ぜて使うことはできない：

Wolfram Language code: TriangleElement[{{1, 2, 6}, {2, 3, 7, 6, 5, 1}}]

インシデントは整数のリストでなければならない：

Wolfram Language code: TriangleElement[{{a, 2, 6}, {2, 3, 7}, {5, 6, 11}}]

マーカーの数は，インシデントの数とマッチしなければならない：

Wolfram Language code: TriangleElement[{{1, 2, 6}, {2, 3, 7}, {5, 6, 11}}, {1, 1, 2, 2}]

マーカーは，整数のベクトルでなければならない：

Wolfram Language code: TriangleElement[{{1, 2, 6}, {2, 3, 7}, {5, 6, 11}}, {1, 1, a}]

可能であれば，非整数のマーカーは，整数に変換される：

Wolfram Language code: TriangleElement[{{1, 2, 6}, {2, 3, 7}, {5, 6, 11}}, {1, 1, 2.}]
Wolfram Research (2014), TriangleElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/TriangleElement.html.

テキスト

Wolfram Research (2014), TriangleElement, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/TriangleElement.html.

CMS

Wolfram Language. 2014. "TriangleElement." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/TriangleElement.html.

APA

Wolfram Language. (2014). TriangleElement. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/TriangleElement.html

BibTeX

@misc{reference.wolfram_2026_triangleelement, author="Wolfram Research", title="{TriangleElement}", year="2014", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/TriangleElement.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_triangleelement, organization={Wolfram Research}, title={TriangleElement}, year={2014}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/TriangleElement.html}, note=[Accessed: 13-September-2026]}