WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AstroAngularSeparation[astro1,astro2]

現行の地理位置から観測した天体 astro1と astro2の間の天球上の角距離を与える．

AstroAngularSeparation[astro1,astro2,observer]

指定された観測者が知覚した astro1と astro2の間の角距離を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AstroAngularSeparation

AstroAngularSeparation[astro1,astro2]

現行の地理位置から観測した天体 astro1と astro2の間の天球上の角距離を与える．

AstroAngularSeparation[astro1,astro2,observer]

指定された観測者が知覚した astro1と astro2の間の角距離を与える．

詳細

  • 天体角分離は，角距離，見かけの分離，見かけの距離としても知られている．
  • AstroAngularSeparationは，太陽系内の任意の位置（デフォルトでは現在の地理位置）からの任意の2つのオブジェクト間の天球上の角度，位置または方向を計算する．
  • AstroAngularSeparation[astro1,astro2]は，任意の"frame"についてAstroAngularSeparation[astro1,astro2,{"frame",Now,Here}]に等しい．
  • AstroSeparation[astro1,astro2,…]の astroiは，のような天体Entityオブジェクト，AstroPositionオブジェクト，あるいは"Zenith"のような名前付きの方向でよい．
  • AstroSeparation[astro1,astro2,observer]の引数 observer は任意の基準座標系指定でよい．観測地点が与えられていない場合はHereが想定される．観測日が与えられていない場合はNowが想定される．
  • AstroSeparation[…]はQuantity角を角度単位で返す．

例題

すべて開く すべて閉じる

例  (3)

ユーザ位置から観測した太陽と月の現在の角距離を計算する：

Wolfram Language code: AstroAngularSeparation[Entity["Star", "Sun"], Entity["PlanetaryMoon", "Moon"]]

ユーザ位置の対蹠点から観測されたその角度分離を計算する：

Wolfram Language code: AstroAngularSeparation[Entity["Star", "Sun"], Entity["PlanetaryMoon", "Moon"], GeoAntipode[Here]]

2000年から2040年までの木星と土星の角度分離をプロットする：

Wolfram Language code: Plot[AstroAngularSeparation[Entity["Planet", "Jupiter"], Entity["Planet", "Saturn"], DateObject[{year}, CalendarType -> "GregorianYear"]], {year, 2000, 2040}]

冥王星から観測した地球と太陽の角度分離をプロットする：

Wolfram Language code: Plot[AstroAngularSeparation[Entity["Planet", "Earth"], Entity["Star", "Sun"], {"ICRS", Now + Quantity[day, "Days"], Entity["MinorPlanet", "Pluto"]}], {day, -365, 365}]

スコープ  (3)

2つのローカルな名前が付いた方向の間の角度分離を計算する：

Wolfram Language code: AstroAngularSeparation["Zenith", "North"]
Wolfram Language code: AstroAngularSeparation["Zenith", "NorthCelestialPole"]

真の分点方向とローカルな北方向との現行角度を求める：

Wolfram Language code: AstroAngularSeparation["TrueEquinox", "North"]

その数日間の変化をプロットする：

Wolfram Language code: Plot[AstroAngularSeparation["TrueEquinox", "North", Now + Quantity[day, "Days"]], {day, -2, 2}]

AstroAngularSeparationはその最初の2つの引数についてリスト可能である：

Wolfram Language code: planets = PlanetData[]
Wolfram Language code: AstroAngularSeparation[Entity["Star", "Sun"], planets]//Normal[#, QuantityArray]&
Wolfram Language code: AstroAngularSeparation[planets, planets, DateObject[{2023, 1, 1, 0, 0, 0}, TimeZone -> 0]]//MatrixForm

アプリケーション  (2)

章動効果を秒角で可視化する：

Wolfram Language code: Plot[AstroAngularSeparation["TrueEquinox", "MeanEquinox", {"ICRS", Now + Quantity[day, "Days"], Here}], {day, -365, 365}, PlotRange -> All, TargetUnits -> "Arcseconds"]

重力による光の屈折についてのエディントン(Eddington)の観測は，ほぼ以下の日付に以下の場所で行われた：

Wolfram Language code: date = SolarEclipse[DateObject[{1919}]]
Wolfram Language code: location = GeoPosition[Entity["Island", "PrincipeIsland"]]

食の際に太陽の位置を中心として何が起こっているのかを可視化する：

Wolfram Language code: Manipulate[ AstroGraphics[Entity["Star", "Sun"], AstroReferenceFrame -> {"Equatorial", date + Quantity[t, "Hours"], location}, AstroRange -> Quantity[1, "AngularDegrees"], ImageSize -> Medium], {t, 0, 7}, ...]

これは，HR1403としても知られるHIP20842星のおうし座における観測位置を与えるが，それはその日に太陽があった星座である：

Wolfram Language code: ap[t_] := AstroPosition[Entity["Star", "HIP20842"], {"Equatorial", date + t, location}]

光の偏向がなければ，これがその位置であったであろう：

Wolfram Language code: nodefl[t_] := AstroPosition[Entity["Star", "HIP20842"], {"Equatorial", date + t, location, "LightDeflection" -> False}]

修正された観測の座標系を使って重力偏向の修正前と修正後の位置間の角距離を秒角で計算する：

Wolfram Language code: sep[t_] := UnitConvert[With[{p = ap[t]}, AstroAngularSeparation[p, ReplacePart[p, 1 -> nodefl[t]["Data"]]]], "Arcseconds"]
Wolfram Language code: Plot[sep[Quantity[t, "Hours"]], {t, 0, 18}]

これはエディントンが計測したものとほぼ一致する：

Wolfram Language code: sep[Quantity[1.1, "Hours"]]

以下が，太陽円盤の端をかすめる星の偏向の値である：

Wolfram Language code: sep[Quantity[6.5, "Hours"]]

特性と関係  (2)

任意の2つの基本方位間の角度は固定されている：

Wolfram Language code: dirs = {"North", "South", "East", "West", "Zenith", "Nadir"};
Wolfram Language code: Outer[AstroAngularSeparation, dirs, dirs]//MatrixForm

天文中間原点(CIO, celestial intermediate origin)と真の分点の角距離は原点の方程式と呼ばれる：

Wolfram Language code: AstroAngularSeparation["CIO", "TrueEquinox", {"TETE", Now, Entity["Planet", "Earth"]}]
Wolfram Language code: % - Abs@GeoOrientationData[Now, "EquationOfOrigins"]
Wolfram Research (2022), AstroAngularSeparation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AstroAngularSeparation.html.

テキスト

Wolfram Research (2022), AstroAngularSeparation, Wolfram言語関数， https://reference.wolfram.com/language/ref/AstroAngularSeparation.html.

CMS

Wolfram Language. 2022. "AstroAngularSeparation." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AstroAngularSeparation.html.

APA

Wolfram Language. (2022). AstroAngularSeparation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AstroAngularSeparation.html

BibTeX

@misc{reference.wolfram_2026_astroangularseparation, author="Wolfram Research", title="{AstroAngularSeparation}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AstroAngularSeparation.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_astroangularseparation, organization={Wolfram Research}, title={AstroAngularSeparation}, year={2022}, url={https://reference.wolfram.com/language/ref/AstroAngularSeparation.html}, note=[Accessed: 15-August-2026]}