WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BernoulliProcess[p]

事象確率 p のベルヌーイ(Bernoulli)過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
過程スライス特性  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BernoulliProcess

BernoulliProcess[p]

事象確率 p のベルヌーイ(Bernoulli)過程を表す．

詳細

例題

すべて開く すべて閉じる

例  (3)

ベルヌーイ過程のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BernoulliProcess[1 / 3], {0, 30}]
Wolfram Language code: ListPlot[data, Filling -> Axis]

平均値関数と分散関数：

Wolfram Language code: Mean[BernoulliProcess[p][t]]
Wolfram Language code: Variance[BernoulliProcess[p][t]]

共分散関数：

Wolfram Language code: CovarianceFunction[BernoulliProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[CovarianceFunction[BernoulliProcess[.3], s, t], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

スコープ  (11)

基本的な用法  (5)

経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BernoulliProcess[1 / 3], {0, 30}, 4]
Wolfram Language code: ListPlot[data, Filling -> Axis, PlotStyle -> PointSize[Medium]]

過程母数のさまざまな値についての経路を比較する：

Wolfram Language code: sample[p_] := (SeedRandom[3];RandomFunction[BernoulliProcess[p], {0, 30}])
Wolfram Language code: pars = {.1, .4, .7};
Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["p = ", ToString[#]]]& /@ pars

母数推定を処理する：

Wolfram Language code: sample = RandomFunction[BernoulliProcess[.3], {0, 10 ^ 3}];

サンプルデータについて分布母数を推定する：

Wolfram Language code: edist = EstimatedProcess[sample, BernoulliProcess[p]]

相関関数：

Wolfram Language code: CorrelationFunction[BernoulliProcess[p], s, t]

絶対相関関数：

Wolfram Language code: AbsoluteCorrelationFunction[BernoulliProcess[p], s, t]

過程スライス特性  (6)

一変量SliceDistribution：

Wolfram Language code: SliceDistribution[BernoulliProcess[p], t]

一変量スライス確率密度：

Wolfram Language code: PDF[BernoulliProcess[p][t], x]

複数の時間スライスの分布：

Wolfram Language code: SliceDistribution[BernoulliProcess[p], {1, 3, 7}]

より高次の確率密度関数(PDF)：

Wolfram Language code: PDF[BernoulliProcess[p][{1, 3, 7}], {x, y, z}]

式の期待値を計算する：

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xBernoulliProcess[p]]

事象の確率を計算する：

Wolfram Language code: Probability[3x[t] ^ 2 + 2x[t] < 3, xBernoulliProcess[p]]

歪度は時間に依存しない：

Wolfram Language code: Plot[Skewness[BernoulliProcess[p][t]], {p, 0, 1}]
Wolfram Language code: Skewness[BernoulliProcess[p][t]]

極限値：

Wolfram Language code: Limit[Skewness[BernoulliProcess[p][t]], p -> 0]
Wolfram Language code: Limit[Skewness[BernoulliProcess[p][t]], p -> 1, Direction -> 1]

BernoulliProcessはp=1/2について対称である：

Wolfram Language code: Solve[Skewness[BernoulliProcess[p][t]] == 0, p]

尖度は時間に依存しない：

Wolfram Language code: Plot[Kurtosis[BernoulliProcess[p][t]], {p, 0, 1}]
Wolfram Language code: Kurtosis[BernoulliProcess[p][t]]

極限値：

Wolfram Language code: Limit[Kurtosis[BernoulliProcess[p][t]], p -> 0]
Wolfram Language code: Limit[Kurtosis[BernoulliProcess[p][t]], p -> 1, Direction -> 1]

尖度の最小値：

Wolfram Language code: FindMinimum[Kurtosis[BernoulliProcess[p][t]] && 0 < p < 1, {p, 1 / 3}]

次数rのモーメント：

Wolfram Language code: Moment[BernoulliProcess[p][t], r]

母関数：

Wolfram Language code: CharacteristicFunction[BernoulliProcess[p][t], w]
Wolfram Language code: MomentGeneratingFunction[BernoulliProcess[p][t], w]

CentralMomentおよびその母関数：

Wolfram Language code: CentralMoment[BernoulliProcess[p][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[BernoulliProcess[p][t], w]

FactorialMomentは，記号次数については閉形式を持たない：

Wolfram Language code: FactorialMoment[BernoulliProcess[p][t], 3]
Wolfram Language code: FactorialMomentGeneratingFunction[BernoulliProcess[p][t], w]

Cumulantおよびその母関数：

Wolfram Language code: Cumulant[BernoulliProcess[p][t], r]
Wolfram Language code: CumulantGeneratingFunction[BernoulliProcess[p][t], w]

アプリケーション  (1)

公正なコインによる一連のトスを生成する：

Wolfram Language code: RandomFunction[BernoulliProcess[1 / 2], {0, 20}]["Path"] /. {{x_, 0} :> {x, H}, {x_, 1} :> {x, T}}

特性と関係  (5)

ベルヌーイ過程は弱定常である：

Wolfram Language code: WeakStationarity[BernoulliProcess[p]]

ベルヌーイ過程には明確に定義されたStationaryDistributionがある：

Wolfram Language code: StationaryDistribution[BernoulliProcess[p]]

推移確率は現行の状態には依存しない：

Wolfram Language code: Probability[(x[t2] == x2)(x[t1] == x1), xBernoulliProcess[p]]

BinomialProcess は，BernoulliProcess と の和である：

Wolfram Language code: SeedRandom[3];bernoulli = RandomFunction[BernoulliProcess[p = 17 / 32], {20}];
Wolfram Language code: ListPlot[bernoulli, Filling -> Axis]

サンプルを累積する：

Wolfram Language code: accumulated = Accumulate[bernoulli]
Wolfram Language code: ListPlot[accumulated, Filling -> Axis]

BinomialProcessと比較する：

Wolfram Language code: SeedRandom[3]; sample = RandomFunction[BinomialProcess[p], {1, 21}];

タイムスタンプを整列させる：

Wolfram Language code: binomial = TimeSeriesShift[sample, -1];
Wolfram Language code: ListPlot[{binomial, accumulated}, Filling -> Axis, PlotStyle -> {PointSize[.05], PointSize[0.02]}, PlotLegends -> {"binomial", "accumulated Bernoulli"}]

ベルヌーイ過程は大数の法則を満たす：

Wolfram Language code: proc = BernoulliProcess[1 / 3];

平均値関数は一定している：

Wolfram Language code: m = Mean[proc[t]]

サンプルの平均値を求める：

Wolfram Language code: sample = Mean[RandomFunction[proc, {10 ^ 7}]["Values"]]
Wolfram Language code: m - %//N

おもしろい例題  (1)

ベルヌーイ過程からの経路のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BernoulliProcess[.7], {20}, 500];

20におけるスライスを取り，その分布を可視化する：

Wolfram Language code: sd = data["SliceData", 20];
Wolfram Language code: cf = ColorData["DarkBands"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ First[#]), ImageSize -> 40]&[HistogramList[sd, {-0.5, 1.5, 1}]];

20におけるスライス分布の経路とヒストグラム分布をプロットする：

Wolfram Language code: ListStepPlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {20.5, .5}, {0, 1.5}], PlotStyle -> (cf /@ sd), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 10}, {.5, 1}}]
Wolfram Research (2012), BernoulliProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/BernoulliProcess.html.

テキスト

Wolfram Research (2012), BernoulliProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/BernoulliProcess.html.

CMS

Wolfram Language. 2012. "BernoulliProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BernoulliProcess.html.

APA

Wolfram Language. (2012). BernoulliProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BernoulliProcess.html

BibTeX

@misc{reference.wolfram_2026_bernoulliprocess, author="Wolfram Research", title="{BernoulliProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BernoulliProcess.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_bernoulliprocess, organization={Wolfram Research}, title={BernoulliProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/BernoulliProcess.html}, note=[Accessed: 16-September-2026]}