WOLFRAM

Wolfram 语言与系统参考资料中心

Between[x,{min,max}]

等价于 min≤x≤max.

Between[x,{{min1,max1},{min2,max2},…}]

等价于 min1≤x≤max1||min2≤x≤max2||….

Between[range]

是一个运算符，当应用于表达式 x 时生成 Between[x,range].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

Between

Between[x,{min,max}]

等价于 min≤x≤max.

Between[x,{{min1,max1},{min2,max2},…}]

等价于 min1≤x≤max1||min2≤x≤max2||….

Between[range]

是一个运算符，当应用于表达式 x 时生成 Between[x,range].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

检验一个数是否在某区间内：

Wolfram Language code: Between[3, {2, 5}]

使用运算符形式：

Wolfram Language code: Between[{2, 5}][3]

对于符号表达式，结果以不等式形式给出：

Wolfram Language code: Between[x, {a, b}]

选择 10 和 20 之间的数，包括两端：

Wolfram Language code: Select[{5, 10, 15, 20, 25}, Between[{10, 20}]]

改为舍弃这些数字：

Wolfram Language code: Discard[{5, 10, 15, 20, 25}, Between[{10, 20}]]

范围  (9)

对数字应用 Between：

Wolfram Language code: Between[5, {0, 10}]
Wolfram Language code: Between[2, {E, Pi}]

对数值型 Quantity 对象应用 Between：

Wolfram Language code: Between[Quantity[1, "Pounds"], {Quantity[500., "Grams"], Quantity[1., "Kilograms"]}]

对日期应用 Between：

Wolfram Language code: Between[Today, {Yesterday, Tomorrow}]
Wolfram Language code: Between[DateObject[{2015, 7, 1}], {DateObject[{2015, 6, 1}], DateObject[{2015, 8, 1}]}]

将 Between 与区间一起使用：

Wolfram Language code: Between[3, Interval[{2, 5}]]
Wolfram Language code: Between[Interval[{3, 4}], Interval[{2, 5}]]
Wolfram Language code: Between[Interval[{2, 4}], Interval[{2, 5}]]
Wolfram Language code: Between[Interval[{0, 1}], Interval[{2, 5}]]

也可以使用中心区间：

Wolfram Language code: Between[Interval[{3, 4}], CenteredInterval[5, 3]]
Wolfram Language code: Between[CenteredInterval[4, 1], CenteredInterval[5, 3]]

将 Between 与日期区间一起使用：

Wolfram Language code: Between[Today, DateInterval[{Yesterday, Tomorrow}]]
Wolfram Language code: Between[Yesterday, DateInterval[{Today, Tomorrow}]]

对几个范围的并集应用 Between：

Wolfram Language code: Between[3, {{2, 5}, {8, 12}}]
Wolfram Language code: Between[6, {{2, 5}, {8, 12}}]

及 Between 多个区间和量一起使用：

Wolfram Language code: Between[Quantity[1, "Meters"], Interval[Quantity[{0, 3}, "Feet"], {Quantity[0, "Inches"], Quantity[2, "Yards"]}]]

使用运算符形式的 Between：

Wolfram Language code: Between[{2, 5}] /@ Range[7]

使用符号值：

Wolfram Language code: Between[x, {2, 5}]
Wolfram Language code: Between[3, {2, max}]
Wolfram Language code: Between[1, {2, max}]

应用  (4)

找出质量在给定范围内的粒子：

Wolfram Language code: EntityValue[EntityClass["Particle", {"Mass" -> Between[{Quantity[900., "Megaelectronvolts"/"SpeedOfLight"^2], Quantity[1000., "Megaelectronvolts"/"SpeedOfLight"^2]}]}], "Entities"]

找出代数度数在 7 和 10 之间的曲面，包括两端：

Wolfram Language code: EntityValue[EntityClass["Surface", {"AlgebraicDegree" -> Between[{7, 10}]}], {"Entity", "AlgebraicDegree"}]//SortBy[Last]

找出播放时间在给定范围内的电影，把结果作为关联返回：

Wolfram Language code: EntityValue[EntityClass["Movie", {"Runtime" -> Between[{Quantity[220, "Minutes"], Quantity[225, "Minutes"]}]}], "Runtime", "EntityAssociation"]//Sort

下面是汽车型号的表格数据：

Wolfram Language code: tab = ResourceData["Sample Tabular Data: Car Models"]

选择其 "mpg" 值在 39 到 40 之间的汽车：

Wolfram Language code: Select[tab, Between[#mpg, {39, 40}]&]

属性和关系  (7)

Between[x,{min,max}] 包括 min、max 上下限：

Wolfram Language code: Between[3, {3, 5.}]
Wolfram Language code: Between[5, {3, 5.}]

假设在 Between[x,{min,max}] 中的上下限 min、max 是有序的：

Wolfram Language code: Between[3, {2, 5}]
Wolfram Language code: Between[3, {5, 2}]

用 Interval 自动对界限进行排序：

Wolfram Language code: Between[3, Echo@Interval[{5, 2}]]

假定 Between 中的符号界限是排好序的：

Wolfram Language code: Between[x, {a, b}]
Wolfram Language code: % /. {x -> 3, a -> 5, b -> 2}

用两种顺序的界限来绕过此假设：

Wolfram Language code: Between[x, {{a, b}, {b, a}}]
Wolfram Language code: % /. {x -> 3, a -> 5, b -> 2}

相当于用 Interval 封装界限：

Wolfram Language code: Between[x, Interval[{a, b}]]
Wolfram Language code: % /. {x -> 3, a -> 5, b -> 2}

Between[x,{}] 返回 False，因为不存在包含 x 的区间：

Wolfram Language code: Between[3, {}]
Wolfram Language code: Between[x, {}]

用 Interval 对象和 IntervalMemberQ 代替 Between：

Wolfram Language code: IntervalMemberQ[Interval[{0, 10}], 7]
Wolfram Language code: Between[7, {0, 10}]

或者在 Between 中直接使用区间：

Wolfram Language code: Between[7, Interval[{0, 10}]]

使用 CenteredInterval 范围指定：

Wolfram Language code: Between[4, CenteredInterval[5, 2]]
Wolfram Language code: Between[1, CenteredInterval[5, 2]]

与 LessEqual 类似，Between 在比较不精确的实数时使用七位的容差：

Wolfram Language code: Between[1. + 2 ^ 7 10 ^ -16, {0., 1.}]
Wolfram Language code: Between[1. + 2 ^ 8 10 ^ -16, {0., 1.}]

与只使用一位容差的 IntervalMemberQ 相比较：

Wolfram Language code: IntervalMemberQ[Interval[{0., 1.}], 1. + 2 ^ 1 10 ^ -16]
Wolfram Language code: IntervalMemberQ[Interval[{0., 1.}], 1. + 2 ^ 2 10 ^ -16]
Wolfram Research (2015)，Between，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Between.html.

文本

Wolfram Research (2015)，Between，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Between.html.

CMS

Wolfram 语言. 2015. "Between." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Between.html.

APA

Wolfram 语言. (2015). Between. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Between.html 年

BibTeX

@misc{reference.wolfram_2026_between, author="Wolfram Research", title="{Between}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/Between.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_between, organization={Wolfram Research}, title={Between}, year={2015}, url={https://reference.wolfram.com/language/ref/Between.html}, note=[Accessed: 16-August-2026]}