WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AstroStyling["skystyle"]

AstroGraphics図に空を描画する際のスタイルを指定する．

AstroStyling[{"skystyle","param1"val1,"param2"val2,…}]

"parami"valiで与えられる"skystyle"のデフォルトパラメータの値を変更する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
天体のラベル用スタイル  
星のスタイル  
太陽系外天体のスタイル  
星座のスタイル  
参照平面のスタイル  
オブジェクトを抑制するために使用されるスタイルパラメータ  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AstroStyling

AstroStyling["skystyle"]

AstroGraphics図に空を描画する際のスタイルを指定する．

AstroStyling[{"skystyle","param1"val1,"param2"val2,…}]

"parami"valiで与えられる"skystyle"のデフォルトパラメータの値を変更する．

詳細

  • AstroStyling[…]指定はAstroGraphicsのAstroBackgroundオプションの値として使用される．
  • "skystyle"の可能な形には以下がある．
  • Automaticデフォルトのスタイル付けを使用する
    None明示的なスタイル付けは使用しない
    "BlackSky"星，惑星，その他の天体を黒い背景上に表示する
    "GalacticSky"天の川の画像の上に天体を表示する
    "WhiteSky"白い背景の上に天体を表示する
  • 星は視等級による大きさと温度を表す色を持つ点として表示される．パラメータ"StarLabelStyle"はラベルのスタイルを指定する．
  • 銀河は方向がある楕円として表示される．楕円のスタイルはパラメータ"GalaxyStyle"によって与えられる．パラメータ"GalaxyLabelStyle"はラベルのスタイルを指定する．
  • 散開星団はドットがある円として表示される．スタイルはパラメータ"OpenClusterStyle"によって与えられる．パラメータ"OpenClusterLabelStyle"はラベルのスタイルを指定する．
  • 球状星団は中に十字がある円として表示される．スタイルはパラメータ"GlobularClusterStyle"によって与えられる．パラメータ"GlobularClusterLabelStyle"はラベルのスタイルを指定する．
  • 散光星雲は正方形として表示される．スタイルはパラメータ"DiffuseNebulaStyle"で与えられる．パラメータ"DiffuseNebulaLabelStyle"はラベルのスタイルを指定する．
  • 惑星状星雲は外側に十字がある円として表示される．スタイルはパラメータ"PlanetaryNebulaStyle"によって与えられる．パラメータ"PlanetaryNebulaLabelStyle"はラベルのスタイルを指定する．
  • 次は，星座の表示が変更できるパラメータである．
  • "ShowConstellationBoundaries"True星座の境界線を表示するかどうか
    "ShowConstellationIllustrations"False星座を芸術的に描画するかどうか
    "ShowConstellationLines"True星座の棒線を表示するかどうか
    "ShowConstellationNames"True星座の名前を表示するかどうか
    "ShowConstellations"Automatic星座を表示するかどうか，表示するならどの星座か
  • 次は，星座のさまざまな部分のスタイル付けを制御するパラメータである．
  • "ConstellationBoundaryStyle"境界線のスタイル
    "ConstellationIllustrationStyle"イラスト多角形のスタイル
    "ConstellationLineStyle"星座の棒線のスタイル
    "ConstellationNameStyle"星座のテキスト名のスタイル
    "ConstellationRegionStyle"星座の背景多角形のスタイル
  • 各種の参照平面のスタイリングを制御するパラメータには以下が含まれる．
  • "EclipticStyle"黄道面のスタイル
    "EquatorStyle"赤道面のスタイル
    "GalacticStyle"銀河面のスタイル
    "HorizonStyle"地平面のスタイル
    "ShowMainPlanes"主参照面を表示するかどうか
  • 星のスタイリングを制御するパラメータには以下が含まれる．
  • "ShowStarTooltips"星のツールチップを表示するかどうか
    "StarLabelStyle"星ラベルのスタイル
  • 追加のスタイリングパラメータには以下が含まれる．
  • "HideObjects"非表示にする実体
    "ShowExtrasolarObjects"恒星，星団，星雲および銀河を表示するかどうか
    "ShowSolarSystemObjects"太陽系の実体を表示するかどうか

例題

すべて開く すべて閉じる

例  (3)

デフォルトのパラメータで星座イラストの表示をアクティブにする：

Wolfram Language code: AstroGraphics[Entity["Constellation", "UrsaMajor"], AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationIllustrations" -> True}]]

赤道面がマゼンタ色で表示された空を表示する：

Wolfram Language code: AstroGraphics[AstroBackground -> AstroStyling[{"BlackSky", "EquatorStyle" -> StandardMagenta}]]

銀河の描画に使用されるスタイルを変更する：

Wolfram Language code: AstroGraphics[Entity["Galaxy", "M51"], AstroRange -> Quantity[.5, "AngularDegrees"], AstroBackground -> AstroStyling[{"DarkSky", "GalaxyStyle" -> Directive[AbsoluteDashing[{2, 2}], Thickness[.005], StandardYellow]}]]

スコープ  (33)

天体のラベル用スタイル  (6)

ラベルの色を指定する：

Wolfram Language code: AstroGraphics[Entity["Star", "Rigel"], AstroReferenceFrame -> {"Ecliptic", DateObject[{2025, 3, 6, 10, 0, 0}]}, AstroBackground -> AstroStyling[{"DarkSky", "StarLabelStyle" -> StandardPink}]]

銀河名がマゼンタで表示された空を表示する：

Wolfram Language code: AstroGraphics[{Entity["Galaxy", "M87"]}, AstroRange -> Quantity[2, "AngularDegrees"], AstroReferenceFrame -> "ICRS", AstroBackground -> AstroStyling[{"BlackSky", "GalaxyLabelStyle" -> StandardMagenta}]]

散開星団の名称をマゼンタ色で表示して空を描画する：

Wolfram Language code: AstroGraphics[{Entity["Constellation", "Cygnus"]}, AstroReferenceFrame -> "ICRS", AstroBackground -> AstroStyling[{"BlackSky", "OpenClusterLabelStyle" -> StandardMagenta}]]

球状星団の名称をマゼンタで表示して空を示す：

Wolfram Language code: AstroGraphics[{Entity["Constellation", "Sagittarius"]}, AstroRange -> Quantity[15, "AngularDegrees"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "GlobularClusterLabelStyle" -> StandardMagenta}]]

拡散星雲の名称をマゼンタ色で示して星空を表示する：

Wolfram Language code: AstroGraphics[{Entity["Constellation", "Scorpius"]}, AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "DiffuseNebulaLabelStyle" -> StandardMagenta}]]

惑星状星雲の名称をマゼンタで表示して空を表示する：

Wolfram Language code: AstroGraphics[{Entity["Constellation", "Scorpius"]}, AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "PlanetaryNebulaLabelStyle" -> StandardMagenta}]]

星のスタイル  (3)

星の上にカーソルを合わせた際にツールチップを用いて天球を表示する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> {"Equatorial", Here}, AstroBackground -> AstroStyling[{"BlackSky", "ShowStarTooltips" -> True}]]

恒星名がマゼンタ色で示して空を表示する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> {"Equatorial", Here}, AstroBackground -> AstroStyling[{"BlackSky", "StarLabelStyle" -> StandardMagenta}]]

等級が1より低い恒星のみを表示する：

Wolfram Language code: AstroGraphics[AstroBackground -> AstroStyling[{"BlackSky", "ShowStarMaxMagnitude" -> 1}]]

暗い空における肉眼での可視限界に相当する，等級6.5より明るい恒星を表示する：

Wolfram Language code: AstroGraphics[AstroBackground -> AstroStyling[{"BlackSky", "ShowStarMaxMagnitude" -> 6.5}]]

太陽系外天体のスタイル  (5)

銀河のスタイルを指定する：

Wolfram Language code: AstroGraphics[Entity["Galaxy", "M31"], AstroRange -> Quantity[2, "AngularDegrees"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"DarkSky", "GalaxyStyle" -> Directive[AbsoluteDashing[{2, 2}], Thickness[.005], StandardYellow]}]]

散開星団のスタイルを指定する：

Wolfram Language code: AstroGraphics[Entity["Star", "EtaPersei"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"DarkSky", "OpenClusterStyle" -> StandardBlue}]]

球状星団のスタイルを指定する：

Wolfram Language code: AstroGraphics[Entity["StarCluster", "M13"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"DarkSky", "GlobularClusterStyle" -> StandardOrange}]]

散光星雲に対するスタイルを指定する：

Wolfram Language code: AstroGraphics[Entity["Nebula", "M42"], AstroRange -> Quantity[10, "AngularDegrees"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"DarkSky", "DiffuseNebulaStyle" -> StandardMagenta}]]

惑星状星雲のスタイルを指定する：

Wolfram Language code: AstroGraphics[Entity["Nebula", "M57"], AstroRange -> Quantity[.15, "AngularDegrees"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"DarkSky", "PlanetaryNebulaStyle" -> Directive[Dashed, Thick, StandardBlue]}]]

星座のスタイル  (11)

すべての星座線および境界線を表示する：

Wolfram Language code: AstroGraphics[AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellations" -> True}]]

特定の星座線および境界線を有効にする：

Wolfram Language code: AstroGraphics[AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellations" -> {Entity["Constellation", "UrsaMajor"], Entity["Constellation", "UrsaMinor"]}}]]

星座図の表示をデフォルトのパラメータで有効にする：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationIllustrations" -> True}]]

星座の境界線を非表示にする：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationBoundaries" -> False}]]

星座の棒線をオフにする：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationLines" -> False}]]

星座名を非表示にする：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationNames" -> False}]]

星座境界線のスタイルを変更する：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ConstellationBoundaryStyle" -> StandardRed}]]

星座のイラストのスタイルを変更する：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationIllustrations" -> True, "ConstellationIllustrationStyle" -> Directive[StandardRed, Opacity[.25]]}]]

星座の棒線に対して異なるスタイルを使用する：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ConstellationLineStyle" -> StandardBlue}]]

デフォルトで，星座は天文ズームレベル2.5以上で地図上に表示される：

Wolfram Language code: AstroGraphics[]
Wolfram Language code: Options[%, AstroZoomLevel]

星座が表示される最小ズームレベルを減少させる：

Wolfram Language code: AstroGraphics[AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationMinZoom" -> 1}]]

星座名に異なるスタイルを使用する：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ConstellationNameStyle" -> StandardRed}]]

星座領域には異なるスタイルを用いる：

Wolfram Language code: AstroGraphics[Entity["Constellation", "Lepus"], AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowConstellationRegions" -> True, "ShowConstellations" -> {Entity["Constellation", "Lepus"]}, "ConstellationRegionStyle" -> Yellow}]]

参照平面のスタイル  (5)

参照面を一切表示せずに天空を表示する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowMainPlanes" -> False}]]

赤道面がマゼンタ色でにして天空を表示する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> {"Equatorial", Here}, AstroBackground -> AstroStyling[{"BlackSky", "EquatorStyle" -> StandardMagenta}]]

黄道面をマゼンタ色で表示して空を可視化する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> {"Equatorial", Here}, AstroBackground -> AstroStyling[{"BlackSky", "EclipticStyle" -> StandardMagenta}]]

銀河面をマゼンタ色で表示して天空を表示する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> {"Equatorial", Here}, AstroBackground -> AstroStyling[{"BlackSky", "GalacticStyle" -> StandardMagenta}]]

地平面がマゼンタ色で表示された空を表示する：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> {"Ecliptic", Here}, AstroBackground -> AstroStyling[{"BlackSky", "HorizonStyle" -> Magenta, "ShowSolarSystemObjects" -> False}]]

オブジェクトを抑制するために使用されるスタイルパラメータ  (3)

天文基準座標系の中には，近くの天体が空に非常に大きく見える場合がある：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> "Galactic", AstroBackground -> AstroStyling[{"BlackSky"}]]

"HideObjects"を使って特定のオブジェクトを非表示にする：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> "Galactic", AstroBackground -> AstroStyling[{"BlackSky", "HideObjects" -> {Entity["Star", "Sun"]}}]]

デフォルトで，惑星，太陽および月がすべて含まれる：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky"}]]

"ShowSolarSystemObjects"を使って太陽系の天体を非表示にする：

Wolfram Language code: AstroGraphics[AstroReferenceFrame -> "Equatorial", AstroBackground -> AstroStyling[{"BlackSky", "ShowSolarSystemObjects" -> False}]]

デフォルトで，天体範囲が十分に小さい場合，遠距離天体が含まれる：

Wolfram Language code: AstroGraphics[{Entity["Galaxy", "M87"]}, AstroReferenceFrame -> "Ecliptic", AstroRange -> Quantity[2, "AngularDegrees"]]

"ShowExtrasolarObjects"を使ってそれらが表示されないようにする：

Wolfram Language code: AstroGraphics[{Entity["Galaxy", "M87"]}, AstroReferenceFrame -> "Ecliptic", AstroRange -> Quantity[2, "AngularDegrees"], AstroBackground -> AstroStyling[{"BlackSky", "ShowExtrasolarObjects" -> False}]]

おもしろい例題  (1)

星座用のスタイリング指示子の組合せを指定する：

Wolfram Language code: style = { "ShowConstellationIllustrations" -> True, "ShowConstellationRegions" -> True, "ConstellationRegionStyle" -> Darker[Blue, .2], "ConstellationLineStyle" -> Opacity[0.6, LightBlue], "ShowConstellationBoundaries" -> True, "ConstellationBoundaryStyle" -> Directive[Dashing[{0, Tiny}], Yellow], "ConstellationNameStyle" -> GrayLevel[0.7], "HideObjects" -> Automatic };
Wolfram Language code: AstroGraphics[Entity["Constellation", "Scorpius"], AstroBackground -> AstroStyling[{"GalacticSky", "ShowConstellations" -> {Entity["Constellation", "Scorpius"]}, style}], AstroReferenceFrame -> "J2000"]
Wolfram Research (2022), AstroStyling, Wolfram言語関数， https://reference.wolfram.com/language/ref/AstroStyling.html.

テキスト

Wolfram Research (2022), AstroStyling, Wolfram言語関数， https://reference.wolfram.com/language/ref/AstroStyling.html.

CMS

Wolfram Language. 2022. "AstroStyling." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AstroStyling.html.

APA

Wolfram Language. (2022). AstroStyling. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AstroStyling.html

BibTeX

@misc{reference.wolfram_2026_astrostyling, author="Wolfram Research", title="{AstroStyling}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/AstroStyling.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_astrostyling, organization={Wolfram Research}, title={AstroStyling}, year={2022}, url={https://reference.wolfram.com/language/ref/AstroStyling.html}, note=[Accessed: 08-August-2026]}