WOLFRAM

Wolfram 语言与系统参考资料中心

AdjustTimeSeriesForecast[tproc,forecast,newdata]

使用新的观测结果 newdata 根据时间序列模型 tproc 调整 forecast.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AdjustTimeSeriesForecast

AdjustTimeSeriesForecast[tproc,forecast,newdata]

使用新的观测结果 newdata 根据时间序列模型 tproc 调整 forecast.

更多信息

  • AdjustTimeSeriesForecast 通常用于在获得新数据后，调整已知模型的预测.
  • AdjustTimeSeriesForecast 返回的对象类型与 forecast 中所给定的相同.
  • 可用以下形式给出 forecast 和 newdata 序列：
  • {s0,…}状态 si 在时刻 i 的路径
    {{t0,s0},…}状态 si 在时刻 ti 的路径
    TemporalData[…]一个或多个路径
  • 时刻 ti 和状态 si 必须属于过程 tproc 的时间和状态域.
  • 时间序列模型 tproc 必须是一个离散时间过程，如 ARProcess 或 MAProcess.
  • 当 forecast 作为含有时间标记的对象给出时，newdata 根据时间标记排列. 如果 forecast 作为向量给出，则忽略任何来自 newdata 的时间标记，并且 forecast 和 newdata 被视为起始于相同时间点的连续观测结果的列表. 当 newdata 不带有任何时间信息时，时间标记从 forecast 的第一个时间标记开始创建.
  • 对于非弱平稳时间序列模型，AdjustTimeSeriesForecast 可能会给出不可靠的结果. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

对含有一个新数据点的 MA 过程的预测进行更新：

Wolfram Language code: AdjustTimeSeriesForecast[MAProcess[{1 / 10}, 1], {1, 0, 0}, {1.3}]

对含有两个新数据点的 AR 过程的预测进行更新：

Wolfram Language code: AdjustTimeSeriesForecast[ARProcess[{1 / 3}, 1], {x, y, z}, {a, b}]

对平稳 SARMA 过程的预测进行更新：

Wolfram Language code: proc = SARMAProcess[{.2}, {.3}, {4, {.5}, {.4}}, 1]; sample = RandomFunction[proc, {0, 100}];

创建对未来20步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, sample, {20}];

更新带有两个新数据点的预测：

Wolfram Language code: update = AdjustTimeSeriesForecast[proc, forecast, {0, .2}];
Wolfram Language code: ListLinePlot[{sample, forecast, update}, PlotLegends -> {"data", "forecast", "update"}]

范围  (5)

将预测和新数据作为向量输入：

Wolfram Language code: forecast = {.1, .2, .3}; newdata = {s}; AdjustTimeSeriesForecast[ARMAProcess[{.1}, {.2}, 1], forecast, newdata]

将预测作为向量、新数据作为 TimeSeries 输入：

Wolfram Language code: forecast = {.1, .2, .3};
Wolfram Language code: newdata = TimeSeries[{s}, {{5}}];

时间标记被忽略：

Wolfram Language code: AdjustTimeSeriesForecast[ARMAProcess[{.1}, {.2}, 1], forecast, newdata]

将预测作为 TemporalData 、新数据作为向量输入：

Wolfram Language code: proc = ARMAProcess[2, {.4}, {.2}, 1]; data = RandomFunction[proc, {0, 10}];

求对未来四步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {4}]
Wolfram Language code: forecast["Path"]

对带有两个新数据点的预测进行调整：

Wolfram Language code: newdata = {1.5, 3}; update = AdjustTimeSeriesForecast[ARMAProcess[{.3}, {.2}, 1], forecast, newdata]
Wolfram Language code: update["Path"]

绘制数据、预测和调整后的预测：

Wolfram Language code: ListLinePlot[{data, forecast, update, TimeSeries[newdata, {{11, 12}}]}, Filling -> Axis, PlotLegends -> {"data", "forecast", "update", "new data"}]

将预测和新数据作为 TemporalData 输入：

Wolfram Language code: proc = ARMAProcess[1, {.4}, {.2}, 1]; data = RandomFunction[proc, {0, 20}];

求对未来10步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {10}]
Wolfram Language code: forecast["Path"]

定义从时刻25开始的新数据：

Wolfram Language code: newdata = TemporalData[{{0.7, .8}}, {{25, 26}}]
Wolfram Language code: newdata["Path"]

求更新后的预测：

Wolfram Language code: update = AdjustTimeSeriesForecast[ARMAProcess[{.3}, {.2}, 1], forecast, newdata]
Wolfram Language code: update["Path"]

更新的预测保持不变，直到新的数据可用时为止：

Wolfram Language code: ListLinePlot[{data, forecast, update, newdata}, Filling -> Axis, PlotLegends -> {"data", "forecast", "update", "new data"}]

调整对向量值时间序列过程的预测：

Wolfram Language code: proc = ARMAProcess[{{{.3, .1}, {.3, .1}}}, {{{.2, 1}, {.5, -.3}}}, {{1, .2}, {.2, 1}}]; data = RandomFunction[proc, {0, 15}];

基于数据创建时刻10以内的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data["Part", All, {0, 10}], {10}]

使用路径上的下两个点，更新预测：

Wolfram Language code: newdata = data["Part", All, {{11, 12}}]
Wolfram Language code: af = AdjustTimeSeriesForecast[proc, forecast, newdata]

对每个组件，比较数据与预测和调整后的预测：

Wolfram Language code: Row@Table[ListLinePlot[#["PathComponent", j]& /@ {data, forecast, af}, PlotLabel -> Subscript[x, j], PlotLegends -> {"data", "forecast", "update"}], {j, 1, 2}]

属性和关系  (1)

求调整后的预测，带有均值平方误差：

Wolfram Language code: forecast = TemporalData[Automatic, {{{-0.5903162966787826, -0.19524322222065948, -0.07672129988322252, -0.04116472318199142, -0.030497750171622096, -0.0272976582685113, -0.02633763069757806, -0.02604962242629809, -0.025963219944914094, -0.0259372992004989}}, {{21, 30, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {}}, False, 10.]; af = AdjustTimeSeriesForecast[ARMAProcess[{.3}, {.2}, 1], forecast, {-.3}]
Wolfram Language code: ListLinePlot[{forecast, af}, PlotRange -> All, AxesOrigin -> {21, -1}]

求调整后的预测误差：

Wolfram Language code: errors = af["MeanSquaredErrors"]
Wolfram Language code: errors["Path"]

可能存在的问题  (2)

对非平稳时间序列过程的预测进行更新，可能会给出不可靠的结果：

Wolfram Language code: proc = SARIMAProcess[{.2}, 1, {.3}, {4, {.3}, 1, {.4}}, 1]; SeedRandom[34];sample = RandomFunction[proc, {0, 100}]; WeakStationarity[proc]

创建对未来20步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, sample, {20}];
Wolfram Language code: forecast["Path"]
Wolfram Language code: ListLinePlot[{sample, forecast}]

调整带有两个新数据点的预测：

Wolfram Language code: update = AdjustTimeSeriesForecast[proc, forecast, {420, 512}]; ListLinePlot[{sample, forecast, update}, PlotLegends -> {"data", "forecast", "update"}]

均方误差仅适用于原来的预测自带均方误差的情况：

Wolfram Language code: af = AdjustTimeSeriesForecast[MAProcess[{1 / 10}, 1], {1, 0, 0}, {1.3}]
Wolfram Language code: errors = af["MeanSquarredErrors"]
Wolfram Research (2012)，AdjustTimeSeriesForecast，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html.

文本

Wolfram Research (2012)，AdjustTimeSeriesForecast，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html.

CMS

Wolfram 语言. 2012. "AdjustTimeSeriesForecast." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html.

APA

Wolfram 语言. (2012). AdjustTimeSeriesForecast. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html 年

BibTeX

@misc{reference.wolfram_2026_adjusttimeseriesforecast, author="Wolfram Research", title="{AdjustTimeSeriesForecast}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_adjusttimeseriesforecast, organization={Wolfram Research}, title={AdjustTimeSeriesForecast}, year={2012}, url={https://reference.wolfram.com/language/ref/AdjustTimeSeriesForecast.html}, note=[Accessed: 13-August-2026]}