WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArrayQ[expr]

expr が完全配列のときはTrueを，それ以外のときはFalseを与える．

ArrayQ[expr,patt]

expr がパターン patt と一致する深さを持つ完全配列であることを要求する．

ArrayQ[expr,patt,test]

test を expr の各配列要素に適用した際にTrueが返されることを要求する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ArrayQ

ArrayQ[expr]

expr が完全配列のときはTrueを，それ以外のときはFalseを与える．

ArrayQ[expr,patt]

expr がパターン patt と一致する深さを持つ完全配列であることを要求する．

ArrayQ[expr,patt,test]

test を expr の各配列要素に適用した際にTrueが返されることを要求する．

詳細

  • 完全配列では，特定のレベルにあるすべての要素は同じ長さのリストでなければならないが、異なる要素は異なるリスト表現を使用しても構わない．
  • 完全配列は，矩形配列としても知られている．
  • 以下は，使用可能な配列の表現である． »
  • {…}またはList[…], {{…},{…},…}等通常の（ネストしている可能性がある）リスト
    SparseArray[…]疎な配列
    TabularColumn[…], PermutationMatrix[…], QuantityArray[…], SymmetrizedArray[…]等構造化配列
    {a1,a2,…}，ただしArrayQ[ai]はTrue通常の配列，疎な配列，および／または構造化配列のリスト »
  • ArrayQ[expr,1|2]は expr がベクトルであるか行列であるかを調べる． »
  • 空リスト{}は長さが0のベクトルである． »
  • 数値配列で使用するArrayQ[expr,patt,test]の test の一般的な値には以下がある．
  • NumberQexpr が明示的な数の配列かどうかテストする
    NumericQexpr が数式の配列かどうかテストする
    Positiveexpr が正の数の配列かどうかテストする
    RealValuedNumberQexpr が頭部がInteger，RationalあるいはRealの数の配列かどうかテストする
    RealValuedNumericQexpr が実数の数式の配列かどうかテストする
  • よく使われる構造化テストには以下がある．
  • IntegerQexpr が整数配列かどうかテストする
    PolynomialQ[#,x]&expr が x の多項式かどうかテストする
    QuantityQexpr が数量の配列かどうかテストする
    StringQexpr が文字列の配列かどうかテストする

例題

すべて開く すべて閉じる

例  (2)

数のベクトルは完全配列である：

Wolfram Language code: ArrayQ[{1, 2, 3, 4}]

1つの要素がそれ自体でリストであるベクトルは完全配列ではない：

Wolfram Language code: ArrayQ[{1, 2, {3}, 4}]

ネストしたリストの不規則な集合は完全配列ではない：

Wolfram Language code: ArrayQ[{{1, 2}, {3}}]
Wolfram Language code: ArrayQ[{{1, 2}, {3, 4}}]

スコープ  (11)

異なるさまざまな頭部で配列を表すことができる：

Wolfram Language code: ArrayQ[SparseArray[{{1, 3} -> a, {5, 1} -> b}]]
Wolfram Language code: ArrayQ[TabularColumn[{1, 2, 3}, "Integer8"]]
Wolfram Language code: ArrayQ[SymmetrizedArray[{1, 2, 3} -> 1, {3, 3, 3}, Antisymmetric[All]]]

ベクトルについて調べる：

Wolfram Language code: ArrayQ[{1, 2, 3, 4}, 1]
Wolfram Language code: ArrayQ[{{1, 2}, {3, 4}}, 1]

行列について調べる：

Wolfram Language code: ArrayQ[{1, 2, 3, 4}, 2]
Wolfram Language code: ArrayQ[{{1, 2}, {3, 4}}, 2]

ベクトルあるいは行列について調べる：

Wolfram Language code: ArrayQ[{1, 2, 3, 4}, 1 | 2]
Wolfram Language code: ArrayQ[{{1, 2}, {3, 4}}, 1 | 2]

配列はリストの異なる表現である要素を持つことができる：

Wolfram Language code: mat = {{1, 2, 3}, SparseArray[Automatic, {3}, 0, {1, {{0, 1}, {{3}}}, {a}}], TabularColumn[{4, 5, 6}, "Integer64"]}; ArrayQ[mat]

次の配列は行列である：

Wolfram Language code: ArrayQ[mat, 2]

より深い配列ではより多くの組合せが可能である：

Wolfram Language code: arr = {mat, SymmetrizedArray[{{1, 2} -> b, {3, 3} -> d}, {3, 3}, Symmetric[{1, 2}]]}

次の配列の深さは3である：

Wolfram Language code: ArrayQ[arr, 3]

配列の内容を見る：

Wolfram Language code: arr//MatrixForm

数値ベクトルについて調べる：

Wolfram Language code: ArrayQ[{1, 2, 3, x}, 1, NumericQ]

数値項を持った任意の深さの配列について調べる：

Wolfram Language code: ArrayQ[{{{E, 1}, {Pi, 2}}, {{Sin[1], Cos[2]}, {Sinh[1], Cosh[1]}}}, _, NumericQ]

代りに明示的な数である項目について調べる：

Wolfram Language code: ArrayQ[{{{E, 1}, {Pi, 2}}, {{Sin[1], Cos[2]}, {Sinh[1], Cosh[1]}}}, _, NumberQ]

実数値の数量のベクトルについて調べる：

Wolfram Language code: ArrayQ[{1, Pi, Sin[1], Sqrt[2]}, 1, RealValuedNumericQ]

明示的な実数値に対するより高速なテスト：

Wolfram Language code: ArrayQ[{1, Pi, Sin[1], 3 / 4}, 1, RealValuedNumberQ]

小数第2位に丸めたときに整数となる数を含む，奇数の深さを持つ配列ついて調べる：

Wolfram Language code: ArrayQ[{1, 1.005, 1.997}, _ ? OddQ, Abs[# - Round[#]] < 0.005&]

文字列行列について調べる：

Wolfram Language code: ArrayQ[{{"a", "b"}, {"c", "d"}}, 2, StringQ]
Wolfram Language code: ArrayQ[{{"a", "b"}, {c, d}}, 2, StringQ]

ベクトルまたはxの多項式の行列について調べる：

Wolfram Language code: ArrayQ[{1, x, 1 + x, x ^ 2 + 2x + 1}, 1 | 2, PolynomialQ[#, x]&]
Wolfram Language code: ArrayQ[{1, x, Sin[x], Exp[x]}, 1 | 2, PolynomialQ[#, x]&]

アプリケーション  (1)

配列についてのみ評価される関数を定義する：

Wolfram Language code: iptp[a_ ? ArrayQ, x_] := Module[{n, at = a}, n = ArrayDepth[a]; Do[ at = Transpose[at, RotateRight[Range[ArrayDepth[at]]]]; at = Map[InterpolatingPolynomial[#, Subscript[x, i]]&, at, {n - i}], {i, n}]; at]

次は，整数座標を仮定して多項式を補間するテンソル積を構築する：

Wolfram Language code: data = {{{1, 2, 3, 4}, {5, 6, 7, 8}, {9, 10, 11, 12}}, {{13, 14, 15, 16}, {17, 18, 19, 20}, {21, 22, 23, 24}}}; poly = iptp[data, x]

この多項式はデータを補間する：

Wolfram Language code: pos = Position[data, _ ? NumberQ]; poly /. Map[Thread[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]} -> #]&, pos]
Wolfram Language code: % === Extract[data, pos]

特性と関係  (5)

空リストは長さが0のベクトルであると考えられる：

Wolfram Language code: ArrayQ[{}, 1]

VectorQ[expr]はArrayQ[expr,1]に等しい：

Wolfram Language code: v = {1, 2., E, Pi + I};
Wolfram Language code: {VectorQ[v], ArrayQ[v, 1]}

VectorQ[expr,test]はArrayQ[expr,1,test]に等しい：

Wolfram Language code: {VectorQ[v, NumericQ], ArrayQ[v, 1, NumericQ]}
Wolfram Language code: {VectorQ[v, Im[#] == 0&], ArrayQ[v, 1, Im[#] == 0&]}

MatrixQ[expr]はArrayQ[expr,2]に等しい：

Wolfram Language code: m = RandomReal[1, {2, 2}]
Wolfram Language code: {ArrayQ[m, 2], MatrixQ[m]}

MatrixQ[expr]はArrayQ[expr,2]に等しい：

Wolfram Language code: {ArrayQ[m, 2, MachineNumberQ], MatrixQ[m, MachineNumberQ]}
Wolfram Language code: {ArrayQ[m, 2, IntegerQ], MatrixQ[m, IntegerQ]}

深さ3の配列 arr について，VectorQ[arr,MatrixQ]とMatrixQ[arr,VectorQ]はTrueを返す：

Wolfram Language code: arr = Array[a, {2, 3, 4}]; {ArrayQ[arr, 3], VectorQ[arr, MatrixQ], MatrixQ[arr, VectorQ]}

この命題の逆はFalseである：

Wolfram Language code: narr = {Array[a, {3, 4}], Array[a, {3, 5}]}; {ArrayQ[narr, 4], VectorQ[narr, MatrixQ], MatrixQ[narr, VectorQ]}

ArrayQは，事実上，AllowedHeads"ListLike"を使う：

Wolfram Language code: mat = {SparseArray[{1, 2}], QuantityArray[{1, 2}, "Meters"]}; expr = f[f[1, 2], f[3, 4]];
Wolfram Language code: {ArrayQ[mat], ArrayQ[expr]}
Wolfram Language code: {ArrayDepth[mat, AllowedHeads -> "ListLike"], ArrayDepth[expr, AllowedHeads -> "ListLike"]}
Wolfram Language code: {Dimensions[mat, AllowedHeads -> "ListLike"], Dimensions[expr, AllowedHeads -> "ListLike"]}
Wolfram Research (2003), ArrayQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayQ.html （2012年に更新）.

テキスト

Wolfram Research (2003), ArrayQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArrayQ.html （2012年に更新）.

CMS

Wolfram Language. 2003. "ArrayQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/ArrayQ.html.

APA

Wolfram Language. (2003). ArrayQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArrayQ.html

BibTeX

@misc{reference.wolfram_2026_arrayq, author="Wolfram Research", title="{ArrayQ}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ArrayQ.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrayq, organization={Wolfram Research}, title={ArrayQ}, year={2012}, url={https://reference.wolfram.com/language/ref/ArrayQ.html}, note=[Accessed: 16-August-2026]}