Wolfram 语言与系统参考资料中心

BinomialProcess

表示二项过程，其事件概率为 p.

范例

打开所有单元关闭所有单元

基本范例 (3)

模拟一个二项过程：

Wolfram Language code: data = RandomFunction[BinomialProcess[1 / 3], {0, 50}]

Wolfram Language code: ListPlot[data, Filling -> Axis]

均值和方差函数：

Wolfram Language code: Mean[BinomialProcess[p][t]]

Wolfram Language code: Variance[BinomialProcess[p][t]]

协方差函数：

Wolfram Language code: CovarianceFunction[BinomialProcess[p], s, t]

Wolfram Language code:

DiscretePlot3D[CovarianceFunction[BinomialProcess[.3], s, t], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

范围 (11)

基本用法 (5)

模拟一组路径：

Wolfram Language code: data = RandomFunction[BinomialProcess[0.4], {0, 50}, 4]

Wolfram Language code: ListPlot[data, Filling -> Axis]

比较过程参数取不同值时的路径：

Wolfram Language code: sample[p_] := (SeedRandom[3];RandomFunction[BinomialProcess[p], {0, 30}])

Wolfram Language code: pars = {.1, .4, .7};

Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["p = ", ToString[#]]]& /@ pars

过程参数估计：

Wolfram Language code: sample = RandomFunction[BinomialProcess[.3], {1, 10 ^ 3}];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedProcess[sample, BinomialProcess[p]]

过程切片性质 (6)

单变量 SliceDistribution：

Wolfram Language code:

DiscretePlot[Evaluate@Table[PDF[BinomialProcess[.8][t], x], {t, times = {5, 7, 12}}], {x, 0, 15}, PlotStyle -> PointSize[Medium], PlotLegends -> (StringJoin["t = ", ToString[#]]& /@ times)]

Wolfram Language code: SliceDistribution[BinomialProcess[p], t]

单变量概率密度：

Wolfram Language code: PDF[BinomialProcess[p][t], x]

与 BinomialDistribution 的概率密度比较：

Wolfram Language code: PDF[BinomialDistribution[t, p], x]

Wolfram Language code: % - %%

多时切片分布：

Wolfram Language code: SliceDistribution[BinomialProcess[p], {1, 3, 7}]//Mean

高阶概率密度函数：

Wolfram Language code: PDF[BinomialProcess[.3][{1, 3, 7}], {x, y, z}]

计算表达式的期望：

Wolfram Language code: Expectation[x[t] ^ 2 + x[t], xBinomialProcess[p]]//PiecewiseExpand

计算事件的概率：

Wolfram Language code: Probability[x[t] > 8, xBinomialProcess[p]]

偏度：

Wolfram Language code:

DiscretePlot[Evaluate@Table[Skewness[BinomialProcess[p][t]], {p, pars = {.1, .3, .5, .7}}], {t, 1, 8}, PlotLegends -> (StringJoin["p = ", ToString[#]]& /@ pars)]

Wolfram Language code: Skewness[BinomialProcess[p][t]]

极限值：

Wolfram Language code: Limit[Skewness[BinomialProcess[p][t]], t -> ∞, Assumptions -> 1 > p > 0]

Wolfram Language code: Limit[Skewness[BinomialProcess[p][t]], t -> 0, Assumptions -> 1 > p > 0, Direction -> "FromAbove"]

求使得 BinomialProcess 对称的参数值：

Wolfram Language code: Solve[Skewness[BinomialProcess[p][t]] == 0, p]

峰度：

Wolfram Language code:

DiscretePlot[Evaluate@Table[Kurtosis[BinomialProcess[p][t]], {p, pars = {.1, .2, .5, .7}}], {t, 1, 8}, PlotLegends -> (StringJoin["p = ", ToString[#]]& /@ pars)]

Wolfram Language code: Kurtosis[BinomialProcess[p][t]]

极限值：

Wolfram Language code: Limit[Kurtosis[BinomialProcess[p][t]], t -> ∞, Assumptions -> 1 > p > 0]

Wolfram Language code: Limit[Kurtosis[BinomialProcess[p][t]], t -> 0, Assumptions -> 1 > p > 0, Direction -> "FromAbove"]

求使得 BinomialProcess 为常峰态的参数值：

Wolfram Language code: Solve[Kurtosis[BinomialProcess[p][t]] == 3, p]

Wolfram Language code: N[%]

在符号式阶数下，Moment 没有解析形式：

Wolfram Language code: Moment[BinomialProcess[p][t], 4]

母函数：

Wolfram Language code: CharacteristicFunction[BinomialProcess[p][t], w]

Wolfram Language code: MomentGeneratingFunction[BinomialProcess[p][t], w]

在符号式阶数下，CentralMoment 没有解析形式：

Wolfram Language code: CentralMoment[BinomialProcess[p][t], 3]

Wolfram Language code: CentralMomentGeneratingFunction[BinomialProcess[p][t], w]

FactorialMoment 和它的母函数：

Wolfram Language code: FactorialMoment[BinomialProcess[p][t], r]

Wolfram Language code: FactorialMomentGeneratingFunction[BinomialProcess[p][t], w]

在符号式阶数下，Cumulant 没有解析形式：

Wolfram Language code: Cumulant[BinomialProcess[p][t], 7]

Wolfram Language code: CumulantGeneratingFunction[BinomialProcess[p][t], w]

应用 (4)

一个质量保证检查员随机地从生产过程中选择10个零件，已知产品的 20% 都是坏掉的零件. 求该检查员查到至多1个坏零件的概率：

Wolfram Language code: selectionProcess = BinomialProcess[0.2];

至多选一个坏零件的概率：

Wolfram Language code: NProbability[x[10] ≤ 1, xselectionProcess]

已知一个城市里平均 50% 居民喜欢某电视节目. 求至少 55% 居民（在该城市 804 人的调查问卷中）报告他们喜欢某节目的概率：

Wolfram Language code: programPopularity = BinomialProcess[0.5];

样本中至少 55% 居民喜欢该节目的概率：

Wolfram Language code:

n = 804;
Probability[x[n] / n ≥ 0.55, xprogramPopularity]

一个由个符号组成的字符串的数据包在噪声频道上传输. 每个符号有 0.0001 的概率被错误传输. 求错误传输（至少一个错误符号）的概率小于 0.001 的最大：

Wolfram Language code: transmissionProcess = BinomialProcess[1 / 10000];

在传输过程中出现错误的概率：

Wolfram Language code: prob[n_] = Probability[x > 0, xtransmissionProcess[n]]

将传输错误概率与错误极限绘在同一幅图中：

Wolfram Language code:

errlimit = 1 / 1000;
ListLogPlot[Transpose@Table[{prob[n], errlimit}, {n, 0, 15}], Joined -> True, PlotLegends -> {"probability", "error limit"}]

求使得错误传输概率小于的的最大值：

Wolfram Language code: Maximize[{n, prob[n] ≤ errlimit && n∈Integers && 5 ≤ n ≤ 15}, n]

求在一个多期二项式模型中，欧式看涨期权在第三期后的的价格，已知标的物的初始价格为$100，每期的利率为1%，股票向上移动7％，或下降1/1.07：

Wolfram Language code:

s0 = 100;
strike = 102;
rate = 1.01;
up = 1.07;
down = 1 / 1.07;
T = 3;

模拟该过程：

Wolfram Language code: price = BinomialProcess[(rate - down) / (up - down)];

看涨期权的价格：

Wolfram Language code: Expectation[1 / rate ^ T Max[s0 up ^ proc[T] down ^ (T - proc[T]) - strike, 0], procprice]

属性和关系 (5)

二项过程仅在 p 等于 0 时是弱平稳的：

Wolfram Language code: WeakStationarity[BinomialProcess[p]]

BinomialProcess 是 BernoulliProcess 的和，其中：

Wolfram Language code:

SeedRandom[3];
bernoulli = RandomFunction[BernoulliProcess[p = 17 / 32], {20}];

Wolfram Language code: ListPlot[bernoulli, Filling -> Axis]

样本的累积：

Wolfram Language code: accumulated = Accumulate[bernoulli]

Wolfram Language code: ListPlot[accumulated, Filling -> Axis]

与二项式过程比较：

Wolfram Language code:

SeedRandom[3];
sample = RandomFunction[BinomialProcess[p], {1, 21}];

对齐时间标记：

Wolfram Language code: binomial = TimeSeriesShift[sample, -1];

Wolfram Language code:

ListPlot[{binomial, accumulated}, Filling -> Axis, PlotStyle -> {PointSize[.05], PointSize[0.02]}, PlotLegends -> {"binomial", "accumulated Bernoulli"}]

在二项式过程中，事件之间的时间服从 PascalDistribution：

Wolfram Language code: binomial = RandomFunction[BinomialProcess[1 / 3], {10 ^ 4}];

计算变化之间的时间：

Wolfram Language code: times = Length /@ Split[binomial["Values"]];

Wolfram Language code: h = Histogram[times, {Min[times] - 0.5, Max[times] + 0.5, 1}, "PDF"]

拟合帕斯卡分布：

Wolfram Language code: edist = EstimatedDistribution[times, PascalDistribution[1, p]]

将数据直方图与估计的概率密度函数比较：

Wolfram Language code: Show[h, DiscretePlot[PDF[edist, x], {x, 0, Max[times]}, PlotStyle -> PointSize[Medium]]]

检查拟合优度：

Wolfram Language code: DistributionFitTest[times, edist, "TestConclusion"]

两个状态之间的转移概率：

Wolfram Language code:

Table[DiscretePlot[Probability[(x[12] == Subscript[x, 2])(x[7] == Subscript[x, 1]), xBinomialProcess[.6]], {Subscript[x, 2], 0, 13}, ExtentSize -> 1 / 2, PlotLabel -> StringJoin["SubscriptBox[x, 1] = ", ToString[Subscript[x, 1]]]], {Subscript[x, 1], {1, 3, 5, 7}}]

Wolfram Language code:

Probability[(x[Subscript[t, 2]] == Subscript[x, 2])(x[Subscript[t, 1]] == Subscript[x, 1]), xBinomialProcess[p], Assumptions -> 0 < Subscript[t, 1] < Subscript[t, 2] && 0 ≤ Subscript[x, 1] ≤ Subscript[t, 1] && 0 ≤ Subscript[x, 2] ≤ Subscript[t, 2]]//Simplify

BinomialProcess 是一种特殊的 CompoundRenewalProcess：

Wolfram Language code: proc = CompoundRenewalProcess[PascalDistribution[1, p], BernoulliDistribution[1]];

平均函数一致：

Wolfram Language code: proc[t]//Mean

Wolfram Language code: Mean[BinomialProcess[p][t]]

创建经验协方差函数：

Wolfram Language code: sample1 = RandomFunction[proc /. p -> .3, {30}, 10 ^ 3];

Wolfram Language code: cov1[s_, t_] := Covariance[sample1["SliceData", s], sample1["SliceData", t]]

Wolfram Language code: sample2 = RandomFunction[BinomialProcess[.3], {0, 30}, 10 ^ 3];

Wolfram Language code: cov2[s_, t_] := Covariance[sample2["SliceData", s], sample2["SliceData", t]]

比较协方差函数：

Wolfram Language code:

DiscretePlot3D[#[s, t], {s, 1, 15}, {t, 1, 15}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", PlotRange -> {0, 4}]& /@ {cov1, cov2}

巧妙范例 (1)

模拟一个二项式过程的500个路径：

Wolfram Language code: data = RandomFunction[BinomialProcess[.7], {50}, 500];

在50处取切片，并对它的分布进行可视化：

Wolfram Language code: sd = data["SliceData", 50];

Wolfram Language code:

cf = ColorData["Rainbow"];
sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 30]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 15]}]];

作出切片分布在50处的路径和直方图分布：

Wolfram Language code:

ListLinePlot[data, ImageSize -> 400, PlotRange -> All, 
	AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {50.5, Mean[sd]}, {0, 7.5}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 20}, {.5, 7}}]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

BinomialProcess

更多信息

范例

基本范例 (3)

范围 (11)

基本用法 (5)

过程切片性质 (6)

应用 (4)

属性和关系 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

BinomialProcess

更多信息

范例

基本范例 (3)

范围 (11)

基本用法 (5)

过程切片性质 (6)

应用 (4)

属性和关系 (5)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX