WOLFRAM

Wolfram 语言与系统参考资料中心

AudioReplace[audio,{t1,t2}new]

用新信号 new 替换 t1 和 t2 之间的音频信号.

AudioReplace[audio,{{t11,t12},…}new]

用同样的音频信号 new 替换多个片段.

AudioReplace[audio,{{t11,t12}new1,…}]

替换多个音频片段.

AudioReplace[audio,{t1,t2}new,fitting]

使用指定的 fitting 方法.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
拟合  
应用  
参见
相关指南
历史
按以下格式引用：

AudioReplace

AudioReplace[audio,{t1,t2}new]

用新信号 new 替换 t1 和 t2 之间的音频信号.

AudioReplace[audio,{{t11,t12},…}new]

用同样的音频信号 new 替换多个片段.

AudioReplace[audio,{{t11,t12}new1,…}]

替换多个音频片段.

AudioReplace[audio,{t1,t2}new,fitting]

使用指定的 fitting 方法.

更多信息

  • AudioReplace 可用新信号替换音频信号的一部分. 通常情况下，整个音频信号的时长不变.
  • 时间 t 可为以下形式：
  • t用秒给出的时间
    Quantity[t,"unit"]用与秒兼容的 "unit" 给出的时间
    Quantity[t,"Samples"]用采样数目给出的时间
  • fitting 方法指定 new 怎样替换 {t1,t2} 片段. 可能的设置为：
  • "Fill"把 new 填充或剪辑成时长为 t2-t1 的信号（缺省）
    "Insert"把 t1 到 t2 之间的片段移除，在 t1 处插入新信号
    "Stretch"对 new 进行时间扩展，然后用它替换 {t1,t2}

范例

打开所有单元 关闭所有单元

基本范例  (1)

把 .5 和 1 秒之间的片段替换成一段正弦波：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);
Wolfram Language code: AudioReplace[a, {.5, 1} -> AudioGenerator["Sin"]]

范围  (3)

基本用途  (2)

用同样的信号替换不同的片段：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);
Wolfram Language code: AudioReplace[a, {{.5, 1}, {1.3, 1.6}} -> AudioGenerator["Sin"]]

在不同的时间点插入不同的信号：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);
Wolfram Language code: AudioReplace[a, {{.5, 1} -> AudioGenerator["Sin"], {1.3, 1.6} -> AudioGenerator["White"]}]

拟合  (1)

用 fitting 来控制替换信号的形式：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}, "Audio"];
Wolfram Language code: Duration[a]
Wolfram Language code: b = \!\(\*AudioBox["![Embedded Audio Player](audio://content-93ofj)"]\);

缺省情况下，把替换音频信号剪辑或填充到指定的长度：

Wolfram Language code: AudioReplace[a, {.5, 1.5} -> b, "Fill"]

输入信号的时长保持不变：

Wolfram Language code: Duration[%]

用 "Insert" 避免对替换信号进行剪辑或填充：

Wolfram Language code: AudioReplace[a, {.5, 1.5} -> b, "Insert"]

如果替换信号的时长与要替换的片段不同，信号的总时长会发生改变：

Wolfram Language code: Duration[%]

用 "Stretch" 把替换音频信号拉长到指定的长度：

Wolfram Language code: AudioReplace[a, {.5, 1.5} -> b, "Stretch"]

输入信号的时长保持不变：

Wolfram Language code: Duration[%]

应用  (3)

用静音替换录音的无声部分：

Wolfram Language code: a = ExampleData[{"Audio", "NoisyTalk"}, "Audio"]

找到无声区间：

Wolfram Language code: int = AudioIntervals[a, #LoudnessEBU < -28&]

用静音替换选定的区间：

Wolfram Language code: AudioReplace[a, int -> AudioGenerator["Silence"]]
Wolfram Language code: AudioPlot[%]

用新的音频信号替换录音的一部分：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}, "Audio"]

找出幅值非零、基频在指定范围的片段：.

Wolfram Language code: int = AudioIntervals[a, #RMSAmplitude > .001 && TrueQ[#FundamentalFrequency > 280]&, PartitionGranularity -> .1]

显示所得片段：.

Wolfram Language code: AudioPlot[a, Epilog -> {RGBColor[1, 0, 0, .2], Rectangle[{#[[1]], -1}, {#[[2]], 1}]& /@ int}]

制作替换的音频信号：

Wolfram Language code: b = AudioTrim[ExampleData[{"Audio", "Piano"}, "Audio"], 2];

用替换音频信号更换所选片段：

Wolfram Language code: AudioReplace[a, int -> b, "Stretch"]
Wolfram Language code: AudioPlot[%]

纠正录音部分的音高：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}, "Audio"]

找到具有非零幅值的区间和在指定范围内的基频：

Wolfram Language code: int = AudioIntervals[a, #RMSAmplitude > .001 && TrueQ[#FundamentalFrequency > 280]&, PartitionGranularity -> .1]
Wolfram Language code: AudioLocalMeasurements[a, "FundamentalFrequency"]//ListLinePlot

定义目标频率：

Wolfram Language code: targetFrequencies = {286, 271, 256};

定义音调移位算法：

Wolfram Language code: f[audio_, targetFreq_] := AudioPitchShift[audio, targetFreq / Mean@AudioLocalMeasurements[audio, "FundamentalFrequency", MissingDataMethod -> "Interpolation"]]

计算替换部分：

Wolfram Language code: replacements = Table[int[[i]] -> f[AudioTrim[a, int[[i]]], targetFrequencies[[i]]], {i, Length@int}];

计算结果：

Wolfram Language code: AudioReplace[a, replacements]
Wolfram Language code: AudioLocalMeasurements[%, "FundamentalFrequency"]//ListLinePlot
Wolfram Research (2017)，AudioReplace，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioReplace.html.

文本

Wolfram Research (2017)，AudioReplace，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioReplace.html.

CMS

Wolfram 语言. 2017. "AudioReplace." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AudioReplace.html.

APA

Wolfram 语言. (2017). AudioReplace. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AudioReplace.html 年

BibTeX

@misc{reference.wolfram_2026_audioreplace, author="Wolfram Research", title="{AudioReplace}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/AudioReplace.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audioreplace, organization={Wolfram Research}, title={AudioReplace}, year={2017}, url={https://reference.wolfram.com/language/ref/AudioReplace.html}, note=[Accessed: 08-August-2026]}