WOLFRAM

Wolfram 语言与系统参考资料中心

BlackmanWindow[x]

表示 x 的 Blackman 窗函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BlackmanWindow

BlackmanWindow[x]

表示 x 的 Blackman 窗函数.

更多信息

  • BlackmanWindow 是一个窗函数，通常用于设计有限冲激响应滤波器 (FIR) 和频谱分析.
  • 窗函数使用于数据在小片段中处理的应用中，并通过在每个片段末尾将数据值逐渐减小到零的方式产生平滑效果.
  • Blackman 窗近似于 ExactBlackmanWindow. 截断系数提高高频衰减，但代价是更大的频谱旁瓣.
  • BlackmanWindow[x] 等于  1/(50) (25 cos(2 pi x)+4 cos(4 pi x)+21) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; .
  • BlackmanWindow 自动线性作用于列表.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维 Blackman 窗的形状：

Wolfram Language code: Plot[BlackmanWindow[x], {x, -1, 1}]

二维 Blackman 窗的形状：

Wolfram Language code: Plot3D[BlackmanWindow[x]BlackmanWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示 Blackman 窗的连续函数：

Wolfram Language code: FunctionExpand[BlackmanWindow[x]]

范围  (4)

数值计算：

Wolfram Language code: BlackmanWindow[0.1]

Blackman 窗的变换和伸缩：

Wolfram Language code: Plot[BlackmanWindow[(x - 1) / 2], {x, -1, 3}]

在圆形支持（support）下的二维 Blackman 窗：

Wolfram Language code: Plot3D[BlackmanWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

长度为15的离散 Blackman 窗：

Wolfram Language code: ListPlot[Array[BlackmanWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散15×10 二维 Blackman 窗：

Wolfram Language code: ListPointPlot3D[Array[BlackmanWindow[#1] BlackmanWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

应用  (4)

创建一个长度为 21、截止频率为 的低通 FIR 滤波器：

Wolfram Language code: h = LeastSquaresFilterKernel[{"Lowpass", π / 5}, 21]

用 Blackman 窗窄化滤波器，提高阻带衰减：

Wolfram Language code: w = Array[BlackmanWindow, Length[h], {-1 / 2, 1 / 2}]; fir = h w;

归一化：

Wolfram Language code: fir / Total[fir]

两个滤波器的功率谱的对数幅度图：

Wolfram Language code: Plot[Evaluate[20Log10[Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, %}], {ω, 0, π}, GridLines -> Automatic]

使用 Blackman 窗方法对白噪声信号滤波：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000]; Periodogram[{a, LowpassFilter[a, 8000 π / 3, 21, BlackmanWindow]}]

使用窗指定，计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BlackmanWindow];

与不用窗函数计算得到的谱密度比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

下图显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

将窗指定用于时间序列估计：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BlackmanWindow}]

属性和关系  (5)

Blackman 窗下的面积：

Wolfram Language code: area = Integrate[BlackmanWindow[x], {x, -∞, ∞}]

规范化以创建单位面积的窗：

Wolfram Language code: Plot[{BlackmanWindow[x], BlackmanWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Blackman 窗的傅里叶变换：

Wolfram Language code: f = FourierTransform[BlackmanWindow[x], x, w]

Blackman 窗的功率谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 100}, PlotRange -> {0, -120}]

离散长度为 15 的 Blackman 窗：

Wolfram Language code: Array[BlackmanWindow, 15, {-0.5, 0.5}]

归一化使得系数之和为 1：

Wolfram Language code: % / Total[%]

长度为 15 的归一化离散 Blackman 窗的离散时间傅立叶变换：

Wolfram Language code: (win = Array[HammingWindow, 15, {-0.5, 0.5}]; f = ListFourierSequenceTransform[win / Total[win], ω])

幅值谱：

Wolfram Language code: Plot[Abs@f, {ω, 0, π}, PlotRange -> All]

Blackman 窗和矩形窗的功率谱：

Wolfram Language code: tab = Table[(h = Array[win, 15, {-0.5, 0.5}]; 20Log10[Abs@ListFourierSequenceTransform[h / Total[h], ω]]), {win, {BlackmanWindow, DirichletWindow}}];
Wolfram Language code: Plot[tab, {ω, 0, π}, PlotRange -> {5, -80}, PlotLegends -> {BlackmanWindow, DirichletWindow}]
Wolfram Research (2012)，BlackmanWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlackmanWindow.html.

文本

Wolfram Research (2012)，BlackmanWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlackmanWindow.html.

CMS

Wolfram 语言. 2012. "BlackmanWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BlackmanWindow.html.

APA

Wolfram 语言. (2012). BlackmanWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BlackmanWindow.html 年

BibTeX

@misc{reference.wolfram_2026_blackmanwindow, author="Wolfram Research", title="{BlackmanWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlackmanWindow.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_blackmanwindow, organization={Wolfram Research}, title={BlackmanWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BlackmanWindow.html}, note=[Accessed: 15-September-2026]}