WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AdjustTimeSeriesForecast[tproc,forecast,newdata]

時系列モデル tproc による新たな観察 newdata を使って forecast を調整する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

AdjustTimeSeriesForecast

AdjustTimeSeriesForecast[tproc,forecast,newdata]

時系列モデル tproc による新たな観察 newdata を使って forecast を調整する．

詳細

  • AdjustTimeSeriesForecastは，通常，新たなデータが利用可能になった後に既知のモデルの予測を調整するために用いられる関数である．
  • AdjustTimeSeriesForecastは forecast で与えられたものと同じタイプのオブジェクトを返す．
  • AdjustTimeSeriesForecast[tproc,forecast,newdata]では，forecast は次の形で与えることができる．
  • {s0,…}時間 i における状態 siの経路
    {{t0,s0},…}時間 tiにおける状態 siの経路
    TimeSeries[…], EventSeries[…]1本の経路系列オブジェクト
    TemporalData[…]1本または複数の経路
  • 時間 tiと状態 siは，過程 tproc の時間と状態の領域に属さなければならない．
  • 時系列モデル tproc は，ARProcessやMAProcessのような離散時間過程でなければならない．
  • forecast がタイムスタンプを含むオブジェクトとして与えられる場合には，newdata はタイムスタンプに従って並べられる．forecast がベクトルとして与えられる場合には，newdata に含まれる任意のタイムスタンプは無視され，forecast および newdata はどちらも同じ時点で始まる連続する観察のリストとして扱われる．newdata に時間の情報が含まれない場合には，forecast の最初のタイムスタンプで始まるタイムスタンプが作成される．
  • AdjustTimeSeriesForecastは，弱定常時系列モデルではないものについて信頼できない結果を返すことがある． »

例題

すべて開く すべて閉じる

例  (3)

移動平均過程の予測を新しいデータ点を1つ使って更新する：

Wolfram Language code: AdjustTimeSeriesForecast[MAProcess[{1 / 10}, 1], {1, 0, 0}, {1.3}]

自己回帰過程の予測を新しいデータ点2つを使って更新する：

Wolfram Language code: AdjustTimeSeriesForecast[ARProcess[{1 / 3}, 1], {x, y, z}, {a, b}]

定常の季節的な自己回帰移動平均過程について予測を更新する：

Wolfram Language code: proc = SARMAProcess[{.2}, {.3}, {4, {.5}, {.4}}, 1]; sample = RandomFunction[proc, {0, 100}];

20ステップ先の予測を作成する：

Wolfram Language code: forecast = TimeSeriesForecast[proc, sample, {20}];

新しいデータ点2つを使って予測を更新する：

Wolfram Language code: update = AdjustTimeSeriesForecast[proc, forecast, {0, .2}];
Wolfram Language code: ListLinePlot[{sample, forecast, update}, PlotLegends -> {"data", "forecast", "update"}]

スコープ  (5)

予測と新しいデータの両方をベクトルとして入力する：

Wolfram Language code: forecast = {.1, .2, .3}; newdata = {s}; AdjustTimeSeriesForecast[ARMAProcess[{.1}, {.2}, 1], forecast, newdata]

予測をベクトルとして，新しいデータをTimeSeriesとして入力する：

Wolfram Language code: forecast = {.1, .2, .3};
Wolfram Language code: newdata = TimeSeries[{s}, {{5}}];

タイムスタンプは無視される：

Wolfram Language code: AdjustTimeSeriesForecast[ARMAProcess[{.1}, {.2}, 1], forecast, newdata]

予測をTemporalDataとして，新しいデータをベクトルとして入力する：

Wolfram Language code: proc = ARMAProcess[2, {.4}, {.2}, 1]; data = RandomFunction[proc, {0, 10}];

4ステップ先の予測を求める：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {4}]
Wolfram Language code: forecast["Path"]

予測を新しいデータ点2つで調整する：

Wolfram Language code: newdata = {1.5, 3}; update = AdjustTimeSeriesForecast[ARMAProcess[{.3}, {.2}, 1], forecast, newdata]
Wolfram Language code: update["Path"]

データ，予測，調整後の予測をプロットする：

Wolfram Language code: ListLinePlot[{data, forecast, update, TimeSeries[newdata, {{11, 12}}]}, Filling -> Axis, PlotLegends -> {"data", "forecast", "update", "new data"}]

予測と新しいデータをどちらもTemporalDataとして入力する：

Wolfram Language code: proc = ARMAProcess[1, {.4}, {.2}, 1]; data = RandomFunction[proc, {0, 20}];

10ステップ先の予測を求める：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {10}]
Wolfram Language code: forecast["Path"]

時点25から始まる新しいデータを定義する：

Wolfram Language code: newdata = TemporalData[{{0.7, .8}}, {{25, 26}}]
Wolfram Language code: newdata["Path"]

更新された予測を求める：

Wolfram Language code: update = AdjustTimeSeriesForecast[ARMAProcess[{.3}, {.2}, 1], forecast, newdata]
Wolfram Language code: update["Path"]

新しいデータが使用できるようになるまで，更新された予測は変わらない：

Wolfram Language code: ListLinePlot[{data, forecast, update, newdata}, Filling -> Axis, PlotLegends -> {"data", "forecast", "update", "new data"}]

ベクトル値時系列過程についての予測を調整する：

Wolfram Language code: proc = ARMAProcess[{{{.3, .1}, {.3, .1}}}, {{{.2, 1}, {.5, -.3}}}, {{1, .2}, {.2, 1}}]; data = RandomFunction[proc, {0, 15}];

時点10までのデータに基づく予測を作る：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data["Part", All, {0, 10}], {10}]

経路の次の2つの点を使って予測を更新する：

Wolfram Language code: newdata = data["Part", All, {{11, 12}}]
Wolfram Language code: af = AdjustTimeSeriesForecast[proc, forecast, newdata]

データを，各成分についての予測および調整された予測と比較する：

Wolfram Language code: Row@Table[ListLinePlot[#["PathComponent", j]& /@ {data, forecast, af}, PlotLabel -> Subscript[x, j], PlotLegends -> {"data", "forecast", "update"}], {j, 1, 2}]

特性と関係  (1)

平均二乗誤差で調整された予測を求める：

Wolfram Language code: forecast = TemporalData[Automatic, {{{-0.5903162966787826, -0.19524322222065948, -0.07672129988322252, -0.04116472318199142, -0.030497750171622096, -0.0272976582685113, -0.02633763069757806, -0.02604962242629809, -0.025963219944914094, -0.0259372992004989}}, {{21, 30, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {}}, False, 10.]; af = AdjustTimeSeriesForecast[ARMAProcess[{.3}, {.2}, 1], forecast, {-.3}]
Wolfram Language code: ListLinePlot[{forecast, af}, PlotRange -> All, AxesOrigin -> {21, -1}]

調整された予測の誤差を求める：

Wolfram Language code: errors = af["MeanSquaredErrors"]
Wolfram Language code: errors["Path"]

考えられる問題  (2)

非定常時系列の予測を更新すると，信頼できない結果になることがある：

Wolfram Language code: proc = SARIMAProcess[{.2}, 1, {.3}, {4, {.3}, 1, {.4}}, 1]; SeedRandom[34];sample = RandomFunction[proc, {0, 100}]; WeakStationarity[proc]

20ステップ先の予測を作成する：

Wolfram Language code: forecast = TimeSeriesForecast[proc, sample, {20}];
Wolfram Language code: forecast["Path"]
Wolfram Language code: ListLinePlot[{sample, forecast}]

予測を新しいデータ点2つで調整する：

Wolfram Language code: update = AdjustTimeSeriesForecast[proc, forecast, {420, 512}]; ListLinePlot[{sample, forecast, update}, PlotLegends -> {"data", "forecast", "update"}]

平均二乗誤差は予測に平均二乗誤差が含まれる場合にのみ，使用できる：

Wolfram Language code: af = AdjustTimeSeriesForecast[MAProcess[{1 / 10}, 1], {1, 0, 0}, {1.3}]
Wolfram Language code: errors = af["MeanSquarredErrors"]
Wolfram Research (2012), AdjustTimeSeriesForecast, Wolfram言語関数， https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html.

テキスト

Wolfram Research (2012), AdjustTimeSeriesForecast, Wolfram言語関数， https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html.

CMS

Wolfram Language. 2012. "AdjustTimeSeriesForecast." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html.

APA

Wolfram Language. (2012). AdjustTimeSeriesForecast. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html

BibTeX

@misc{reference.wolfram_2026_adjusttimeseriesforecast, author="Wolfram Research", title="{AdjustTimeSeriesForecast}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_adjusttimeseriesforecast, organization={Wolfram Research}, title={AdjustTimeSeriesForecast}, year={2012}, url={https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html}, note=[Accessed: 18-August-2026]}