WOLFRAM

Wolfram 语言与系统参考资料中心

BohmanWindow[x]

表示 x 的 Bohman 窗函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BohmanWindow

BohmanWindow[x]

表示 x 的 Bohman 窗函数.

更多信息

  • BohmanWindow 是一个窗函数，通常用在信号处理中需要以短的片段对数据进行处理的应用中.
  • 窗函数通过在每个片段的末端将数据值逐渐减小为零来产生平滑效果.
  • BohmanWindow[x] 等于  (-sin(2 pi x)+2 pi x cos(2 pi x)+pi cos(2 pi x))/pi -1/2<=x<0; (sin(2 pi x)-2 pi x cos(2 pi x)+pi cos(2 pi x))/pi 0<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; .
  • BohmanWindow 自动线性作用于列表.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维 Bohman 窗的形状：

Wolfram Language code: Plot[BohmanWindow[x], {x, -1, 1}]

二维 Bohman 窗的形状：

Wolfram Language code: Plot3D[BohmanWindow[x]BohmanWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示 Bohman 窗的连续函数：

Wolfram Language code: FunctionExpand[BohmanWindow[x]]

范围  (4)

Bohman 窗的变换和伸缩：

Wolfram Language code: Plot[BohmanWindow[(x - 1) / 2], {x, -1, 3}]

在圆形支持（support）下的二维 Bohman 窗：

Wolfram Language code: Plot3D[BohmanWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

数值计算：

Wolfram Language code: BohmanWindow[0.1]

长度为15的离散 Bohman 窗：

Wolfram Language code: ListPlot[Array[BohmanWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散15×10 二维 Bohmanl 窗：

Wolfram Language code: ListPointPlot3D[Array[BohmanWindow[#1] BohmanWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

应用  (3)

创建长度为 21 的平均移动滤波器：

Wolfram Language code: h = ConstantArray[1 / 21., 21]

用 Bohman 窗窄化滤波器：

Wolfram Language code: w = Array[BohmanWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h;

滤波器的功率谱的对数幅度图：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.1, Pi}, GridLines -> Automatic]

使用窗指定，计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BohmanWindow];

与不用窗函数计算得到的谱密度比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

下图显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

将窗指定用于时间序列估计：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BohmanWindow}]

属性和关系  (2)

Bohman 窗下的面积：

Wolfram Language code: area = Integrate[BohmanWindow[x], {x, -∞, ∞}]

规范化以创建单位面积的窗：

Wolfram Language code: Plot[{BohmanWindow[x], BohmanWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Bohman 窗的傅里叶变换：

Wolfram Language code: f = FourierTransform[BohmanWindow[x], x, w]

Bohman 窗的功率谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012)，BohmanWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BohmanWindow.html.

文本

Wolfram Research (2012)，BohmanWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BohmanWindow.html.

CMS

Wolfram 语言. 2012. "BohmanWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BohmanWindow.html.

APA

Wolfram 语言. (2012). BohmanWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BohmanWindow.html 年

BibTeX

@misc{reference.wolfram_2026_bohmanwindow, author="Wolfram Research", title="{BohmanWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BohmanWindow.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bohmanwindow, organization={Wolfram Research}, title={BohmanWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BohmanWindow.html}, note=[Accessed: 07-August-2026]}