WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AggregatedEntityClass[class,"prop"f]

関数 f を指定の実体クラス全体に適用した結果を値とする特性 prop を持つ，単一の実体を含む実体クラスを表す．

AggregatedEntityClass[class,{"prop1"f1,"prop2"f2,…}]

fiを class に適用して得られた複数の特性 propiを構築する．

AggregatedEntityClass[class,propspec,gprop]

特性 gprop の値に従って class の要素のグループを作り，次にこれら各グループの実体で実体クラスを生成する．

AggregatedEntityClass[class,propspec,"pname"f]

実体関数 f を適用して得られた値に従って，pname という名前の結果の特性を使ってグループを作る．

AggregatedEntityClass[class,propspec,{gspec1,gspec2,…}]

gspeciによって定義された値の集合が重ならないグループを作る．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

AggregatedEntityClass

AggregatedEntityClass[class,"prop"f]

関数 f を指定の実体クラス全体に適用した結果を値とする特性 prop を持つ，単一の実体を含む実体クラスを表す．

AggregatedEntityClass[class,{"prop1"f1,"prop2"f2,…}]

fiを class に適用して得られた複数の特性 propiを構築する．

AggregatedEntityClass[class,propspec,gprop]

特性 gprop の値に従って class の要素のグループを作り，次にこれら各グループの実体で実体クラスを生成する．

AggregatedEntityClass[class,propspec,"pname"f]

実体関数 f を適用して得られた値に従って，pname という名前の結果の特性を使ってグループを作る．

AggregatedEntityClass[class,propspec,{gspec1,gspec2,…}]

gspeciによって定義された値の集合が重ならないグループを作る．

詳細

例題

すべて開く すべて閉じる

例  (3)

すべての国の集計を作成し，それらの総面積を計算する：

Wolfram Language code: AggregatedEntityClass["Country", "TotalArea" -> EntityFunction[e, Total[e["Area"]]]]["TotalArea"]

小さいデータ集合に適した，同等の計算：

Wolfram Language code: Total[EntityValue["Country", "Area"]]

各周期クラスについて元素の平均原子質量を求める：

Wolfram Language code: AggregatedEntityClass["Element", "AtomicMass" -> Mean, "Period"]["AtomicMass"]

リレーショナルデータベースがバックエンドの実体と一緒に使われた場合，引数が2つのAggregatedEntityClassは，SELECT文で集約関数を使うことに相当する：

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[FindFile["ExampleData/ecommerce-database.sqlite"]]]]

支払い総額を計算する：

Wolfram Language code: AggregatedEntityClass["payments", "amount" -> Total]["amount"]

国ごとの最大クレジット限度額を計算する（SQL言語のGROUP BY文に似ている）：

Wolfram Language code: AggregatedEntityClass["customers", "creditLimit" -> Max, "country"][{"country", "creditLimit"}]

スコープ  (4)

第3引数はEntityFunctionでよい：

Wolfram Language code: AggregatedEntityClass["Country", "MeanArea" -> EntityFunction[e, Mean[e["Area"]]], "RoundedPopulation" -> EntityFunction[c, Round[c["Population"], 100000000]]][{"RoundedPopulation", "MeanArea"}]

結果に関数（通常は集約関数）を適用する：

Wolfram Language code: AggregatedEntityClass[["G7"], "AggregatedPopulation" -> EntityFunction[e, f[e[EntityProperty["Country", "Population"]]]]]["AggregatedPopulation"]

これを使って結果の平均値を計算する：

Wolfram Language code: AggregatedEntityClass[["G7"], "MeanPopulation" -> EntityFunction[e, Mean[e[EntityProperty["Country", "Population"]]]]]["MeanPopulation"]//N

あるいは，結果の円グラフを作る：

Wolfram Language code: AggregatedEntityClass[["G7"], "PopulationChart" -> EntityFunction[e, PieChart[e[EntityProperty["Country", "Population"]]]]]["PopulationChart"]

ヨーロッパ諸国の総面積と人口を計算する：

Wolfram Language code: AggregatedEntityClass[EntityClass["Country", "Europe"], {"Area" -> Total, "Population" -> Total}][{"Population", "Area"}]

多面体をキラルか凹面かどうかでグループ化し，各グループの長さを計算する：

Wolfram Language code: AggregatedEntityClass["Polyhedron", "Count" -> EntityFunction[e, Length[e]], {"Chiral", "Concave"}]["Count", "EntityAssociation"]

特性と関係  (2)

AggregatedEntityClassは，群に対応する実体を生成する：

Wolfram Language code: EntityList[AggregatedEntityClass["Element", "AtomicNumber" -> Mean, "Period"]]

AggregatedEntityClassから得られた単一の実体は，事実上，陰的実体に対応する：

Wolfram Language code: Entity["Food", { EntityProperty["Food", "FoodType"] -> ContainsExactly[{Entity["FoodType", "IceCream"]}], EntityProperty["Food", "AddedFoodTypes"] -> ContainsExactly[{}], EntityProperty["Food", "Flavor"] -> Entity["FoodFlavor", "Chocolate"] } ]["RelativeTotalCaloriesContent"]
Wolfram Language code: AggregatedEntityClass[EntityClass["Food", {EntityProperty["Food", "FoodType"] -> ContainsExactly[{Entity["FoodType", "IceCream"]}], EntityProperty["Food", "AddedFoodTypes"] -> ContainsExactly[{}], EntityProperty["Food", "Flavor"] -> Entity["FoodFlavor", "Chocolate"]}], "RelativeTotalCaloriesContent" -> Median @* DeleteMissing]["RelativeTotalCaloriesContent"]

おもしろい例題  (1)

多面体を頂点数と凸状かどうかでグループ化し，「コラージュ」特性を指定する：

Wolfram Language code: polys = AggregatedEntityClass["Polyhedron", "collage" -> EntityFunction[e, ImageCollage[e["Image"]]], {"VertexCount", "Convex"}];

グループを頂点数でソートし，コラージュをTabularで表示する：

Wolfram Language code: SortedEntityClass[polys, "VertexCount"][{"collage"}, "Tabular"]
Wolfram Research (2019), AggregatedEntityClass, Wolfram言語関数， https://reference.wolfram.com/language/ref/AggregatedEntityClass.html.

テキスト

Wolfram Research (2019), AggregatedEntityClass, Wolfram言語関数， https://reference.wolfram.com/language/ref/AggregatedEntityClass.html.

CMS

Wolfram Language. 2019. "AggregatedEntityClass." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AggregatedEntityClass.html.

APA

Wolfram Language. (2019). AggregatedEntityClass. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AggregatedEntityClass.html

BibTeX

@misc{reference.wolfram_2026_aggregatedentityclass, author="Wolfram Research", title="{AggregatedEntityClass}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/AggregatedEntityClass.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_aggregatedentityclass, organization={Wolfram Research}, title={AggregatedEntityClass}, year={2019}, url={https://reference.wolfram.com/language/ref/AggregatedEntityClass.html}, note=[Accessed: 17-August-2026]}