WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AudioReplace[audio,{t1,t2}new]

t1から t2までの音声信号を新たな信号 new で置換する．

AudioReplace[audio,{{t11,t12},…}new]

複数の区間を同じ音声 new で置換する．

AudioReplace[audio,{{t11,t12}new1,…}]

複数の区間を置換する．

AudioReplace[audio,{t1,t2}new,fitting]

指定された fitting メソッドを使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
フィッティング  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

AudioReplace

AudioReplace[audio,{t1,t2}new]

t1から t2までの音声信号を新たな信号 new で置換する．

AudioReplace[audio,{{t11,t12},…}new]

複数の区間を同じ音声 new で置換する．

AudioReplace[audio,{{t11,t12}new1,…}]

複数の区間を置換する．

AudioReplace[audio,{t1,t2}new,fitting]

指定された fitting メソッドを使う．

詳細

  • AudioReplaceは，音声信号の一部を新たな信号で置換するために使うことができる．大抵の場合，音声全体の持続時間は変化しない．
  • 時点 t は次のいずれでもよい．
  • t秒単位で与えられた時点
    Quantity[t,"unit"]秒と互換の"unit"で与えられた時点
    Quantity[t,"Samples"]サンプル数として与えられた時点
  • fitting メソッドはどのように new で{t1,t2}区間を置換するかを指定する．次は使用可能な設定である．
  • "Fill"持続時間が t2-t1になるように new に充填や切取りを施す（デフォルト）
    "Insert"t1から t2までの音声を削除し，新たに t1に挿入する
    "Stretch"{t1,t2}を new の時間を引き伸ばしたバージョンで置換する

例題

すべて開く すべて閉じる

例  (1)

.5秒から1秒までの区間を正弦曲線で置換する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);
Wolfram Language code: AudioReplace[a, {.5, 1} -> AudioGenerator["Sin"]]

スコープ  (3)

基本的な用法  (2)

同じ信号で異なる区間を置換する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);
Wolfram Language code: AudioReplace[a, {{.5, 1}, {1.3, 1.6}} -> AudioGenerator["Sin"]]

異なる信号を異なる時点に挿入する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);
Wolfram Language code: AudioReplace[a, {{.5, 1} -> AudioGenerator["Sin"], {1.3, 1.6} -> AudioGenerator["White"]}]

フィッティング  (1)

fitting を使って置換信号の動作を制御する：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}, "Audio"];
Wolfram Language code: Duration[a]
Wolfram Language code: b = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);

デフォルトで，置換音声は指定された長さになるように切り取られたり充填されたりする：

Wolfram Language code: AudioReplace[a, {.5, 1.5} -> b, "Fill"]

入力信号の持続時間は同じままである：

Wolfram Language code: Duration[%]

"Insert"を使って置換音声の切取りや充填を避ける：

Wolfram Language code: AudioReplace[a, {.5, 1.5} -> b, "Insert"]

置換信号の持続時間が置換区間と異なる場合は持続時間が変化する：

Wolfram Language code: Duration[%]

"Stretch"を使って置換信号を希望する持続時間まで引き伸ばす：

Wolfram Language code: AudioReplace[a, {.5, 1.5} -> b, "Stretch"]

入力信号の持続時間は変化しない：

Wolfram Language code: Duration[%]

アプリケーション  (3)

録音の静かな部分を無音で置換する：

Wolfram Language code: a = ExampleData[{"Audio", "NoisyTalk"}, "Audio"]

静かな区間を求める：

Wolfram Language code: int = AudioIntervals[a, #LoudnessEBU < -28&]

選択した区間を無音で置換する：

Wolfram Language code: AudioReplace[a, int -> AudioGenerator["Silence"]]
Wolfram Language code: AudioPlot[%]

録音を新たな音声信号で部分的に置換する：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}, "Audio"]

増幅が非零で基本周波数が指定された範囲にある区間を求める：

Wolfram Language code: int = AudioIntervals[a, #RMSAmplitude > .001 && TrueQ[#FundamentalFrequency > 280]&, PartitionGranularity -> .1]

結果の区間を描画する：

Wolfram Language code: AudioPlot[a, Epilog -> {RGBColor[1, 0, 0, .2], Rectangle[{#[[1]], -1}, {#[[2]], 1}]& /@ int}]

置換する音声を準備する：

Wolfram Language code: b = AudioTrim[ExampleData[{"Audio", "Piano"}, "Audio"], 2];

選択された区間を置換音声で置換する：

Wolfram Language code: AudioReplace[a, int -> b, "Stretch"]
Wolfram Language code: AudioPlot[%]

録音のピッチを部分的に修正する：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}, "Audio"]

指定された範囲内の振幅が非零で基本周波数を持つ区間を求める：

Wolfram Language code: int = AudioIntervals[a, #RMSAmplitude > .001 && TrueQ[#FundamentalFrequency > 280]&, PartitionGranularity -> .1]
Wolfram Language code: AudioLocalMeasurements[a, "FundamentalFrequency"]//ListLinePlot

目標とする周波数を定義する：

Wolfram Language code: targetFrequencies = {286, 271, 256};

ピッチシフトアルゴリズムを定義する：

Wolfram Language code: f[audio_, targetFreq_] := AudioPitchShift[audio, targetFreq / Mean@AudioLocalMeasurements[audio, "FundamentalFrequency", MissingDataMethod -> "Interpolation"]]

置換を計算する：

Wolfram Language code: replacements = Table[int[[i]] -> f[AudioTrim[a, int[[i]]], targetFrequencies[[i]]], {i, Length@int}];

結果を計算する：

Wolfram Language code: AudioReplace[a, replacements]
Wolfram Language code: AudioLocalMeasurements[%, "FundamentalFrequency"]//ListLinePlot
Wolfram Research (2017), AudioReplace, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioReplace.html.

テキスト

Wolfram Research (2017), AudioReplace, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioReplace.html.

CMS

Wolfram Language. 2017. "AudioReplace." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AudioReplace.html.

APA

Wolfram Language. (2017). AudioReplace. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AudioReplace.html

BibTeX

@misc{reference.wolfram_2026_audioreplace, author="Wolfram Research", title="{AudioReplace}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/AudioReplace.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_audioreplace, organization={Wolfram Research}, title={AudioReplace}, year={2017}, url={https://reference.wolfram.com/language/ref/AudioReplace.html}, note=[Accessed: 13-September-2026]}