WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AirSoundAttenuation[spec,frequency]

湿った空気中の音の減衰係数を frequency について指定されたパラメータ spec で返す．

AirSoundAttenuation[spec,frequency, distance]

音の減衰因子を distance における指定されたパラメータについて返す．

AirSoundAttenuation[spec,frequency, distance,sl]

ソースのサウンドレベルが sl のときの distance におけるサウンドレベルを返す．

AirSoundAttenuation[spec,audio, distance]

ソースからの distance に基づいて audio を変換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Method  
UnitSystem  
考えられる問題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

AirSoundAttenuation

AirSoundAttenuation[spec,frequency]

湿った空気中の音の減衰係数を frequency について指定されたパラメータ spec で返す．

AirSoundAttenuation[spec,frequency, distance]

音の減衰因子を distance における指定されたパラメータについて返す．

AirSoundAttenuation[spec,frequency, distance,sl]

ソースのサウンドレベルが sl のときの distance におけるサウンドレベルを返す．

AirSoundAttenuation[spec,audio, distance]

ソースからの distance に基づいて audio を変換する．

詳細とオプション

  • spec は，次のパラメータに対応するキーがある連想でなければならない．
  • "DewPointTemperature"露点温度
    "DryBulbTemperature"乾球温度
    "HumidityRatio"混合比
    "Pressure"大気圧
    "RelativeHumidity"相対湿度
    "WetBulbTemperature"湿球温度
  • "DryBulbTemperature"は，他の温度または湿度測定のいずれかを含めるのと同様に必要である．"Pressure"は含めても含めなくてもよい．
  • "Pressure"は，他に指定がない限り，Quantity[101325,"Pascals"]の値を持つものと想定される．
  • 複数の湿度測定値が含まれる場合，それらの値は"DewPointTemperature"，"RelativeHumidity"，"HumidityRatio"，"DewPointTemperature"の順で使われる．
  • frequency は50Hzから20kHzまでのQuantityでなければならない．
  • distance は次元長のQuantityでなければならない．
  • 音の減衰係数は単位長あたりのデシベル単位で返される．
  • 音の減衰因子はソースのサウンドレベルが縮小される数値係数である．
  • 次は，使用可能なオプションである．
  • Method Automatic使用するメソッド
    UnitSystem $UnitSystem返される数量の単位を指定する
  • UnitSystemのサポートには"Imperial"と"Metric"の設定がある．音の減衰係数はメートル単位ではメートルあたりのデシベル単位で，帝国単位ではフィートあたりのデシベル単位で返される．
  • Methodは移動距離による音の分散を考慮して調整される"IncludeDispersion"メソッドをサポートする．オプション"ReferenceDistance"を使うと，ソースのサウンドレベルあるいは音声がサンプルされた点までの距離が指定できる．
  • sl はデシベルQuantity，または，ネーパー．オクターブ，ディケードのような，デシベルと互換の単位でなければならない．
  • サウンドレベルは sl と同じ単位で返される．
  • audio は有効なAudioオブジェクトでなければならない．結果はサウンドが frequency と distance に従って減衰されたAudioオブジェクトになる．

例題

すべて開く すべて閉じる

例  (3)

音響減衰係数を計算する：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[1000, "Hertz"]]

音響減衰による2000フィートでの75デシベル200Hzソースのサウンドレベルを決定する：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[200, "Hertz"], Quantity[2000, "Feet"], Quantity[75, IndependentUnit["decibels"]]]

大気条件と距離に基づいて音声を変換する：

Wolfram Language code: audio = Import[File["ExampleData/car.mp3"], "Audio"]
Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[30, "DegreesCelsius"], "RelativeHumidity" -> Quantity[60, "Percent"]|>, audio, Quantity[500, "Meters"]]

スコープ  (5)

距離と周波数を使って音の減衰因子を計算する：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[23, "DegreesCelsius"], "WetBulbTemperature" -> Quantity[20, "DegreesCelsius"], "Pressure" -> Quantity[1050, "Millibars"]|>, Quantity[2500, "Hertz"], Quantity[0.5, "Miles"]]

減衰されたサウンドレベルをオクターブで計算する：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[200, "Hertz"], Quantity[2000, "Feet"], Quantity[50, IndependentUnit["octaves"]]]

減衰係数を周波数の関数として可視化する：

Wolfram Language code: ListPlot[Table[{f, AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[f, "Hertz"], UnitSystem -> "Metric"]}, {f, 100, 20000, 500}], AxesLabel -> {Quantity[None, "Hertz"], Quantity[None, IndependentUnit["decibels"] / "Meters"]}]

音の減衰係数が温度によってどのように変化するかを調べる：

Wolfram Language code: ListPlot[Table[{c, AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[c, "DegreesCelsius"], "RelativeHumidity" -> Quantity[60, "Percent"]|>, Quantity[500, "Hertz"], UnitSystem -> "Metric"]}, {c, 18, 40, 2}], AxesLabel -> {Quantity[None, "DegreesCelsius"], Quantity[None, IndependentUnit["decibels"] / "Meters"]}]

相対湿度の上昇にともなう音の減衰係数の動作を比較する：

Wolfram Language code: ListPlot[Table[{c, AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[40, "DegreesCelsius"], "RelativeHumidity" -> Quantity[c, "Percent"]|>, Quantity[500, "Hertz"], UnitSystem -> "Metric"]}, {c, 20, 100, 5}], AxesLabel -> {Quantity[None, "Percent"], Quantity[None, IndependentUnit["decibels"] / "Meters"]}]

デシベルが距離とともにどのように減少するかを調べる：

Wolfram Language code: ListPlot[Table[{Quantity[d, "Feet"], AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[2500, "Hertz"], Quantity[d, "Feet"], Quantity[75, IndependentUnit["decibels"]]]}, {d, 100, 2500, 100}], AxesLabel -> Automatic]

オプション  (4)

Method  (2)

2000フィートでの75デシベル200Hzソースの音の分散を考慮する：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[200, "Hertz"], Quantity[2000, "Feet"], Quantity[75, IndependentUnit["decibels"]], Method -> {"IncludeDispersion", "ReferenceDistance" -> Quantity[1, "Feet"]}]

音声に分散を適用する：

Wolfram Language code: audio = Import[File["ExampleData/car.mp3"], "Audio"]
Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[30, "DegreesCelsius"], "RelativeHumidity" -> Quantity[60, "Percent"]|>, audio, Quantity[500, "Meters"], Method -> {"IncludeDispersion", "ReferenceDistance" -> Quantity[3, "Meters"]}]

分散なしのサウンドレベルと比較する：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[30, "DegreesCelsius"], "RelativeHumidity" -> Quantity[60, "Percent"]|>, audio, Quantity[500, "Meters"]]

UnitSystem  (2)

デフォルトで，結果は"Metric"単位になる：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "RelativeHumidity" -> Quantity[40, "Percent"]|>, Quantity[3300, "Hertz"], UnitSystem -> "Metric"]

UnitSystemを"Imperial"に設定して結果がフィートあたりのデシベルになるようにする：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "RelativeHumidity" -> Quantity[40, "Percent"]|>, Quantity[3300, "Hertz"], UnitSystem -> "Imperial"]

UnitConvertは単位調整にも使うことができる：

Wolfram Language code: UnitConvert[N@AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "RelativeHumidity" -> Quantity[40, "Percent"]|>, Quantity[3300, "Hertz"], UnitSystem -> "Metric"], IndependentUnit["decibels"] / "Feet"]

考えられる問題  (3)

乾球温度は湿球点温度以上でなければならない：

Wolfram Language code: AirSoundAttenuation[<|"WetBulbTemperature" -> Quantity[305, "Kelvins"], "DryBulbTemperature" -> Quantity[300, "Kelvins"]|>, Quantity[1000, "Hertz"]]

乾球温度は露点温度以上でなければならない：

Wolfram Language code: AirSoundAttenuation[<|"DewPointTemperature" -> Quantity[300, "Kelvins"], "DryBulbTemperature" -> Quantity[295, "Kelvins"]|>, Quantity[1000, "Hertz"]]

計算には乾球温度が必要である：

Wolfram Language code: AirSoundAttenuation[<|"DewPointTemperature" -> Quantity[295, "Kelvins"]|>, Quantity[1000, "Hertz"]]

周波数は50Hzから20kHzまででなければならない：

Wolfram Language code: AirSoundAttenuation[<|"DryBulbTemperature" -> Quantity[20, "DegreesCelsius"], "DewPointTemperature" -> Quantity[18, "DegreesCelsius"]|>, Quantity[50, "Kilohertz"]]
Wolfram Research (2020), AirSoundAttenuation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AirSoundAttenuation.html.

テキスト

Wolfram Research (2020), AirSoundAttenuation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AirSoundAttenuation.html.

CMS

Wolfram Language. 2020. "AirSoundAttenuation." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AirSoundAttenuation.html.

APA

Wolfram Language. (2020). AirSoundAttenuation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AirSoundAttenuation.html

BibTeX

@misc{reference.wolfram_2026_airsoundattenuation, author="Wolfram Research", title="{AirSoundAttenuation}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/AirSoundAttenuation.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_airsoundattenuation, organization={Wolfram Research}, title={AirSoundAttenuation}, year={2020}, url={https://reference.wolfram.com/language/ref/AirSoundAttenuation.html}, note=[Accessed: 18-August-2026]}