WOLFRAM

Wolfram 语言与系统参考资料中心

Arrowheads[spec]

是一种图形指令，它指定箭头头部应该具有 spec 所指定的尺寸、位置和形式.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
箭头尺寸  
多个箭头  
自定义箭头  
应用  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Arrowheads

Arrowheads[spec]

是一种图形指令，它指定箭头头部应该具有 spec 所指定的尺寸、位置和形式.

更多信息和选项

  • 缺省设置 Arrowheads[Automatic] 时，每个箭头标记只有一个头部.
  • Arrowheads[s] 指定箭头头部的长度应该是图形总宽度 s 的分数. 缺省值为 0.04. »
  • 符号值 Tiny、Small、Medium 和 Large 可用于 s. 这些值使得箭头尺寸不再取决于图形总宽度. »
  • Arrowheads[{spec1,spec2,…}] 指定箭头标记应该包含几种箭头头部元素.
  • 每个箭头头部元素可以指定如下：
  • s具有尺度缩放的尺寸 s 的缺省箭头头部
    {Automatic,pos}在 pos 位置处的缺省箭头头部
    {s,pos}在 pos 位置处，尺度缩放的缺省箭头头部
    {s,pos,g}以图形 g 绘制箭头头部
    {s,pos,{g,δ}}指定缩短 δ 的箭杆
  • 位置 pos 从 0 直到 1，从箭头标记的尾部到顶端.
  • Arrowheads[{s0,s1,…,sn}] 指定在 i/n 处具有尺度缩放的尺寸 si 的箭头. »
  • Arrowheads[{-s,s}] 给出双箭头的箭头标记. »
  • 放置图形 g，使其坐标原点 {0,0} 位于沿箭头标记的位置 pos 上.
  • 放置图形 g，使 正轴与在 pos 位置的箭杆方向对齐.
  • 标注图形 g，使其坐标的一个单位等于绘箭完整箭头标记宽度的分数 s.
  • 图形 g 通常假定具有 AspectRatio->Automatic.
  • 指定 {s,pos,{g,δ}}，箭杆在坐标系 g 中缩短 δ. 这样可以防止较粗箭杆在箭的头部或尾部“冒出来”. »
  • 在三维中，默认选项设置 Appearance->"Flat" 使箭头头部总是呈现在屏幕平面上， Appearance->"Projected" 使他们呈现为三维，并投射到屏幕平面上.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一个二维箭头：

Wolfram Language code: {Graphics[{Arrowheads[.1], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[.1], Arrow[BezierCurve[{{0, 0}, {1, 1}, {2, 0}}]]}]}

一个三维箭头：

Wolfram Language code: {Graphics3D[{Arrowheads[.1], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[.1], Arrow[BSplineCurve[{{0, 0, 0}, {1, 1, 1}, {2, -1, 1}}]]}]}

一个使用管的全三维箭头基元：

Wolfram Language code: {Graphics3D[{Arrowheads[.1], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[.1], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {1, 1, 1}, {2, -1, 1}}]]]}]}

范围  (16)

箭头尺寸  (5)

具有缩放尺寸的箭头：

Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[{{0, 0}, {2, 1}}]}, PlotLabel -> i], {i, {.1, .2, .4}}]
Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotLabel -> i], {i, {.1, .2, .4}}]

在三维空间中，具有缩放尺寸的箭头：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[{{0, 0, 0}, {2, 1, 1}}]}, PlotLabel -> i], {i, {.1, .2, .4}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}, PlotLabel -> i], {i, {.1, .2, .4}}]

在三维空间中，具有缩放尺寸的管状箭头：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.02]]}, PlotLabel -> i], {i, {.1, .2, .4}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, .5}, {2, 1, 1}}], 0.02]]}, PlotLabel -> i], {i, {.1, .2, .4}}]

符号值指定箭头的预定义绝对尺寸：

Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[{{0, 0}, {2, 1}}]}, PlotRange -> {{0, 2}, {0, 1}}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{Arrowheads[i], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{0, 2}, {-0.5, 1}}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]

三维空间中的符号值：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[{{0, 0, 0}, {2, 1, 1}}]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]

管状箭头：

Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}, 0.02]]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[i], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}], 0.02]]}, PlotLabel -> i], {i, {Tiny, Small, Medium, Large}}]

多个箭头  (8)

双头箭头：

Wolfram Language code: {Graphics[{Arrowheads[{-.1, .1}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{-.1, .1}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{0, 2}, {-0.5, 1}}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{-.1, .1}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{-.1, .1}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{-.1, .1}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{-.1, .1}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

具有指定尺寸的均匀间隔的箭头：

Wolfram Language code: {Graphics[{Arrowheads[{.05, .1, .1, .05}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{.05, .1, .1, .05}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{-0.1, 2}, {-0.5, 1}}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}
Wolfram Language code: {Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{.05, .1, .1, .05}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

指定箭头尺寸和位置：

Wolfram Language code: Table[Graphics[{Arrowheads[{{.1, i}}], Arrow[{{0, 0}, {1, 1 / 3}}]}], {i, {0.2, 0.5, 1}}]
Wolfram Language code: Table[Graphics[{Arrowheads[{{.1, i}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{-0.1, 2}, {-0.5, 1}}], {i, {0.2, 0.5, 1}}]

指定三维空间中的尺寸和位置：

Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {i, {0.2, 0.5, 1}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}], {i, {0.2, 0.5, 1}}]

管状箭头：

Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], {i, {0.2, 0.5, 1}}]
Wolfram Language code: Table[Graphics3D[{Arrowheads[{{.1, i}}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}], {i, {0.2, 0.5, 1}}]

具有指定尺寸和位置的多个箭头：

Wolfram Language code: {Graphics[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}, PlotRange -> {{-0.1, 2}, {-0.5, 1}}]}

三维空间中：

Wolfram Language code: {Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}

管状箭头：

Wolfram Language code: {Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{{.1, 0}, {.2, .5}, {.3, 1}}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

通过赋以负值尺寸，可以将箭头的方向逆转：

Wolfram Language code: {Graphics[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}]}

三维空间中：

Wolfram Language code: {Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}]}

管状箭头：

Wolfram Language code: {Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[Tube[{{0, 0, 0}, {2, 1, 1}}]]}], Graphics3D[{Arrowheads[{{-.1, 0}, {.1, .4}, {-.1, .6}, {.1, 1}}], Arrow[Tube[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]]}]}

多个不连通箭头：

Wolfram Language code: s = {{0, 0}, {2, 1.5}, {4, 0}};
Wolfram Language code: {Graphics[Arrow[Line[{s, s + 1}]]], Graphics[Arrow[BezierCurve[{s, s + 1}]]]}
Wolfram Language code: s = {{0, 0, 0}, {1, 2, 2}, {4, 2, 2}};
Wolfram Language code: {Graphics3D[Arrow[Line[{s, s + 3}]]], Graphics3D[Arrow[BSplineCurve[{s, s + 3}]]], Graphics3D[Arrow[Tube[BSplineCurve[{s, s + 3}]]]]}

具有不同箭头的多个不连通箭号：

Wolfram Language code: s = {{0, 0}, {2, 1.5}, {4, 0}};
Wolfram Language code: {Graphics[{Arrowheads[{{0.04}, {0.1}}], Arrow[Line[{s, s + 1}]]}], Graphics[{Arrowheads[{{0.04}, {0.1}}], Arrow[BezierCurve[{s, s + 1}]]}]}
Wolfram Language code: s = {{0, 0, 0}, {1, 2, 2}, {4, 2, 2}};
Wolfram Language code: {Graphics3D[{Arrowheads[{{0.04}, {0.1}}], Arrow[Line[{s, s + 3}]]}], Graphics3D[{Arrowheads[{{0.04}, {0.1}}], Arrow[BSplineCurve[{s, s + 3}]]}], Graphics3D[{Arrowheads[{{0.04}, {0.1}}], Arrow[Tube[BSplineCurve[{s, s + 3}]]]}]}

自定义箭头  (3)

图形可以作为箭头使用：

Wolfram Language code: h = Graphics[Line[{{{-1, 1 / 2}, {0, 0}, {-1, -1 / 2}}, {{0, 1 / 2}, {1, 0}, {0, -1 / 2}}, {{1, 1 / 2}, {2, 0}, {1, -1 / 2}}}]]
Wolfram Language code: Graphics[{Arrowheads[{{Automatic, Automatic, h}}], Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {0, 1}}], Arrow[{{0, 0}, {1, 0}}]}]

Graphics3D 可用作三维箭号的箭头：

Wolfram Language code: h = Graphics3D[Line[{{{-1, 1 / 2, 0}, {0, 0, 0}, {-1, -1 / 2, 0}}, {{0, 1 / 2, 0}, {1, 0, 0}, {0, -1 / 2, 0}}, {{1, 1 / 2, 0}, {2, 0, 0}, {1, -1 / 2, 0}}}]]
Wolfram Language code: Graphics3D[{Arrowheads[{{Automatic, Automatic, h}}], Arrow[{{0, 0, 0}, {1, 0, 0}}], Arrow[{{0, 0, 0}, {0, 1, 0}}], Arrow[{{0, 0, 0}, {0, 0, 1}}]}]

缩短箭杆：

Wolfram Language code: h = Graphics[Line[{{-1, 1 / 2}, {0, 0}, {-1, -1 / 2}, {-1, 1 / 2}}]];
Wolfram Language code: Table[Graphics[{Thick, Arrowheads[{{.5, 1, {h, i}}}], Arrow[{{0, 0}, {2, 1}}]}], {i, {0, .5, 1}}]
Wolfram Language code: Table[Graphics[{Thick, Arrowheads[{{.5, 1, {h, i}}}], Arrow[BezierCurve[{{0, 0}, {1, -1}, {2, 1}}]]}], {i, {0, .5, 1}}]

三维空间中：

Wolfram Language code: h = Graphics3D[Line[{{-1, 1 / 2, 0}, {0, 0, 0}, {-1, -1 / 2, 0}, {-1, 1 / 2, 0}}]];
Wolfram Language code: Table[Graphics3D[{Thick, Arrowheads[{{.5, 1, {h, i}}}], Arrow[{{0, 0, 0}, {2, 1, 1}}]}], {i, {0, .5, 1}}]

管状箭号：

Wolfram Language code: Table[Graphics3D[{Thick, Opacity[.5], Arrowheads[{{.1, 1, {Graphics3D[Sphere[]], i}}}], Arrow[BSplineCurve[{{0, 0, 0}, {.2, 1, 0.5}, {2, 1, 1}}]]}, PlotRange -> {{0, 3}, {0, 2}, {0, 2}}], {i, {0, .5, 1}}]

应用  (1)

使用投映箭头的告示牌树：

Wolfram Language code: tree = \!\(\*GraphicsBox[«2»]\);
Wolfram Language code: Graphics3D[{Arrowheads[{{.1, 1, tree}}, Appearance -> "Projected"], Arrow[{{0, 0, 0}, {0, -0, 0.001}}], Green, Cuboid[{-10, -10, -3}, {10, 10, -2.8}]}]

巧妙范例  (1)

正在移动的箭头头部：

Wolfram Language code: Animate[Graphics[{Arrowheads[{{.1, t}, {.1, Mod[t + 1 / 3, 1]}, {.1, Mod[t + 2 / 3, 1]}}], Thick, Arrow[{{0, 0}, {10, 5}}]}, PlotRangePadding -> 1], {t, 0, 1}, AnimationRunning -> False]
Wolfram Research (2007)，Arrowheads，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Arrowheads.html （更新于 2008 年）.

文本

Wolfram Research (2007)，Arrowheads，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Arrowheads.html （更新于 2008 年）.

CMS

Wolfram 语言. 2007. "Arrowheads." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/Arrowheads.html.

APA

Wolfram 语言. (2007). Arrowheads. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Arrowheads.html 年

BibTeX

@misc{reference.wolfram_2026_arrowheads, author="Wolfram Research", title="{Arrowheads}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Arrowheads.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arrowheads, organization={Wolfram Research}, title={Arrowheads}, year={2008}, url={https://reference.wolfram.com/language/ref/Arrowheads.html}, note=[Accessed: 12-August-2026]}