WOLFRAM

Wolfram 语言与系统参考资料中心

BernoulliProcess[p]

表示事件概率为 p 的伯努利过程.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
过程切片性质  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BernoulliProcess

BernoulliProcess[p]

表示事件概率为 p 的伯努利过程.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

模拟一个伯努利过程：

Wolfram Language code: data = RandomFunction[BernoulliProcess[1 / 3], {0, 30}]
Wolfram Language code: ListPlot[data, Filling -> Axis]

均值和方差函数：

Wolfram Language code: Mean[BernoulliProcess[p][t]]
Wolfram Language code: Variance[BernoulliProcess[p][t]]

协方差函数：

Wolfram Language code: CovarianceFunction[BernoulliProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[CovarianceFunction[BernoulliProcess[.3], s, t], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

范围  (11)

基本用法  (5)

模拟路径的一个组合：

Wolfram Language code: data = RandomFunction[BernoulliProcess[1 / 3], {0, 30}, 4]
Wolfram Language code: ListPlot[data, Filling -> Axis, PlotStyle -> PointSize[Medium]]

比较过程参数取不同值时的路径：

Wolfram Language code: sample[p_] := (SeedRandom[3];RandomFunction[BernoulliProcess[p], {0, 30}])
Wolfram Language code: pars = {.1, .4, .7};
Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["p = ", ToString[#]]]& /@ pars

过程参数估计：

Wolfram Language code: sample = RandomFunction[BernoulliProcess[.3], {0, 10 ^ 3}];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedProcess[sample, BernoulliProcess[p]]

相关函数：

Wolfram Language code: CorrelationFunction[BernoulliProcess[p], s, t]

绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[BernoulliProcess[p], s, t]

过程切片性质  (6)

单变量 SliceDistribution：

Wolfram Language code: SliceDistribution[BernoulliProcess[p], t]

单变量切片概率密度：

Wolfram Language code: PDF[BernoulliProcess[p][t], x]

多时切片分布：

Wolfram Language code: SliceDistribution[BernoulliProcess[p], {1, 3, 7}]

高阶 PDF：

Wolfram Language code: PDF[BernoulliProcess[p][{1, 3, 7}], {x, y, z}]

计算表达式的期望：

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xBernoulliProcess[p]]

计算事件的概率：

Wolfram Language code: Probability[3x[t] ^ 2 + 2x[t] < 3, xBernoulliProcess[p]]

偏度与时间无关：

Wolfram Language code: Plot[Skewness[BernoulliProcess[p][t]], {p, 0, 1}]
Wolfram Language code: Skewness[BernoulliProcess[p][t]]

极限值：

Wolfram Language code: Limit[Skewness[BernoulliProcess[p][t]], p -> 0]
Wolfram Language code: Limit[Skewness[BernoulliProcess[p][t]], p -> 1, Direction -> 1]

对于 p=1/2，BernoulliProcess 是对称的：

Wolfram Language code: Solve[Skewness[BernoulliProcess[p][t]] == 0, p]

峰度与时间无关：

Wolfram Language code: Plot[Kurtosis[BernoulliProcess[p][t]], {p, 0, 1}]
Wolfram Language code: Kurtosis[BernoulliProcess[p][t]]

极限值：

Wolfram Language code: Limit[Kurtosis[BernoulliProcess[p][t]], p -> 0]
Wolfram Language code: Limit[Kurtosis[BernoulliProcess[p][t]], p -> 1, Direction -> 1]

峰度的最小值：

Wolfram Language code: FindMinimum[Kurtosis[BernoulliProcess[p][t]] && 0 < p < 1, {p, 1 / 3}]

阶 r 的矩：

Wolfram Language code: Moment[BernoulliProcess[p][t], r]

母函数：

Wolfram Language code: CharacteristicFunction[BernoulliProcess[p][t], w]
Wolfram Language code: MomentGeneratingFunction[BernoulliProcess[p][t], w]

CentralMoment 及其母函数：

Wolfram Language code: CentralMoment[BernoulliProcess[p][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[BernoulliProcess[p][t], w]

对于符号式阶，FactorialMoment 无解析形式：

Wolfram Language code: FactorialMoment[BernoulliProcess[p][t], 3]
Wolfram Language code: FactorialMomentGeneratingFunction[BernoulliProcess[p][t], w]

Cumulant 及其母函数：

Wolfram Language code: Cumulant[BernoulliProcess[p][t], r]
Wolfram Language code: CumulantGeneratingFunction[BernoulliProcess[p][t], w]

应用  (1)

生成一个投掷公平硬币的序列：

Wolfram Language code: RandomFunction[BernoulliProcess[1 / 2], {0, 20}]["Path"] /. {{x_, 0} :> {x, H}, {x_, 1} :> {x, T}}

属性和关系  (5)

伯努利过程是弱平稳的：

Wolfram Language code: WeakStationarity[BernoulliProcess[p]]

伯努利过程是具有明确定义的 StationaryDistribution：

Wolfram Language code: StationaryDistribution[BernoulliProcess[p]]

转移概率与当前状态无关：

Wolfram Language code: Probability[(x[t2] == x2)(x[t1] == x1), xBernoulliProcess[p]]

BinomialProcess 是 BernoulliProcess 的和，其中 ：

Wolfram Language code: SeedRandom[3];bernoulli = RandomFunction[BernoulliProcess[p = 17 / 32], {20}];
Wolfram Language code: ListPlot[bernoulli, Filling -> Axis]

样本累积：

Wolfram Language code: accumulated = Accumulate[bernoulli]
Wolfram Language code: ListPlot[accumulated, Filling -> Axis]

与 BinomialProcess 比较：

Wolfram Language code: SeedRandom[3]; sample = RandomFunction[BinomialProcess[p], {1, 21}];

对齐时间标记：

Wolfram Language code: binomial = TimeSeriesShift[sample, -1];
Wolfram Language code: ListPlot[{binomial, accumulated}, Filling -> Axis, PlotStyle -> {PointSize[.05], PointSize[0.02]}, PlotLegends -> {"binomial", "accumulated Bernoulli"}]

伯努利过程满足大数定律：

Wolfram Language code: proc = BernoulliProcess[1 / 3];

均值函数是常数：

Wolfram Language code: m = Mean[proc[t]]

求样本均值：

Wolfram Language code: sample = Mean[RandomFunction[proc, {10 ^ 7}]["Values"]]
Wolfram Language code: m - %//N

巧妙范例  (1)

模拟伯努利过程的路径：

Wolfram Language code: data = RandomFunction[BernoulliProcess[.7], {20}, 500];

取20处的切片，并对其分布进行可视化：

Wolfram Language code: sd = data["SliceData", 20];
Wolfram Language code: cf = ColorData["DarkBands"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ First[#]), ImageSize -> 40]&[HistogramList[sd, {-0.5, 1.5, 1}]];

绘制切片分布在20处的路径和直方图分布：

Wolfram Language code: ListStepPlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {20.5, .5}, {0, 1.5}], PlotStyle -> (cf /@ sd), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 10}, {.5, 1}}]
Wolfram Research (2012)，BernoulliProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BernoulliProcess.html.

文本

Wolfram Research (2012)，BernoulliProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BernoulliProcess.html.

CMS

Wolfram 语言. 2012. "BernoulliProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BernoulliProcess.html.

APA

Wolfram 语言. (2012). BernoulliProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BernoulliProcess.html 年

BibTeX

@misc{reference.wolfram_2026_bernoulliprocess, author="Wolfram Research", title="{BernoulliProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BernoulliProcess.html}", note=[Accessed: 15-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_bernoulliprocess, organization={Wolfram Research}, title={BernoulliProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/BernoulliProcess.html}, note=[Accessed: 15-October-2026]}