WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Arrowheads[spec]

続く矢印が spec で指定された大きさ，位置，形の鏃（やじり）を持つように指定するグラフィックス指示子である．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
矢印の大きさ  
複数の鏃  
カスタム鏃  
アプリケーション  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Arrowheads

Arrowheads[spec]

続く矢印が spec で指定された大きさ，位置，形の鏃（やじり）を持つように指定するグラフィックス指示子である．

詳細とオプション

  • デフォルトのArrowheads[Automatic]では，矢印の先端に単一の鏃が置かれる．
  • Arrowheads[s]では，長さがグラフィックスの全体幅に対する割合 s である鏃が使用される．デフォルト値は0.04である． »
  • s には，Tiny，Small，Medium，Largeの記号形式を使うことができる．これらの値では，鏃の大きさはグラフィックスの全体幅に依存しない． »
  • Arrowheads[{spec1,spec2,…}]は，矢印が数種類の鏃要素を含むように指定する．
  • 各鏃要素は次のように指定することができる．
  • sスケールされた大きさ s のデフォルトの鏃
    {Automatic,pos}位置 pos におけるデフォルトの鏃
    {s,pos}位置 pos におけるスケールされたデフォルトの鏃
    {s,pos,g}グラフィックス g として描かれた鏃
    {s,pos,{g,δ}}δ で短く表示された矢柄
  • 位置 pos は矢印の終端0から矢印の先端1までである．
  • Arrowheads[{s0,s1,…,sn}]は，鏃をスケールされた大きさ siで位置 i/n に描くように指定する． »
  • Arrowheads[{-s,s}]は鏃が2つある矢印を与える． »
  • グラフィックス g は，その座標の原点{0,0}が各矢印と並んで位置 pos になるように置かれる．
  • グラフィックス g は，正の 軸が位置 pos で矢柄と同じ方向を向くように置かれる．
  • グラフィックス g は，座標の単位が矢印が描かれるグラフィックスの全体幅に対する割合 s に当たるようにスケールされる．
  • グラフィックス g は，常にAspectRatio->Automaticであると推定される．
  • {s,pos,{g,δ}}と指定すると，矢印の矢柄は g 座標系の中の δ を使って短く表示される．これは，矢印の先端や終端で太い矢柄が鏃を突き抜けるのを防ぐ． »
  • 3Dでは，デフォルトのオプション設定Appearance->"Flat"で鏃は常にスクリーン平面上に描画される．Appearance->"Projected"とすると，鏃は3Dでスクリーン平面に投影されて描画される．

例題

すべて開く すべて閉じる

例  (3)

2Dの矢印：

Wolfram Language code: {Graphics[{Arrowheads[.1], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[.1], Arrow[BezierCurve[{{0, 0}, {1, 1}, {2, 0}}]]}]}

3Dの矢印：

Wolfram Language code: {Graphics3D[{Arrowheads[.1], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[.1], Arrow[BSplineCurve[{{0, 0, 0}, {1, 1, 1}, {2, -1, 1}}]]}]}

管を使った完全な3Dの矢印のプリミティブ：

Wolfram Language code: {Graphics3D[{Arrowheads[.1], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[.1], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {1, 1, 1}, {2, -1, 1}}]]]}]}

スコープ  (16)

矢印の大きさ  (5)

スケールされた大きさの鏃：

Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[{{0, 0}, {2, 1}}]}, PlotLabel -> i], {i, {.1, .2, .4}}]
Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotLabel -> i], {i, {.1, .2, .4}}]

三次元でスケールされた大きさの鏃：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[{{0, 0, 0}, {2, 1, 1}}]}, PlotLabel -> i], {i, {.1, .2, .4}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}, PlotLabel -> i], {i, {.1, .2, .4}}]

三次元で管にスケールされた大きさの鏃：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.02]]}, PlotLabel -> i], {i, {.1, .2, .4}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, .5}, {2, 1, 1}}], 0.02]]}, PlotLabel -> i], {i, {.1, .2, .4}}]

鏃の定義済みの絶対的な大きさを指定する記号値：

Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[{{0, 0}, {2, 1}}]}, PlotRange -> {{0, 2}, {0, 1}}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{0, 2}, {-0.5, 1}}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]

三次元での記号的値：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[{{0, 0, 0}, {2, 1, 1}}]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]

管の鏃：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.02]]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}], 0.02]]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]

複数の鏃  (8)

両端に鏃が付いた矢印：

Wolfram Language code: {Graphics[{Arrowheads[{-.1, .1}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{-.1, .1}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{0, 2}, {-0.5, 1}}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{-.1, .1}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{-.1, .1}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{-.1, .1}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{-.1, .1}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

等間隔に置かれた指定された大きさの鏃：

Wolfram Language code: {Graphics[{Arrowheads[{.05, .1, .1, .05}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{.05, .1, .1, .05}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{-0.1, 2}, {-0.5, 1}}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

鏃の大きさと位置を指定する：

Wolfram Language code: Table[Graphics[{Arrowheads[{{.1, i}}], Arrow[{{0, 0}, {1, 1 / 3}}]}], {i, {0.2, 0.5, 1}}]
Wolfram Language code: Table[Graphics[{Arrowheads[{{.1, i}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{-0.1, 2}, {-0.5, 1}}], {i, {0.2, 0.5, 1}}]

三次元で大きさと位置を指定する：

Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {i, {0.2, 0.5, 1}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}], {i, {0.2, 0.5, 1}}]

管の矢印で：

Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], {i, {0.2, 0.5, 1}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}], {i, {0.2, 0.5, 1}}]

大きさと位置を指定した複数の鏃：

Wolfram Language code: {Graphics[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{-0.1, 2}, {-0.5, 1}}]}

三次元で：

Wolfram Language code: {Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}

管の矢印で：

Wolfram Language code: {Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

負の大きさを割り当てて逆向きにした鏃：

Wolfram Language code: {Graphics[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}]}

三次元で：

Wolfram Language code: {Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}

管の矢印で：

Wolfram Language code: {Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

複数の接続していない矢印：

Wolfram Language code: s = {{0, 0}, {2, 1.5}, {4, 0}};
Wolfram Language code: {Graphics[Arrow[Line[{s, s + 1}]]], Graphics[Arrow[BezierCurve[{s, s + 1}]]]}
Wolfram Language code: s = {{0, 0, 0}, {1, 2, 2}, {4, 2, 2}};
Wolfram Language code: {Graphics3D[Arrow[Line[{s, s + 3}]]], Graphics3D[Arrow[BSplineCurve[{s, s + 3}]]], Graphics3D[Arrow[Tube[BSplineCurve[{s, s + 3}]]]]}

異なる鏃を持つ複数の接続していない矢印：

Wolfram Language code: s = {{0, 0}, {2, 1.5}, {4, 0}};
Wolfram Language code: {Graphics[{Arrowheads[{{0.04}, {0.1}}], Arrow[Line[{s, s + 1}]]}], Graphics[{Arrowheads[{{0.04}, {0.1}}], Arrow[BezierCurve[{s, s + 1}]]}]}
Wolfram Language code: s = {{0, 0, 0}, {1, 2, 2}, {4, 2, 2}};
Wolfram Language code: {Graphics3D[{Arrowheads[{{0.04}, {0.1}}], Arrow[Line[{s, s + 3}]]}], Graphics3D[{Arrowheads[{{0.04}, {0.1}}], Arrow[BSplineCurve[{s, s + 3}]]}], Graphics3D[{Arrowheads[{{0.04}, {0.1}}], Arrow[Tube[BSplineCurve[{s, s + 3}]]]}]}

カスタム鏃  (3)

鏃としてグラフィッスを用いることができる：

Wolfram Language code: h = Graphics[Line[{{{-1, 1 / 2}, {0, 0}, {-1, -1 / 2}}, {{0, 1 / 2}, {1, 0}, {0, -1 / 2}}, {{1, 1 / 2}, {2, 0}, {1, -1 / 2}}}]]
Wolfram Language code: Graphics[{Arrowheads[{{Automatic, Automatic, h}}], Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {0, 1}}], Arrow[{{0, 0}, {1, 0}}]}]

Graphics3Dもまた三次元の矢印の鏃として使うことができる：

Wolfram Language code: h = Graphics3D[Line[{{{-1, 1 / 2, 0}, {0, 0, 0}, {-1, -1 / 2, 0}}, {{0, 1 / 2, 0}, {1, 0, 0}, {0, -1 / 2, 0}}, {{1, 1 / 2, 0}, {2, 0, 0}, {1, -1 / 2, 0}}}]]
Wolfram Language code: Graphics3D[{Arrowheads[{{Automatic, Automatic, h}}], Arrow[{{0, 0, 0}, {1, 0, 0}}], Arrow[{{0, 0, 0}, {0, 1, 0}}], Arrow[{{0, 0, 0}, {0, 0, 1}}]}]

矢柄を短く表示する：

Wolfram Language code: h = Graphics[Line[{{-1, 1 / 2}, {0, 0}, {-1, -1 / 2}, {-1, 1 / 2}}]];
Wolfram Language code: Table[Graphics[{Thick, Arrowheads[{{.5, 1, {h, i}}}], Arrow[{{0, 0}, {2, 1}}]}], {i, {0, .5, 1}}]
Wolfram Language code: Table[Graphics[{Thick, Arrowheads[{{.5, 1, {h, i}}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}], {i, {0, .5, 1}}]

三次元で：

Wolfram Language code: h = Graphics3D[Line[{{-1, 1 / 2, 0}, {0, 0, 0}, {-1, -1 / 2, 0}, {-1, 1 / 2, 0}}]];
Wolfram Language code: Table[Graphics3D[{Thick, Arrowheads[{{.5, 1, {h, i}}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {i, {0, .5, 1}}]

管の矢印で：

Wolfram Language code: Table[Graphics3D[{Thick, Opacity[.5], Arrowheads[{{.1, 1, {Graphics3D[Sphere[]], i}}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}, PlotRange -> {{0, 3}, {0, 2}, {0, 2}}], {i, {0, .5, 1}}]

アプリケーション  (1)

投影した鏃を使ったビルボードツリー：

Wolfram Language code: tree = \!\(\*GraphicsBox[«2»]\);
Wolfram Language code: Graphics3D[{Arrowheads[{{.1, 1, tree}}, Appearance -> "Projected"], Arrow[{{0, 0, 0}, {0, -0, 0.001}}], Green, Cuboid[{-10, -10, -3}, {10, 10, -2.8}]}]

おもしろい例題  (1)

移動する鏃：

Wolfram Language code: Animate[Graphics[{Arrowheads[{{.1, t}, {.1, Mod[t + 1 / 3, 1]}, {.1, Mod[t + 2 / 3, 1]}}], Thick, Arrow[{{0, 0}, {10, 5}}]}, PlotRangePadding -> 1], {t, 0, 1}, AnimationRunning -> False]
Wolfram Research (2007), Arrowheads, Wolfram言語関数， https://reference.wolfram.com/language/ref/Arrowheads.html （2008年に更新）.

テキスト

Wolfram Research (2007), Arrowheads, Wolfram言語関数， https://reference.wolfram.com/language/ref/Arrowheads.html （2008年に更新）.

CMS

Wolfram Language. 2007. "Arrowheads." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/Arrowheads.html.

APA

Wolfram Language. (2007). Arrowheads. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Arrowheads.html

BibTeX

@misc{reference.wolfram_2026_arrowheads, author="Wolfram Research", title="{Arrowheads}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Arrowheads.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrowheads, organization={Wolfram Research}, title={Arrowheads}, year={2008}, url={https://reference.wolfram.com/language/ref/Arrowheads.html}, note=[Accessed: 15-August-2026]}