WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Between[x,{min,max}]

min≤x≤max に等しい．

Between[x,{{min1,max1},{min2,max2},…}]

min1≤x≤max1||min2≤x≤max2||…に等しい．

Between[range]

式 x に適用されたときにBetween[x,range]を返す，演算子形である．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Between

Between[x,{min,max}]

min≤x≤max に等しい．

Between[x,{{min1,max1},{min2,max2},…}]

min1≤x≤max1||min2≤x≤max2||…に等しい．

Between[range]

式 x に適用されたときにBetween[x,range]を返す，演算子形である．

詳細

  • Betweenは，ある値 x が指定された範囲内にあるかどうかを判断するためにLessEqualを使用する．
  • 値 x，mini，maxiは，数値，量，日付，または一般的な記号式でよい．
  • Betweenの第2引数は，Interval，CenteredIntervalまたはDateIntervalという頭部を持つ区間としても指定することができる．
  • Between[range][x]はBetween[x,range]に等しい．

例題

すべて開く すべて閉じる

例  (3)

ある数が区間内に含まれるかどうか調べる：

Wolfram Language code: Between[3, {2, 5}]

演算子形を使う：

Wolfram Language code: Between[{2, 5}][3]

記号式については，結果が不等式で与えられる：

Wolfram Language code: Between[x, {a, b}]

10から20までの数（両端を含む）から選択する：

Wolfram Language code: Select[{5, 10, 15, 20, 25}, Between[{10, 20}]]

代りにこれらの数値を削除する：

Wolfram Language code: Discard[{5, 10, 15, 20, 25}, Between[{10, 20}]]

スコープ  (9)

Betweenを数に使う：

Wolfram Language code: Between[5, {0, 10}]
Wolfram Language code: Between[2, {E, Pi}]

Betweenを数値Quantityオブジェクトに使う：

Wolfram Language code: Between[Quantity[1, "Pounds"], {Quantity[500., "Grams"], Quantity[1., "Kilograms"]}]

Betweenを日付に使う：

Wolfram Language code: Between[Today, {Yesterday, Tomorrow}]
Wolfram Language code: Between[DateObject[{2015, 7, 1}], {DateObject[{2015, 6, 1}], DateObject[{2015, 8, 1}]}]

Betweenを区間とともに使う：

Wolfram Language code: Between[3, Interval[{2, 5}]]
Wolfram Language code: Between[Interval[{3, 4}], Interval[{2, 5}]]
Wolfram Language code: Between[Interval[{2, 4}], Interval[{2, 5}]]
Wolfram Language code: Between[Interval[{0, 1}], Interval[{2, 5}]]

同様に中心半径区間も使用することができる：

Wolfram Language code: Between[Interval[{3, 4}], CenteredInterval[5, 3]]
Wolfram Language code: Between[CenteredInterval[4, 1], CenteredInterval[5, 3]]

Betweenを日付区間とともに使う：

Wolfram Language code: Between[Today, DateInterval[{Yesterday, Tomorrow}]]
Wolfram Language code: Between[Yesterday, DateInterval[{Today, Tomorrow}]]

Betweenをいくつかの範囲の和集合に使う：

Wolfram Language code: Between[3, {{2, 5}, {8, 12}}]
Wolfram Language code: Between[6, {{2, 5}, {8, 12}}]

Betweenを複数範囲の区間および量に対して使う：

Wolfram Language code: Between[Quantity[1, "Meters"], Interval[Quantity[{0, 3}, "Feet"], {Quantity[0, "Inches"], Quantity[2, "Yards"]}]]

Betweenを演算子形で使う：

Wolfram Language code: Between[{2, 5}] /@ Range[7]

記号的値を使う：

Wolfram Language code: Between[x, {2, 5}]
Wolfram Language code: Between[3, {2, max}]
Wolfram Language code: Between[1, {2, max}]

アプリケーション  (4)

質量が指定された範囲内にある粒子を求める：

Wolfram Language code: EntityValue[EntityClass["Particle", {"Mass" -> Between[{Quantity[900., "Megaelectronvolts"/"SpeedOfLight"^2], Quantity[1000., "Megaelectronvolts"/"SpeedOfLight"^2]}]}], "Entities"]

代数次数7以上10以下の曲面を求める：

Wolfram Language code: EntityValue[EntityClass["Surface", {"AlgebraicDegree" -> Between[{7, 10}]}], {"Entity", "AlgebraicDegree"}]//SortBy[Last]

上演時間が指定範囲内の映画を求め，結果を連想で返す：

Wolfram Language code: EntityValue[EntityClass["Movie", {"Runtime" -> Between[{Quantity[220, "Minutes"], Quantity[225, "Minutes"]}]}], "Runtime", "EntityAssociation"]//Sort

自動車モデルに関する表形式データを取得する：

Wolfram Language code: tab = ResourceData["Sample Tabular Data: Car Models"]

"mpg"の値が39から40の間にある車を選択する：

Wolfram Language code: Select[tab, Between[#mpg, {39, 40}]&]

特性と関係  (7)

Between[x,{min,max}]は下限 min および上限 max を含む：

Wolfram Language code: Between[3, {3, 5.}]
Wolfram Language code: Between[5, {3, 5.}]

Between[x,{min,max}]における限界 min および max はソートされていると仮定される：

Wolfram Language code: Between[3, {2, 5}]
Wolfram Language code: Between[3, {5, 2}]

Intervalを使用することで，限界値を自動的に並べ替えることができる：

Wolfram Language code: Between[3, Echo@Interval[{5, 2}]]

Betweenにおける記号的な限界は，並べ替えられているものと仮定される：

Wolfram Language code: Between[x, {a, b}]
Wolfram Language code: % /. {x -> 3, a -> 5, b -> 2}

この仮定を回避するためには，限界を両方の順序で用いるとよい：

Wolfram Language code: Between[x, {{a, b}, {b, a}}]
Wolfram Language code: % /. {x -> 3, a -> 5, b -> 2}

同様に，Intervalで限界を囲むことによっても指定することができる：

Wolfram Language code: Between[x, Interval[{a, b}]]
Wolfram Language code: % /. {x -> 3, a -> 5, b -> 2}

x を含む区間が存在しないので，Between[x,{}]はFalseを返す：

Wolfram Language code: Between[3, {}]
Wolfram Language code: Between[x, {}]

Betweenの代りにIntervalオブジェクトとIntervalMemberQを使う：

Wolfram Language code: IntervalMemberQ[Interval[{0, 10}], 7]
Wolfram Language code: Between[7, {0, 10}]

Betweenの中で区間を直接使うこともできる：

Wolfram Language code: Between[7, Interval[{0, 10}]]

CenteredInterval範囲指定を使用する：

Wolfram Language code: Between[4, CenteredInterval[5, 2]]
Wolfram Language code: Between[1, CenteredInterval[5, 2]]

LessEqualと同様に，Betweenは，不正確な実数値を比較する際に7ビットの許容誤差を用いる：

Wolfram Language code: Between[1. + 2 ^ 7 10 ^ -16, {0., 1.}]
Wolfram Language code: Between[1. + 2 ^ 8 10 ^ -16, {0., 1.}]

ビット分の許容差しかないIntervalMemberQと比較する：

Wolfram Language code: IntervalMemberQ[Interval[{0., 1.}], 1. + 2 ^ 1 10 ^ -16]
Wolfram Language code: IntervalMemberQ[Interval[{0., 1.}], 1. + 2 ^ 2 10 ^ -16]
Wolfram Research (2015), Between, Wolfram言語関数， https://reference.wolfram.com/language/ref/Between.html.

テキスト

Wolfram Research (2015), Between, Wolfram言語関数， https://reference.wolfram.com/language/ref/Between.html.

CMS

Wolfram Language. 2015. "Between." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Between.html.

APA

Wolfram Language. (2015). Between. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Between.html

BibTeX

@misc{reference.wolfram_2026_between, author="Wolfram Research", title="{Between}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/Between.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_between, organization={Wolfram Research}, title={Between}, year={2015}, url={https://reference.wolfram.com/language/ref/Between.html}, note=[Accessed: 09-September-2026]}