WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BlackmanNuttallWindow[x]

x のBlackman–Nuttall窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BlackmanNuttallWindow

BlackmanNuttallWindow[x]

x のBlackman–Nuttall窓関数を表す．

詳細

  • BlackmanNuttallWindowは，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • BlackmanNuttallWindow[x]は (4891775 cos(2 pi x)+1365995 cos(4 pi x)+106411 cos(6 pi x)+3635819)/(10000000) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • BlackmanNuttallWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1DのBlackman–Nuttall窓の形：

Wolfram Language code: Plot[BlackmanNuttallWindow[x], {x, -1, 1}]

2DのBlackman–Nuttall窓の形：

Wolfram Language code: Plot3D[BlackmanNuttallWindow[x]BlackmanNuttallWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

Blackman–Nuttall窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[BlackmanNuttallWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: BlackmanNuttallWindow[0.1]

平行移動され広げられたBlackman–Nuttall窓：

Wolfram Language code: Plot[BlackmanNuttallWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2DのBlackman–Nuttall窓：

Wolfram Language code: Plot3D[BlackmanNuttallWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散Blackman–Nuttall窓：

Wolfram Language code: ListPlot[Array[BlackmanNuttallWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2Dの離散Blackman–Nuttall窓：

Wolfram Language code: ListPointPlot3D[Array[BlackmanNuttallWindow[#1] BlackmanNuttallWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis, PlotRange -> All]

アプリケーション  (3)

長さ11の移動平均フィルタを作る：

Wolfram Language code: h = ConstantArray[1 / 21., 21]

Blackman–Nuttall窓を使ってフィルタを漸減させる：

Wolfram Language code: w = Array[BlackmanNuttallWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h;

フィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.01, Pi}, PlotRange -> {5, -100}, GridLines -> Automatic]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BlackmanNuttallWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BlackmanNuttallWindow}]

特性と関係  (2)

Blackman–Nuttall窓の下の面積：

Wolfram Language code: area = Integrate[BlackmanNuttallWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{BlackmanNuttallWindow[x], BlackmanNuttallWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Blackman–Nuttall窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[BlackmanNuttallWindow[x], x, w]

Blackman–Nuttall窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012), BlackmanNuttallWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlackmanNuttallWindow.html.

テキスト

Wolfram Research (2012), BlackmanNuttallWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlackmanNuttallWindow.html.

CMS

Wolfram Language. 2012. "BlackmanNuttallWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlackmanNuttallWindow.html.

APA

Wolfram Language. (2012). BlackmanNuttallWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlackmanNuttallWindow.html

BibTeX

@misc{reference.wolfram_2026_blackmannuttallwindow, author="Wolfram Research", title="{BlackmanNuttallWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlackmanNuttallWindow.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blackmannuttallwindow, organization={Wolfram Research}, title={BlackmanNuttallWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BlackmanNuttallWindow.html}, note=[Accessed: 11-August-2026]}