WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BooleanConsecutiveFunction[k,n]

変数が n 個で，連続する k 個の変数がTrueのときにTrueを与えるブール関数を表す．

BooleanConsecutiveFunction[{k,True},n]

変数のリストを循環的に扱う．

BooleanConsecutiveFunction[{k1,k2,…,kd},{n1,n2,…,nd}]

変数が n1 n2 ⋯ nd 個で， 変数配列の ブロックのすべての変数がTrueのときTrueを与えるブール関数を表す．

BooleanConsecutiveFunction[{{k1,k2,…,kd},{c1,c2,…,cd}},{n1,n2,…,nd}]

ciがTrueのときは，変数配列の i 番目のレベルを循環的に扱う．

BooleanConsecutiveFunction[spec,{a1,a2,…}]

spec で指定されたブール連続関数に対応する変数 aiのブール式を与える．

BooleanConsecutiveFunction[spec,{a1,a2,…},form]

form で指定された形式でブール式を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
線形モデル  
円形モデル  
混合モデル  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BooleanConsecutiveFunction

BooleanConsecutiveFunction[k,n]

変数が n 個で，連続する k 個の変数がTrueのときにTrueを与えるブール関数を表す．

BooleanConsecutiveFunction[{k,True},n]

変数のリストを循環的に扱う．

BooleanConsecutiveFunction[{k1,k2,…,kd},{n1,n2,…,nd}]

変数が n1 n2 ⋯ nd 個で， 変数配列の ブロックのすべての変数がTrueのときTrueを与えるブール関数を表す．

BooleanConsecutiveFunction[{{k1,k2,…,kd},{c1,c2,…,cd}},{n1,n2,…,nd}]

ciがTrueのときは，変数配列の i 番目のレベルを循環的に扱う．

BooleanConsecutiveFunction[spec,{a1,a2,…}]

spec で指定されたブール連続関数に対応する変数 aiのブール式を与える．

BooleanConsecutiveFunction[spec,{a1,a2,…},form]

form で指定された形式でブール式を与える．

詳細

例題

すべて開く すべて閉じる

例  (3)

連続型2アウトオブ3のブール関数を作る：

Wolfram Language code: BooleanConsecutiveFunction[2, 3][Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]]

明示的な形に変換する：

Wolfram Language code: BooleanConvert[%]

BooleanConsecutiveFunctionをReliabilityDistributionで使う：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = Table[ExponentialDistribution[Subscript[λ, i]], {i, 3}];
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[2, 3][x, y, z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

生存関数を計算する：

Wolfram Language code: SurvivalFunction[ℛ, t]//Simplify

BooleanConsecutiveFunctionをFailureDistributionで使う：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = Table[ExponentialDistribution[Subscript[λ, i]], {i, 3}];
Wolfram Language code: ℱ = FailureDistribution[BooleanConsecutiveFunction[2, 3][x, y, z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

生存関数を計算する：

Wolfram Language code: SurvivalFunction[ℱ, t]//Simplify

スコープ  (10)

線形モデル  (4)

BooleanConsecutiveFunctionは未評価のまま残る：

Wolfram Language code: BooleanConsecutiveFunction[2, 4][x, y, z, v]

BooleanConvertを使ってこれを展開する：

Wolfram Language code: BooleanConvert[%]

関数を連言標準形の式として構築する：

Wolfram Language code: BooleanConsecutiveFunction[2, {x, y, z, v}, "CNF"]

格子状の形をした二次元関数を定義する：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{2, 2}, {3, 3}][Array[Subscript[x, #1, #2]&, {3, 3}]]]

変数もまた平坦なリストで与えることができる：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{2, 2}, {3, 3}][Array[Subscript[x, #]&, 9]]]

1列になった連続する4つの成分の少なくとも3つが動けば動く系：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ, t]

BooleanConsecutiveFunctionは構造で使うことができる：

Wolfram Language code: ℛ2 = ReliabilityDistribution[w∨BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ2, t]

1列になった連続する4つの成分の少なくとも3つが故障すると故障する系：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℱ = FailureDistribution[BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ, t]

BooleanConsecutiveFunctionは構造で使うことができる：

Wolfram Language code: ℱ2 = FailureDistribution[w∨BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ2, t]

円形モデル  (4)

BooleanConsecutiveFunctionは未評価のままで残る：

Wolfram Language code: BooleanConsecutiveFunction[{2, True}, 3][x, y, z]

BooleanConvertを使ってこれを展開する：

Wolfram Language code: BooleanConvert[%]

関数を代数標準形の式として構築する：

Wolfram Language code: BooleanConsecutiveFunction[{2, True}, {x, y, z}, "ANF"]

トーラス形状の二次元関数を定義する：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{{2, 2}, True}, {3, 3}][Array[Subscript[x, #1, #2]&, {3, 3}]]]

変数もまた平坦なリストで与えることができる：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{{2, 2}, True}, {3, 3}][Array[Subscript[x, #]&, 9]]]

円状になった連続する4つの成分のうち少なくとも3つが故障すると故障する系：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℛ = FailureDistribution[BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ, t]//PiecewiseExpand

BooleanConsecutiveFunctionは構造に使うことができる：

Wolfram Language code: ℛ2 = FailureDistribution[w∨BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ2, t]//PiecewiseExpand

円状になった連続する4つの成分のうち少なくとも3つが動くと動く系：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℱ = ReliabilityDistribution[BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ, t]//PiecewiseExpand

BooleanConsecutiveFunctionは構造に使うことができる：

Wolfram Language code: ℱ2 = ReliabilityDistribution[w∨BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ2, t]//PiecewiseExpand

混合モデル  (2)

ラッピングは次元が異なると異なることがある．円柱を定義する：

Wolfram Language code: BooleanConsecutiveFunction[{{2, 2}, {True, False}}, {3, 3}][Array[Subscript[x, #1, #2]&, {3, 3}]]

BooleanConvertを使ってこれを展開する：

Wolfram Language code: BooleanConvert[%]

関数を連言標準形の式として構築する：

Wolfram Language code: BooleanConsecutiveFunction[{{2, 2}, {True, False}}, Array[Subscript[x, #1, #2]&, {3, 3}], "CNF"]

互いの内側にスタックして連結する円柱：

Wolfram Language code: BooleanConsecutiveFunction[{{2, 3, 3}, {False, False, True}}, {3, 3, 3}][Flatten[Array[Subscript[x, #1, #2, #3]&, {3, 3, 3}]]];

BooleanConvertを使ってこれを展開する：

Wolfram Language code: BooleanConvert[%]

アプリケーション  (2)

一連の10台の無線等塔は，隣り合う2台の塔が故障すると故障する：

Wolfram Language code: structure = BooleanConsecutiveFunction[2, 10][Array[Subscript[x, #]&, 10]]

各塔の寿命は指数分布に従い，寿命の期待値は10年である：

Wolfram Language code: 𝒟tower = ExponentialDistribution[1 / 10];

一連の塔の片方の端から網一方の端への接続の生存関数：

Wolfram Language code: ℱ = FailureDistribution[structure, Array[{Subscript[x, #], 𝒟tower}&, 10]];
Wolfram Language code: Plot[Evaluate@SurvivalFunction[ℱ, t], {t, 0, 10}, Filling -> Axis]

整備をせずに5年間経った後で機能している確率：

Wolfram Language code: Probability[t > 5, tℱ]//N

カメラが重なり合う格子上に配置されている．2×2の格子が故障するまでは全領域がカバーされている：

Wolfram Language code: structure = BooleanConsecutiveFunction[{2, 2}, {4, 4}][Array[Subscript[x, #1, #2]&, {4, 4}]];

各カメラの寿命の期待値は6年である：

Wolfram Language code: 𝒟camera = ExponentialDistribution[1 / 6];

完全なカメラの系の寿命分布は’FailureDistributionでモデル化することができる：

Wolfram Language code: ℱ = FailureDistribution[structure, Join@@Array[{Subscript[x, #1, #2], 𝒟camera}&, {4, 4}]];

オーバーラップを最小にして同じ領域をカバーするのに4台のカメラが必要である：

Wolfram Language code: ℱnooverlap = FailureDistribution[Subscript[x, 1] || Subscript[x, 2] || Subscript[x, 3] || Subscript[x, 4], {{Subscript[x, 1], 𝒟camera}, {Subscript[x, 2], 𝒟camera}, {Subscript[x, 3], 𝒟camera}, {Subscript[x, 4], 𝒟camera}}];

重なり合う構造の方が信頼度は高いが，より多くのカメラが必要である：

Wolfram Language code: Plot[Evaluate@{SurvivalFunction[ℱ, t], SurvivalFunction[ℱnooverlap, t]}, {t, 0, 15}, Filling -> Axis]

代りに同じ台数のカメラを待機モードで使う：

Wolfram Language code: 𝒟standby = StandbyDistribution[𝒟camera, {𝒟camera, 𝒟camera, 𝒟camera}, 0.9];
Wolfram Language code: ℱstandby = FailureDistribution[Subscript[x, 1] || Subscript[x, 2] || Subscript[x, 3] || Subscript[x, 4], {{Subscript[x, 1], 𝒟standby}, {Subscript[x, 2], 𝒟standby}, {Subscript[x, 3], 𝒟standby}, {Subscript[x, 4], 𝒟standby}}];

業務時間によっては，待機構造の方がオーバーラップする格子よりも信頼性が高くなる：

Wolfram Language code: Plot[Evaluate@{SurvivalFunction[ℱ, t], SurvivalFunction[ℱstandby, t]}, {t, 0, 15}, Filling -> Axis]

特性と関係  (2)

より低い次元はより高い次元の特殊ケースである：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{3, True}, 4][Array[Subscript[x, 1, #]&, 4]]]
Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{{1, 3}, True}, {1, 4}][Array[Subscript[x, #1, #2]&, {1, 4}]]]
Wolfram Language code: Equivalent[%%, %]//TautologyQ

BooleanConsecutiveFunctionのあるReliabilityDistributionはFailureDistributionにおいて対応するブール式を否定したものに等しい：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = Table[ExponentialDistribution[Subscript[λ, i]], {i, 3}];
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[2, 3][x, y, z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];
Wolfram Language code: ℱ = FailureDistribution[¬BooleanConsecutiveFunction[2, 3][¬x, ¬y, ¬z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];
Wolfram Language code: CDF[ℛ, t] - CDF[ℱ, t]

おもしろい例題  (1)

線形 k アウトオブ n 系のシミュレーションを行う：

Wolfram Language code: meaning[False] = "working";meaning[True] = "failed";
Wolfram Language code: simulate[k_, n_, λ_ : 1 / 2] := Block[{failed = False, deaths, t = -1, res = {}}, deaths = RandomVariate[ExponentialDistribution[λ], n]; While[!failed, t++; tab = Table[Style[Subscript[x, i], If[deaths[[i]] < t, Red, Green]], {i, n}]; failed = BooleanConvert@BooleanConsecutiveFunction[k, n][Map[t > #&, deaths]]; AppendTo[res, Graph[tab, Table[Subscript[x, j]Subscript[x, j + 1], {j, n - 1}], VertexSize -> Large, PlotLabel -> "t = " <> ToString[t] <> ", system " <> meaning[failed]]]; ]; res//Column]

10個のうち4個の成分が故障すると系が故障する場合．故障率で：

Wolfram Language code: simulate[4, 10, 1 / 3]
Wolfram Research (2012), BooleanConsecutiveFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html.

テキスト

Wolfram Research (2012), BooleanConsecutiveFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html.

CMS

Wolfram Language. 2012. "BooleanConsecutiveFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html.

APA

Wolfram Language. (2012). BooleanConsecutiveFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html

BibTeX

@misc{reference.wolfram_2026_booleanconsecutivefunction, author="Wolfram Research", title="{BooleanConsecutiveFunction}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanconsecutivefunction, organization={Wolfram Research}, title={BooleanConsecutiveFunction}, year={2012}, url={https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html}, note=[Accessed: 12-August-2026]}