WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BohmanWindow[x]

x のBohman窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BohmanWindow

BohmanWindow[x]

x のBohman窓関数を表す．

詳細

  • BohmanWindowは，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • BohmanWindow[x]は (-sin(2 pi x)+2 pi x cos(2 pi x)+pi cos(2 pi x))/pi -1/2<=x<0; (sin(2 pi x)-2 pi x cos(2 pi x)+pi cos(2 pi x))/pi 0<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • BohmanWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1DのBohman窓の形：

Wolfram Language code: Plot[BohmanWindow[x], {x, -1, 1}]

2DのBohman窓の形：

Wolfram Language code: Plot3D[BohmanWindow[x]BohmanWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

Bohman窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[BohmanWindow[x]]

スコープ  (4)

平衡移動され広げられたBohman窓：

Wolfram Language code: Plot[BohmanWindow[(x - 1) / 2], {x, -1, 3}]

円形サポートを持つ2DのBohman窓：

Wolfram Language code: Plot3D[BohmanWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

数値評価する：

Wolfram Language code: BohmanWindow[0.1]

長さ15の離散Bohman窓：

Wolfram Language code: ListPlot[Array[BohmanWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散Bohman窓：

Wolfram Language code: ListPointPlot3D[Array[BohmanWindow[#1] BohmanWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis, PlotRange -> All]

アプリケーション  (3)

長さ21の移動平均フィルタを作る：

Wolfram Language code: h = ConstantArray[1 / 21., 21]

Bohman窓を使ってフィルタを漸減させる：

Wolfram Language code: w = Array[BohmanWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h;

フィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.1, Pi}, GridLines -> Automatic]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BohmanWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BohmanWindow}]

特性と関係  (2)

Bohman窓の下の面積：

Wolfram Language code: area = Integrate[BohmanWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{BohmanWindow[x], BohmanWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Bohman窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[BohmanWindow[x], x, w]

Bohman窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012), BohmanWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BohmanWindow.html.

テキスト

Wolfram Research (2012), BohmanWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BohmanWindow.html.

CMS

Wolfram Language. 2012. "BohmanWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BohmanWindow.html.

APA

Wolfram Language. (2012). BohmanWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BohmanWindow.html

BibTeX

@misc{reference.wolfram_2026_bohmanwindow, author="Wolfram Research", title="{BohmanWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BohmanWindow.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bohmanwindow, organization={Wolfram Research}, title={BohmanWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BohmanWindow.html}, note=[Accessed: 12-August-2026]}