WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BiquadraticFilterModel[{ω,q}]

特性周波数 ω とQ値 q を使ってローパス双二次フィルタを作る．

BiquadraticFilterModel[{"type",spec}]

指定された{"type",spec}のフィルタを作る．

BiquadraticFilterModel[{"type",spec},var]

モデルを変数 var によって表現する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BiquadraticFilterModel

BiquadraticFilterModel[{ω,q}]

特性周波数 ω とQ値 q を使ってローパス双二次フィルタを作る．

BiquadraticFilterModel[{"type",spec}]

指定された{"type",spec}のフィルタを作る．

BiquadraticFilterModel[{"type",spec},var]

モデルを変数 var によって表現する．

詳細

  • 双二次フィルタは2つの二次多項式の比によって定義される二次フィルタで，アナログ・デジタル双方の信号処理回路で最もよく使われているものの一つである．
  • BiquadraticFilterModelはフィルタをTransferFunctionModelとして返す．
  • フィルタ指定{"type",spec}は次の任意のものでよい．
  • {"Lowpass",{{ω,q}}}カットオフ周波数 ω，Q値 q
    {"Highpass",{{ω,q}}}カットオフ周波数 ω，Q値 q
    {"Allpass",{{ω,q}}}周波数 ω，Q値 q
    {"Bandpass",{ω1,ω2}}コーナー周波数 ω1と ω2
    {"Bandpass",{{ω,q}}}中心周波数 ω，Q値 q
    {"Bandstop",{ω1,ω2}}コーナー周波数 ω1と ω2
    {"Bandstop",{{ω,q}}}中心周波数 ω，Q値 q
  • 次のフィルタ指定を与えてイコライザを作ることができる．
  • {"Peaking",{{ω,q}},g}ゲイン値 g を使ったピーキングイコライザ
    {"LowShelf",{{ω,q}},g}ゲイン値 g を使ったローパスシェルビングイコライザ
    {"HighShelf",{{ω,q}},g}ゲイン値 g を使ったハイパスシェルビングイコライザ
  • ゲイン値 のとき，減衰は である．

例題

すべて開く すべて閉じる

例  (3)

ローパス双二次フィルタ：

Wolfram Language code: tf = BiquadraticFilterModel[{1, 1}]

フィルタのボード線図：

Wolfram Language code: BodePlot[tf, GridLines -> Automatic, PlotLayout -> "Magnitude"]

完全指定を使ったバンドパスフィルタ：

Wolfram Language code: tf = BiquadraticFilterModel[{"Bandpass", {{1, 1}}}]

フィルタのボード線図：

Wolfram Language code: BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

ローパスフィルタを作り，デュアルトーン信号に適用する：

Wolfram Language code: in = Sin[ 1 / 5 t] + Sin[5t]; out = OutputResponse[BiquadraticFilterModel[{1, 1}], in, {t, 0, 60}]; Plot[{in, out}, {t, 0, 40}, PlotLegends -> {"Input", "Output"}]

スコープ  (8)

カットオフ周波数 ω，Q値 の記号的ローパスフィルタ：

Wolfram Language code: BiquadraticFilterModel[{ω, Q}]

完全な指定を使う：

Wolfram Language code: BiquadraticFilterModel[{"Lowpass", {{1, 1}}}, s]

カットオフ周波数 を指定する：

Wolfram Language code: tf = BiquadraticFilterModel[{"Lowpass", {{10, 1}}}, s]

フィルタのボード線図：

Wolfram Language code: BodePlot[tf, {1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

カットオフ周波数 ，Q値 の記号的ハイパスフィルタ：

Wolfram Language code: BiquadraticFilterModel[{"Highpass", {{ω, Q}}}]

カットオフ周波数 を使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"Highpass", {{10, 1}}}, s]
Wolfram Language code: BodePlot[tf, {1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

カットオフ周波数 ，Q値 の記号的バンドパスフィルタ：

Wolfram Language code: BiquadraticFilterModel[{"Bandpass", {{ω, Q}}}]

Q値 を使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"Bandpass", {{1, 10}}}, s]
Wolfram Language code: BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

中心周波数 ，Q値 の記号的バンドストップフィルタ：

Wolfram Language code: BiquadraticFilterModel[{"Bandstop", {{ω, Q}}}]

Q値 を使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"Bandstop", {{1, 2}}}, s]
Wolfram Language code: BodePlot[tf, {0.1, 10}, PlotRange -> {0, -10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

中心周波数 ，Q値 の記号的なオールパスフィルタ：

Wolfram Language code: BiquadraticFilterModel[{"Allpass", {{ω, Q}}}]

Q値 を使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"Allpass", {{1, 2}}}, s]
Wolfram Language code: BodePlot[tf, PlotRange -> {0.99, 1.01}, PlotLayout -> "Magnitude"]

中心周波数 ，Q値 ，ゲイン値 の記号的な"Peaking"オールパスフィルタ：

Wolfram Language code: BiquadraticFilterModel[{"Peaking", {{ω, Q}}, g}]

ピークゲイン値 デシベルを使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"Peaking", {{1, 1}}, Quantity[10, "dB"]}, s]
Wolfram Language code: BodePlot[tf, {0.1, 10}, PlotRange -> {-5, 15}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

中心周波数 ，Q値 ，ゲイン値 の記号的な"LowShelf"フィルタ：

Wolfram Language code: BiquadraticFilterModel[{"LowShelf", {{ω, Q}}, g}]

ローシェルフゲイン値 デシベルを使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"LowShelf", {{1, 1}}, Quantity[-5, "dB"]}, s]
Wolfram Language code: BodePlot[tf, {0.1, 10}, PlotRange -> {-10, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

中心周波数 ，Q値 ，ゲイン値 の記号的な"HighShelf"フィルタ：

Wolfram Language code: BiquadraticFilterModel[{"HighShelf", {{ω, Q}}, g}]

ローシェルフゲイン値 デシベルを使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"HighShelf", {{1, 1}}, Quantity[-5, "dB"]}, s]
Wolfram Language code: BodePlot[tf, {0.1, 10}, PlotRange -> {-10, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

一般化と拡張  (1)

2つあるいはそれ以上のフィルタを直列に繋いでストップバンド減衰を改善する：

Wolfram Language code: tf = BiquadraticFilterModel[{"Lowpass", {{1, 1}}}]; tfs = NestList[SystemsModelSeriesConnect[tf, #]&, tf, 2]
Wolfram Language code: BodePlot[tfs, {0.1, 10}, PlotRange -> {-120, 20}, GridLines -> Automatic, PlotLayout -> "Magnitude", FrameTicks -> {{Range[0, -120, -40], None}, {Automatic, Automatic}}, PlotLegends -> {"40 dB/decade", "80 dB/decade", "120 dB/decade"}]

アプリケーション  (1)

正弦波音のペアから高周波音をフィルタアウトする：

Wolfram Language code: in = (Sin[ 1 / 5 t] + Sin[5t]) UnitStep[t]; Plot[in, {t, 20, 60}]

双二次ローパスフィルタを使う：

Wolfram Language code: tf = BiquadraticFilterModel[{"Lowpass", {{1, 1}}}]; out = OutputResponse[tf, in, {t, 0, 60}]; Plot[out, {t, 20, 60}]

3つフィルタを組み合せて高次フィルタを作り，フィルタリングの質を改善する：

Wolfram Language code: tf2 = Nest[SystemsModelSeriesConnect[tf, #]&, tf, 2]
Wolfram Language code: out = OutputResponse[tf2, in, {t, 0, 60}]; Plot[out, {t, 20, 60}]

特性と関係  (7)

基本的な4つのフィルタタイプの位相応答：

Wolfram Language code: type = {"Lowpass", "Highpass", "Bandpass", "Bandstop"}; tfs = BiquadraticFilterModel[{#, {{1, 1}}}]& /@ type; BodePlot[tfs, {0.1, 10.}, PlotLayout -> "Phase", GridLines -> Automatic, PlotLegends -> type]

BiquadraticFilterModelの次数を抽出する：

Wolfram Language code: SystemsModelOrder[StateSpaceModel[BiquadraticFilterModel[{"Lowpass", {{1., 1.}}}]]]

ストップバンド減衰は10年に40デシベルの割合で増加する：

Wolfram Language code: tf = BiquadraticFilterModel[{"Lowpass", {{1, 1}}}]; BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

カットオフ周波数のゲインはQ値 の品質を上げると増す：

Wolfram Language code: tf = BiquadraticFilterModel[{"Lowpass", {{1, #}}}]& /@ {1 / 2, 1, 3, 9}; BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotRange -> {-20, 20}, PlotLayout -> "Magnitude", PlotLegends -> {0.5, 1., 3., 9.}]

バンドパスフィルタの帯域はQ値 の増加につれて減少する：

Wolfram Language code: tf = BiquadraticFilterModel[{"Bandpass", {{1., #}}}]& /@ {0.5, 1., 3.}; BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude", PlotRange -> {-40, 5}, PlotLegends -> {0.5, 1., 3.}]

ゲイン値 はピーキングイコライザの振幅特性を「強化」する：

Wolfram Language code: tfboost = BiquadraticFilterModel[{"Peaking", {{1, 1}}, #}, s]& /@ {4 / 3, 5 / 3, 6 / 3}
Wolfram Language code: BodePlot[tfboost, {0.1, 10}, PlotRange -> {-15, 15}, PlotLayout -> "Magnitude", GridLines -> Automatic, PlotLegends -> N@{4 / 3, 5 / 3, 6 / 3}]

ゲイン値 はピーキングイコライザの振幅特性を「カット」する：

Wolfram Language code: tfcut = BiquadraticFilterModel[{"Peaking", {{1, 1}}, #}, s]& /@ {3 / 6, 3 / 5, 3 / 4}
Wolfram Language code: BodePlot[tfcut, {0.1, 10}, PlotRange -> {-15, 15}, PlotLayout -> "Magnitude", GridLines -> Automatic, PlotLegends -> N@{3 / 6, 3 / 5, 3 / 4}]

ゲイン値 はローシェルフフィルタの振幅特性を「強化」する：

Wolfram Language code: tfboost = BiquadraticFilterModel[{"LowShelf", {{1, 1}}, #}, s]& /@ {4 / 3, 5 / 3, 6 / 3}
Wolfram Language code: BodePlot[tfboost, {0.1, 10}, PlotRange -> {-15, 15}, PlotLayout -> "Magnitude", GridLines -> Automatic, PlotLegends -> N@{4 / 3, 5 / 3, 6 / 3}]

ゲイン値 はローシェルフフィルタの振幅特性を「カット」する：

Wolfram Language code: tfcut = BiquadraticFilterModel[{"LowShelf", {{1, 1}}, #}, s]& /@ {3 / 6, 3 / 5, 3 / 4}
Wolfram Language code: BodePlot[tfcut, {0.1, 10}, PlotRange -> {-15, 15}, PlotLayout -> "Magnitude", GridLines -> Automatic, PlotLegends -> N@{3 / 6, 3 / 5, 3 / 4}]
Wolfram Research (2016), BiquadraticFilterModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/BiquadraticFilterModel.html.

テキスト

Wolfram Research (2016), BiquadraticFilterModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/BiquadraticFilterModel.html.

CMS

Wolfram Language. 2016. "BiquadraticFilterModel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BiquadraticFilterModel.html.

APA

Wolfram Language. (2016). BiquadraticFilterModel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BiquadraticFilterModel.html

BibTeX

@misc{reference.wolfram_2026_biquadraticfiltermodel, author="Wolfram Research", title="{BiquadraticFilterModel}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BiquadraticFilterModel.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_biquadraticfiltermodel, organization={Wolfram Research}, title={BiquadraticFilterModel}, year={2016}, url={https://reference.wolfram.com/language/ref/BiquadraticFilterModel.html}, note=[Accessed: 12-August-2026]}