WOLFRAM

Wolfram 语言与系统参考资料中心

BooleanConsecutiveFunction[k,n]

表示由 n 个变量组成的布尔函数，如果 k 个连续变量是 True，则给出 True.

BooleanConsecutiveFunction[{k,True},n]

将变量列表视为循环的.

BooleanConsecutiveFunction[{k1,k2,…,kd},{n1,n2,…,nd}]

表示由 n1 n2 ⋯ nd 个变量组成的布尔函数，如果 变量数组的 块中所有变量是 True，那么给出 True.

BooleanConsecutiveFunction[{{k1,k2,…,kd},{c1,c2,…,cd}},{n1,n2,…,nd}]

如果 ci 是 True，那么将变量数组的第 i 层视为循环处理.

BooleanConsecutiveFunction[spec,{a1,a2,…}]

给出对应于由 spec 指定的布尔连续函数的关于变量 ai 的布尔表达式.

BooleanConsecutiveFunction[spec,{a1,a2,…},form]

以由 form 指定的格式给出布尔表达式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
线性模型  
圆形模型  
混合模型  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BooleanConsecutiveFunction

BooleanConsecutiveFunction[k,n]

表示由 n 个变量组成的布尔函数，如果 k 个连续变量是 True，则给出 True.

BooleanConsecutiveFunction[{k,True},n]

将变量列表视为循环的.

BooleanConsecutiveFunction[{k1,k2,…,kd},{n1,n2,…,nd}]

表示由 n1 n2 ⋯ nd 个变量组成的布尔函数，如果 变量数组的 块中所有变量是 True，那么给出 True.

BooleanConsecutiveFunction[{{k1,k2,…,kd},{c1,c2,…,cd}},{n1,n2,…,nd}]

如果 ci 是 True，那么将变量数组的第 i 层视为循环处理.

BooleanConsecutiveFunction[spec,{a1,a2,…}]

给出对应于由 spec 指定的布尔连续函数的关于变量 ai 的布尔表达式.

BooleanConsecutiveFunction[spec,{a1,a2,…},form]

以由 form 指定的格式给出布尔表达式.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

创建一个连续 3 中取 2 布尔函数：

Wolfram Language code: BooleanConsecutiveFunction[2, 3][Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]]

转化为显式形式：

Wolfram Language code: BooleanConvert[%]

在 ReliabilityDistribution 中使用 BooleanConsecutiveFunction：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = Table[ExponentialDistribution[Subscript[λ, i]], {i, 3}];
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[2, 3][x, y, z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

计算生存函数：

Wolfram Language code: SurvivalFunction[ℛ, t]//Simplify

在 FailureDistribution 中使用 BooleanConsecutiveFunction：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = Table[ExponentialDistribution[Subscript[λ, i]], {i, 3}];
Wolfram Language code: ℱ = FailureDistribution[BooleanConsecutiveFunction[2, 3][x, y, z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

计算生存函数：

Wolfram Language code: SurvivalFunction[ℱ, t]//Simplify

范围  (10)

线性模型  (4)

BooleanConsecutiveFunction 未计算：

Wolfram Language code: BooleanConsecutiveFunction[2, 4][x, y, z, v]

使用 BooleanConvert 来展开：

Wolfram Language code: BooleanConvert[%]

将函数构建为合取范式表达式：

Wolfram Language code: BooleanConsecutiveFunction[2, {x, y, z, v}, "CNF"]

定义一个二维函数，以网格为形状：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{2, 2}, {3, 3}][Array[Subscript[x, #1, #2]&, {3, 3}]]]

变量也可以在展平的列表中给出：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{2, 2}, {3, 3}][Array[Subscript[x, #]&, 9]]]

如果线上四个连续组件中至少有三个可运作，则该系统可以运作：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ, t]

BooleanConsecutiveFunction 可用于结构中：

Wolfram Language code: ℛ2 = ReliabilityDistribution[w∨BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ2, t]

如果线上四个连续分量中至少3个失效，则该系统失效：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℱ = FailureDistribution[BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ, t]

BooleanConsecutiveFunction 可以在结构中使用：

Wolfram Language code: ℱ2 = FailureDistribution[w∨BooleanConsecutiveFunction[3, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ2, t]

圆形模型  (4)

BooleanConsecutiveFunction 未计算：

Wolfram Language code: BooleanConsecutiveFunction[{2, True}, 3][x, y, z]

使用 BooleanConvert 来展开：

Wolfram Language code: BooleanConvert[%]

将函数构建为代数范式表达式：

Wolfram Language code: BooleanConsecutiveFunction[{2, True}, {x, y, z}, "ANF"]

定义一个二维函数，以 torus 形状表示：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{{2, 2}, True}, {3, 3}][Array[Subscript[x, #1, #2]&, {3, 3}]]]

变量也可以在一个展平的列表中给出：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{{2, 2}, True}, {3, 3}][Array[Subscript[x, #]&, 9]]]

如果圆形中四个连续组件中至少3个失效，则该系统失效：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℛ = FailureDistribution[BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ, t]//PiecewiseExpand

BooleanConsecutiveFunction 可以在结构中使用：

Wolfram Language code: ℛ2 = FailureDistribution[w∨BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℛ2, t]//PiecewiseExpand

如果圆形中的四个连续分量中至少3个可以运作，则该系统可运作：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℱ = ReliabilityDistribution[BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ, t]//PiecewiseExpand

BooleanConsecutiveFunction 可以在结构中使用：

Wolfram Language code: ℱ2 = ReliabilityDistribution[w∨BooleanConsecutiveFunction[{3, True}, 4][x, y, z, v], {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}, {v, 𝒟}, {w, 𝒟}}];
Wolfram Language code: SurvivalFunction[ℱ2, t]//PiecewiseExpand

混合模型  (2)

封装在不同维度下不同. 定义一个圆柱体：

Wolfram Language code: BooleanConsecutiveFunction[{{2, 2}, {True, False}}, {3, 3}][Array[Subscript[x, #1, #2]&, {3, 3}]]

使用 BooleanConvert 来展开：

Wolfram Language code: BooleanConvert[%]

将函数构建为合取范式表达式：

Wolfram Language code: BooleanConsecutiveFunction[{{2, 2}, {True, False}}, Array[Subscript[x, #1, #2]&, {3, 3}], "CNF"]

连接的圆柱体一层一层在内部堆起来：

Wolfram Language code: BooleanConsecutiveFunction[{{2, 3, 3}, {False, False, True}}, {3, 3, 3}][Flatten[Array[Subscript[x, #1, #2, #3]&, {3, 3, 3}]]];

使用 BooleanConvert 来展开：

Wolfram Language code: BooleanConvert[%]

应用  (2)

10 个无线电塔链在两个相邻的塔出故障后，塔链失效：

Wolfram Language code: structure = BooleanConsecutiveFunction[2, 10][Array[Subscript[x, #]&, 10]]

每个塔具有指数分布的使用期，期望使用期是10年：

Wolfram Language code: 𝒟tower = ExponentialDistribution[1 / 10];

从塔链的一端到另一端的生存函数：

Wolfram Language code: ℱ = FailureDistribution[structure, Array[{Subscript[x, #], 𝒟tower}&, 10]];
Wolfram Language code: Plot[Evaluate@SurvivalFunction[ℱ, t], {t, 0, 10}, Filling -> Axis]

在使用五年没有维修的情况下，仍然能够运作的概率：

Wolfram Language code: Probability[t > 5, tℱ]//N

摄像头在重叠网格中排列. 所有区域都被覆盖直至一个 2×2 网格失效：

Wolfram Language code: structure = BooleanConsecutiveFunction[{2, 2}, {4, 4}][Array[Subscript[x, #1, #2]&, {4, 4}]];

每个摄像头的期望使用期限是六年：

Wolfram Language code: 𝒟camera = ExponentialDistribution[1 / 6];

整个摄像头系统的使用期分布是使用 FailureDistribution 建模：

Wolfram Language code: ℱ = FailureDistribution[structure, Join@@Array[{Subscript[x, #1, #2], 𝒟camera}&, {4, 4}]];

在使用最小重叠覆盖同样区域的情况下，需要四个摄像头：

Wolfram Language code: ℱnooverlap = FailureDistribution[Subscript[x, 1] || Subscript[x, 2] || Subscript[x, 3] || Subscript[x, 4], {{Subscript[x, 1], 𝒟camera}, {Subscript[x, 2], 𝒟camera}, {Subscript[x, 3], 𝒟camera}, {Subscript[x, 4], 𝒟camera}}];

重叠结构具有较高的可靠性，但是使用较多摄像头：

Wolfram Language code: Plot[Evaluate@{SurvivalFunction[ℱ, t], SurvivalFunction[ℱnooverlap, t]}, {t, 0, 15}, Filling -> Axis]

在 standby 模式下使用相同数目的摄像头：

Wolfram Language code: 𝒟standby = StandbyDistribution[𝒟camera, {𝒟camera, 𝒟camera, 𝒟camera}, 0.9];
Wolfram Language code: ℱstandby = FailureDistribution[Subscript[x, 1] || Subscript[x, 2] || Subscript[x, 3] || Subscript[x, 4], {{Subscript[x, 1], 𝒟standby}, {Subscript[x, 2], 𝒟standby}, {Subscript[x, 3], 𝒟standby}, {Subscript[x, 4], 𝒟standby}}];

与发动时机有关，一次 standby 设置比重叠网格具有更高的可靠性：

Wolfram Language code: Plot[Evaluate@{SurvivalFunction[ℱ, t], SurvivalFunction[ℱstandby, t]}, {t, 0, 15}, Filling -> Axis]

属性和关系  (2)

较低的维度是较高维度的特例：

Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{3, True}, 4][Array[Subscript[x, 1, #]&, 4]]]
Wolfram Language code: BooleanConvert[BooleanConsecutiveFunction[{{1, 3}, True}, {1, 4}][Array[Subscript[x, #1, #2]&, {1, 4}]]]
Wolfram Language code: Equivalent[%%, %]//TautologyQ

具有一个 BooleanConsecutiveFunction 的 ReliabilityDistribution 等于 FailureDistribution 中相应的布尔表达式取负：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = Table[ExponentialDistribution[Subscript[λ, i]], {i, 3}];
Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[2, 3][x, y, z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];
Wolfram Language code: ℱ = FailureDistribution[¬BooleanConsecutiveFunction[2, 3][¬x, ¬y, ¬z], {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];
Wolfram Language code: CDF[ℛ, t] - CDF[ℱ, t]

巧妙范例  (1)

模拟一个线性连续-k-out-of-n 系统：

Wolfram Language code: meaning[False] = "working";meaning[True] = "failed";
Wolfram Language code: simulate[k_, n_, λ_ : 1 / 2] := Block[{failed = False, deaths, t = -1, res = {}}, deaths = RandomVariate[ExponentialDistribution[λ], n]; While[!failed, t++; tab = Table[Style[Subscript[x, i], If[deaths[[i]] < t, Red, Green]], {i, n}]; failed = BooleanConvert@BooleanConsecutiveFunction[k, n][Map[t > #&, deaths]]; AppendTo[res, Graph[tab, Table[Subscript[x, j]Subscript[x, j + 1], {j, n - 1}], VertexSize -> Large, PlotLabel -> "t = " <> ToString[t] <> ", system " <> meaning[failed]]]; ]; res//Column]

当要求10个组件中有4个是坏的，系统才坏，其失效率为 ：

Wolfram Language code: simulate[4, 10, 1 / 3]
Wolfram Research (2012)，BooleanConsecutiveFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html.

文本

Wolfram Research (2012)，BooleanConsecutiveFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html.

CMS

Wolfram 语言. 2012. "BooleanConsecutiveFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html.

APA

Wolfram 语言. (2012). BooleanConsecutiveFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html 年

BibTeX

@misc{reference.wolfram_2026_booleanconsecutivefunction, author="Wolfram Research", title="{BooleanConsecutiveFunction}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanconsecutivefunction, organization={Wolfram Research}, title={BooleanConsecutiveFunction}, year={2012}, url={https://reference.wolfram.com/language/ref/BooleanConsecutiveFunction.html}, note=[Accessed: 12-August-2026]}